C++和Objective-C混编(官方文档翻译)

转载 2011年10月15日 18:12:20

C++和Objective-C混编(官方文档翻译)   

原文网址:http://developer.apple.com/iphone/library/documentation/Cocoa/Conceptual/ObjectiveC/Articles/o*****lusPlus.html

Using C++ With Objective-C
    苹果的Objective-C编译器允许用户在同一个源文件里自由地混合使用C++和Objective-C,混编后的语言叫Objective-C++。有了它,你就可以在Objective-C应用程序中使用已有的C++类库。

Objective-C和C++混编的要点
   在Objective-C++中,可以用C++代码调用方法也可以从Objective-C调用方法。在这两种语言里对象都是指针,可以在任何地方使用。例如,C++类可以使用Objective-C对象的指针作为数据成员,Objective-C类也可以有C++对象指针做实例变量。下例说明了这一点。
    注意:Xcode需要源文件以".mm"为扩展名,这样才能启动编译器的Objective-C++扩展。
复制代码
  1. /* Hello.mm
  2.  * Compile with: g++ -x objective-c++ -framework Foundation Hello.mm  -o hello
  3.  */
  4. #import <Foundation/Foundation.h>
  5. class Hello {
  6. private:
  7.     id greeting_text;  // holds an NSString
  8. public:
  9.     Hello() {
  10.         greeting_text = @"Hello, world!";
  11.     }
  12.     Hello(const char* initial_greeting_text) {
  13.         greeting_text = [[NSString alloc] initWithUTF8String:initial_greeting_text];
  14.     }
  15.     void say_hello() {
  16.         printf("%s\n", [greeting_text UTF8String]);
  17.     }
  18. };
  19. @interface Greeting : NSObject {
  20. @private
  21.     Hello *hello;
  22. }
  23. - (id)init;
  24. - (void)dealloc;
  25. - (void)sayGreeting;
  26. - (void)sayGreeting:(Hello*)greeting;
  27. @end
  28. @implementation Greeting
  29. - (id)init {
  30.     if (self = [super init]) {
  31.         hello = new Hello();
  32.     }
  33.     return self;
  34. }
  35. - (void)dealloc {
  36.     delete hello;
  37.     [super dealloc];
  38. }
  39. - (void)sayGreeting {
  40.     hello->say_hello();
  41. }
  42. - (void)sayGreeting:(Hello*)greeting {
  43.     greeting->say_hello();
  44. }
  45. @end
  46. int main() {
  47.     NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
  48.    
  49.     Greeting *greeting = [[Greeting alloc] init];
  50.     [greeting sayGreeting];                         // > Hello,  world!
  51.    
  52.     Hello *hello = new Hello("Bonjour, monde!");
  53.     [greeting sayGreeting:hello];                   // > Bonjour,  monde!
  54.    
  55.     delete hello;
  56.     [greeting release];
  57.     [pool release];
  58.     return 0;
  59. }

    正如你可以在OC接口中声明C结构一样,你也可以在OC接口中声明C++类。跟C结构一样,OC接口中定义的C++类是全局范围的,不是OC类的内嵌类(这与标准C(尽管不是C++)提升嵌套结构定义为文件范围是一致的)。
    为了允许你基于语言变种条件化地编写代码,OC++编译器定义了__cplusplus和__OBJC__预处理器常量,分别指定C++和OC。    如前所述,OC++不允许C++类继承自OC对象,也不允许OC类继承自C++对象。
复制代码
  1. class Base { /* ... */ };
  2. @interface ObjCClass: Base ... @end // ERROR!
  3. class Derived: public ObjCClass ... // ERROR!

   与OC不同的是,C++对象是静态类型的,有运行时多态是特殊情况。两种语言的对象模型因此不能直接兼容。更根本的,OC和C++对象在内存中的布局是互不相容的,也就是说,一般不可能创建一个对象实例从两种语言的角度来看都是有效的。因此,两种类型层次结构不能被混合。
    你可以在OC类内部声明C++类,编译器把这些类当作已声明在全局名称空间来对待。就像下面: 
复制代码
  1. @interface Foo {
  2.     class Bar { ... } // OK
  3. }
  4. @end
  5. Bar *barPtr; // OK

    OC允许C结构作为实例变量,不管它是否声明在OC声明内部。
复制代码
  1. @interface Foo {
  2.    struct CStruct { ... };
  3.    struct CStruct bigIvar; // OK
  4. } ... @end

    Mac OS X 10.4以后,如果你设置fobjc-call-cxx-cdtors编译器标志,你就可以使用包含虚函数和有意义的用户自定义零参数构造函数、析构函数的C++类实例来做为实例变量(gcc-4.2默认设置编译器标志fobjc-call-cpp-cdtors)。OC成员变量alloc完以后,alloc函数会按声明顺序调用构造器。构造器使用公共无参数恰当的构造函数。OC成员变量dealloc之前,dealloc方法按声明顺序反序调用调用析构函数。    OC没有名称空间得概念。不能在C++名称空间内部声明OC类,也不能在OC类里声明名称空间。
    OC类,协议,分类不能声明在C++ template里,C++ template也不能声明在OC接口,协议,分类的范围内。
    但是,OC类可以做C++ template的参数,C++ template参数也可以做OC消息表达式的接收者或参数(不能通过selector)。

