并查集/poj1182 noi2001食物链eat

题意

　　有三类动物A,B,C，题中给出两种关系：

　　　　1 x y :x y 同类

　　　　2 x y :x吃y

　　对于假话的定义：

　　　　1.当前的话与前面的某些真的话冲突，就是假话；

　　　　2.当前的话中X或Y比N大，就是假话；

　　　　3.当前的话表示X吃X，就是假话。

　　现在给出n句这样的关系，求假话个数。

分析

　　这是第二次写这道题了，第一次是去年刚学并查集的时候。当初囫囵吞枣A了，现在拿出来发现自己根本就没明白。

　　感觉，经典的题还是要时常拿出来做一做。

　　刚才某人吐槽：这题比就我小4岁。呵呵....

 

　　废话少说，说正题。

 

　　看题解写的，这个人的分析很详细哦~！膜拜！http://blog.csdn.net/c0de4fun/article/details/7318642

　　感觉他说的太详细了，所以鄙人就摘抄并整理修改一下这位大神的，自己也没什么可写的了...谢谢大神

　　Part I - 权值(relation)的确定。
　　　　我们根据题意，森林中有3种动物。A吃B，B吃C，C吃A。
　　　　我们还要使用并查集，那么，我们就以动物之间的关系来作为并查集每个节点的权值。
　　　　注意，我们不知道所给的动物（题目说了，输入只给编号）所属的种类。

　　　　所以，我们可以用动物之间“相对”的关系来确定一个并查集。
　　　　　　　　0 - 这个节点与它的父节点是同类
　　　　　　　　1 - 这个节点被它的父节点吃
　　　　　　　　2 - 这个节点吃它的父节点。

　　　　注意，这个0,1,2所代表的意义不是随便制定的，我们看题目中的要求。
　　　　说话的时候，第一个数字（下文中，设为d）指定了后面两种动物的关系：
　　　　　　　　1 - X与Y同类
　　　　　　　　2 - X吃Y

　　　　我们注意到，当 d = 1的时候，( d - 1 ) = 0，也就是我们制定的意义
　　　　当 d = 2的时候，( d - 1 ) = 1，代表Y被X吃，也是我们指定的意义。
　　　　所以，这个0,1,2不是随便选的

　　Part II - 路径压缩，以及节点间关系确定
　　　　确定了权值之后，我们要确定有关的操作。
　　　　我们把所有的动物全初始化 relation[i]=0,f[i]=i

　　　　(1)路径压缩时的节点算法

　　　　通过穷举我们可以发现

　　　　　　f[now]=f[f[now]]

　　　　　　relation[now]=(relation[now]+relation[f[now]]) % 3

　　　　这个路径压缩算法是正确的
　　　　关于这个路径压缩算法，还有一点需要注意的地方，我们一会再谈
　　　　注意，根据当前节点的relation和当前节点父节点的relation推出
　　　　当前节点与其父节点的父节点的relation这个公式十分重要！！
　　　　它推不出来下面都理解不了！！自己用穷举法推一下：
　　　　好吧，为了方便伸手党，我给出穷举过程
　　　　　　　　        i      j
　　　　　　　 爷爷  父亲 儿子      儿子与爷爷
　　　　　　　　　　 0      0      (i + j)%3 = 0
　　　　　　　　　　 0      1      (i + j)%3 = 1
　　　　　　　　　　 0      2      (i + j)%3 = 2
　　　　　　　　　　 1      0      (i + j)%3 = 1
　　　　　　　　　　 1      1      (i + j)%3 = 2
　　　　　　　　　　 1      2      (i + j)%3 = 0
　　　　　　　　　　 2      0      (i + j)%3 = 2
　　　　　　　　　　 2      1      (i + j)%3 = 0
　　　　　　　　　　 2      2      (i + j)%3 = 1
　　　　嗯，这样可以看到，( 儿子relation + 父亲relation ) % 3 = 儿子对爷爷的relation

　　　　　　所以有relation[now]=(relation[now]+relation[f[now]]) % 3
　　　　　　这就是路径压缩的节点算法

