【最短路】心灵的抚慰

题目:心灵的抚慰 rqnoj389

题目描述

背景 Background
病毒问题解决后，神牛们的心灵久久不能平静。有个神牛因此已经“乱了”。他脑子中满是程序（否则怎么会成为神牛呢），而且他可以从一个程序联想到一些相似的程序。比如从程序1联想到2，从2联想到4，从4联想到6，从6联想到9……躺就像搜索一样一步一步越陷越深。不过同一种联想他只会联想一次。比如1、2之间他进行了一次联想，那么他不会再重新联想1到2，或2到1。眼看他又要乱了，有人突然想到，如果他刚开始时想到的程序能够经过联想若干次后联想回到原程序，那不就乱回来了吗？由于神牛马上就要开乱，请在1秒内告诉他，他需要想哪个程序，以便乱回来。

题目描述 Description
给出一些程序和他们互相联想的关系（如果两个程序A、B有联系，神牛可以从A联想到B，也可以从B联想到A，但A、B之间神牛最多联想一次），请告诉神牛他需要想哪个程序，以便在最短的时间内乱回来，并输出这个最短时间。

数据范围
对于100% 的数据，n≤250。

输入格式

第一行有两个正整数N，M，分别表示程序个数和有多少对程序可以被神牛直接互相联想。
以下M行，每行三个正整数，分别表示一种联想的两端的程序的编号（从1开始），以及进行这种联想所需要的最短时间。

输出格式

如果神牛无论如何都再也乱不回来了，输出“He will never come back.”。
如果神牛能够乱回来，请输出神牛会乱多长时间。

样例输入

4 3 1 2 10 1 3 20 1 4 30

样例输出

He will never come back.

 

题目大部分不难，很容易想到用floyd算出任意两点的最短路，然后再枚举。但是问题就来了，题目要求路径不能重复，所以要边floyd边枚举边，并且注意，三条边至多有一条是松弛后的，否则有可能重复路径，形成直线往返。

这一题涉及到了动规的思想，可能理解起来有点抽象。

Pascal Code

program rqnoj389;

const maxn=300;

var
  n,m:longint;
  map,dist:array[0..maxn,0..maxn] of longint;
  f:array[0..maxn,0..maxn] of longint;

procedure init;
begin
  assign(input,'rqnoj389.in');
  assign(output,'rqnoj389.out');
  reset(input);
  rewrite(output);
end;
procedure outit;
begin
  close(input);
  close(output);
  halt;
end;

procedure readdata;
var
  i,x,y,z:longint;
begin
  fillchar(map,sizeof(map),$7);
  fillchar(dist,sizeof(dist),$7);
  read(n,m);
  for i:=1 to m do
  begin
    read(x,y,z);
    map[x,y]:=z;
    map[y,x]:=z;
    dist[x,y]:=z;
    dist[y,x]:=z;
  end;
end;

procedure main;
var
  k,i,j,min:longint;
begin
  min:=$07070707;
  for k:=1 to n do
  begin
    for i:=1 to k-1 do
      for j:=1 to k-1 do
        if (i<>j)and(min>dist[i,j]+map[i,k]+map[k,j]) then
          min:=dist[i,j]+map[i,k]+map[k,j];

    for i:=1 to n do
      for j:=1 to n do
        if (i<>k)and(i<>j)and(j<>k)and(dist[i,j]>dist[i,k]+dist[k,j]) then
          dist[i,j]:=dist[i,k]+dist[k,j];
  end;
  if min=$07070707 then writeln('He will never come back.')
    else writeln(min);
end;

begin
  init;
  readdata;
  main;
  outit;
end.

 

 

转载于:https://www.cnblogs.com/oijzh/archive/2012/08/18/2645781.html