C++词汇歧义和冲突
    OC头文件中定义了一些标识符,所有的OC程序必须包含的,这些标识符识id,Class,SEL,IMP和BOOL。
    OC方法内,编译器预声明了标识符self和super,就想C++中的关键字this。跟C++的this不同的是,self和super是上下文相关的;OC方法外他们还可以用于普通标识符。
    协议内方法的参数列表,有5个上下文相关的关键字(oneway,in,out,inout,bycopy)。这些在其他内容中不是关键字。
   从OC程序员的角度来看,C++增加了不少新的关键字。你仍然可以使用C++的关键字做OC selector的一部分,所以影响并不严重,但你不能使用他们命名OC类和实例变量。例如,尽管class是C++的关键字,但是你仍然能够使用NSObject的方法class:
复制代码
  1. [foo class]; // OK

    然而,因为它是一个关键字,你不能用class做变量名称:
复制代码
  1. NSObject *class; // Error

    OC里类名和分类名有单独的命名空间。@interface foo和@interface(foo)能够同时存在在一个源代码中。OC++里,你也能用C++中的类名或结构名来命名你的分类。
    协议和template标识符使用语法相同但目的不同:
复制代码
  1. id<someProtocolName> foo;
  2. TemplateType<SomeTypeName> bar;

    为了避免这种含糊之处,编译器不允许把id做template名称。    最后,C++有一个语法歧义,当一个label后面跟了一个表达式表示一个全局名称时,就像下面:
复制代码
  1. label: ::global_name = 3;

    第一个冒号后面需要空格。OC++有类似情况,也需要一个空格:
复制代码
  1. receiver selector: ::global_c++_name;


限制
   OC++没有为OC类增加C++的功能,也没有为C++类增加OC的功能。例如,你不能用OC语法调用C++对象,也不能为OC对象增加构造函数和析构函数,也不能将this和self互相替换使用。类的体系结构是独立的。C++类不能继承OC类,OC类也不能继承C++类。另外,多语言异常处理是不支持的。也就是说,一个OC抛出的异常不能被C++代码捕获,反过来C++代码抛出的异常不能被OC代码捕获。

Swift与Objective-C\C\C++混合编程

Swift语言出现后,iOS程序员有了更多的选择。很多应用开发会涉及到Swift和Objective-C、C和C++混合编程。本课程介绍了Swift与Objective-C API映射、同一应用目标中的混合编程和同一框架目标中的混合编程情况下Swift调用Objective-C,Objective-C调用Swift,Swift调用C和C++等。
  • 2016年05月17日 16:19

Xcode中Objective-C和C++混编的实现 (二)

事例代码,代码主要只是为了说明Objective-C如何与C++混编调用原理,代码在写法上不是非常严谨, 1.封装类 .h // //  CellCountObj.h //   // ...
  • color99
  • color99
  • 2015-11-11 23:23:01
  • 886

C++和Objective-C混编 如何在xcode中用C++的STL

  • 2010年11月02日 16:23
  • 20KB
  • 下载

Xcode中Objective-C和C++混编的实现(一)

最近在做一个项目需要把OpenCV 的代码移植到iOS中,在移植过程中遇到了很多问题,其中最关键的就是OC与C++混编的问题,找了很多资料和弯路终于走通了,现在把思路整理好做个笔记.希望能给有需要的朋...
  • color99
  • color99
  • 2015-11-11 23:14:29
  • 4655

Objective-C/C++混编编译器设置

当使用Xcode编写C++代码时,难以避免要使用xcode/C++混合编译。           如果你在Xcode中编写的工程中既有Objective-C代码,又有C++代码,在没有任何设置编译器...
  • wangyuchun_799
  • wangyuchun_799
  • 2012-07-09 15:18:50
  • 22797

在Xcode中使用C++与Objective-C混编

有时候,出于性能或可移植性的考虑,需要在iOS项目中使用到C++。 假设我们用C++写了下面的People类: // // People.h // MixedWithCppDemo // //...
  • jasonblog
  • jasonblog
  • 2012-08-18 15:36:47
  • 23235

iOS 里面 Swift与Objective-C混编,Swift与C++混编的一些比较

即使你尽量用Swift编写iOS程序,难免会遇到部分算法是用C++语言编写的。那你只能去问问”度娘“或“狗哥”怎么用Swift调用C++算法。   一,C,C++, Objective-C...
  • sinat_24436879
  • sinat_24436879
  • 2015-03-24 00:05:35
  • 972

object-c 混编 调用C,C++接口

xcode 支持 object-c 混编,在object-c 中调用c,c++接口 第一步 定义c语言 接口(File.c) #include void printsByC(){ ...
  • pizi0475
  • pizi0475
  • 2016-01-28 12:03:27
  • 1557

关于C/C++,Objective-C混合编程

IOS开始使用的编程语言主要是Objective-C,在大多数情况下可以满足我们的需求,但有些情况下,必须要用到C/C++语言:         ①如很多算法都是以C/C++写成,如果要使用这些算法...
  • gh1232008
  • gh1232008
  • 2013-11-24 18:36:09
  • 2102

Swift和Objective-C混编要点

前言 Swift已推出数年,与Objective-C相比Swift的语言机制及使用简易程度上更接地气,大大降低了iOS入门门槛。当然这对新入行的童鞋们来讲,的确算是福音,但对于整个iOS编程从业...
  • ewfrggregtrwt
  • ewfrggregtrwt
  • 2017-08-03 20:34:41
  • 385
收藏助手
不良信息举报
您举报文章:C++和Objective-C混编(官方文档翻译)
举报原因:
原因补充:

(最多只允许输入30个字)