　　　　(2) 集合间关系的确定
　　　　　　　　relation[find(y)]=(3-relation[y]+(d-1)+relation[x]) % 3;
　　　　　　　　这个公式，是分三部分，这么推出来的：
　　　　　　　　( d - 1 ) :这是X和Y之间的relation，X是Y的父节点时，Y的relation就是这个
　　　　　　　　3 - relation[y] = 根据Y与根节点的关系，逆推根节点与Y的关系
　　　　　　　　　　　　这部分也是穷举法推出来的，我们举例：
　　　　　　　　　　　　　　0（父子同类）( 3 - 0 ) % 3 = 0
　　　　　　　　　　　　　　1（父吃子） ( 3 - 1 ) % 3 = 2 //父吃子
　　　　　　　　　　　　　　2（子吃父) ( 3 - 2 ) % 3 = 1 //子吃父，一样的哦亲

　　　　　　　　所以有y的父结点与x的父结点关系relation[find(y)]=(3-relation[y]+(d-1)+relation[x]) % 3;
　　　　　　　　注意，这个当所有集合都是初始化状态的时候也适用

　　Part III - 判断

　　　　先处理特殊情况：　　　　　　

　　　　1.当x>n或y>n时，为假话（在这里竟然wa了一次...囧还是太不认真了）

　　　　 2.当d=2而x=y时，为假话

　
　　　　其实所有的不同集合到最后都会被合并成一个集合的。我们只要在一个集合中找那些假话就可以了。

　　　　　　(1)首先，如何判断
　　　　　　　　1 X Y是不是假话。//此时 d = 1
　　　　　　　　if ( X 和 Y 不在同一集合) Union(x,y,xroot,yroot,d) 　　

　　　　　　　　　　　　　　　　　　　　else if x.relation != y.relation ->假话

　　　　　　(2)其次，如何判断
　　　　　　　　2 X Y是不是假话 //此时d = 2
　　　　　　　　if ( X 和 Y 不在同一集合）Union(x,y,xroot,yroot,d)
　　　　　　　　　　　　　　　　　　　　else (relation [y]+ 3 - relation[x] ) % 3 != 1 ->假话
　　　　　　　　这个公式是这么来的：
　　　　　　　　　　3 - relation[x]得到了根节点关于x的relation，
　　　　　　　　　　relation [y]+ 3 - relation[x]得到了y关于x的relation
　　　　　　　　　　所以，只要y关于x的relation不是1，就是y不被x吃的话，这句话肯定是假话！

 

　　　　　　综合(1) 和(2),无论d=1或2，只要满足 ((relation[y]-relation[x]+3) Mod 3)<>(d-1) 即为假话

Accepted Code

 1 {
 2      PROBLEM:poj1182 noi2001 食物链 
 3      AUTHER:Rinyo
 4      MEMO:并查集
 5 }
 6 
 7 Program poj1182;
 8 Const
 9   Infile = 'poj1182.in';
10   Outfile = 'poj1182.out';
11 Var
12   relation,f:Array[0..50030]Of Longint;
13   n,k,d,x,y,ans,i,fx,fy:Longint;
14 Function find(x:Longint):Longint;
15 Var
16   fx:Longint;
17 Begin
18   If f[x]=x Then Exit(x)
19   Else Begin
20     fx:=find(f[x]);
21     relation[x]:=(relation[x]+relation[f[x]]) Mod 3;
22     f[x]:=fx;
23     Exit(fx);
24   End;
25 End;
26 Procedure union(x,y,fx,fy,d:Longint);
27 Begin
28   f[fy]:=fx;
29   relation[fy]:=(3-relation[y]+d-1+relation[x]) Mod 3;
30 End;
31 Begin
32   Assign(input,infile);Reset(input);
33   Assign(output,outfile);Rewrite(output);
34   ReadLn(n,k);
35   For i:=1 To n Do Begin
36     f[i]:=i;
37     relation[i]:=0;
38   End;
39   For i:=1 To k Do Begin
40     ReadLn(d,x,y);
41     If (x>n) or (y>n) Then Begin
42       Inc(ans);
43       Continue;
44     End;
45     If (d=2) And (x=y) Then Begin
46       Inc(ans);
47       Continue;
48     End;
49     fx:=find(x);fy:=find(y);
50     If fx<>fy Then union(x,y,fx,fy,d);
51     Else Begin
52       If (((relation[y]-relation[x]+3) Mod 3)<>(d-1)) Then Inc(ans)
53     End;
54   End;
55   WriteLn(ans);
56   Close(input);Close(output)
57 End.
58             

 

 

转载于:https://www.cnblogs.com/Rinyo/archive/2013/02/23/2923802.html