王爽《汇编语言》第十二章实验——0号中断处理程序

1. 中断向量表：

    中断向量表即中断处理程序入口地址的列表。

    8086CPU，中断向量表必须放在0000:0000~0000:03FF单元中。

    每个中断向量占32位内存地址空间（低十六位为偏移地址(IP)，高十六位为段地址(CS)）。

2. 中断过程：

    (1).（从中断信息中）取得中断类型码

    (2). 标志寄存器的值入栈

    (3). 设置标志寄存器的第8位TF和第9位IF的值为0

    (4). CS的内容入栈

    (5). IP的内容入栈

    (6). 从内存地址为中断类型码*4 和中断类型码*4+2 的两个字单元中读取中断处理程序的入口地址设置IP和CS

中断过程是CPU在收到中断信息后，由硬件自动执行的。

3. 中断处理程序：

     由于CPU随时都有可能可能处理中断处理程序，所以中断处理程序必须一直存储在内存某段空间中。

     并且中段处理程序的入口地址(中断向量)，必须存储在相应的中断向量表表项中。

4. 以下以0号中断(除法错误)为例说面上面的处理过程:

     假设我们将中断处理程序安装在起始地址为00200h的256字节内存空间中。

5. 源代码：

assume cs:code
code segment
	start: mov ax,cs
		   mov ds,ax
		   mov si,offset do0
		   mov ax,0
		   mov es,ax
		   mov di,200h
		   
		   mov cx, offset do0ends - offset do0
		   cld
		   rep movsb
		   
		   mov ax,0
		   mov es,ax
		   mov word ptr es:[0*4],200h
		   mov word ptr es:[0*4+2],0h
		   
		   mov ax,1000h
		   mov dx,1
		   mov bx,1
		   div bx
		   
		   mov ax,4c00h
		   int 21h
	  do0: jmp short do0start
		   db "divide error!"
 do0start: mov ax,cs
		   mov ds,ax
		   mov si,202h
		   mov ax,0b800h
            mov es,ax
		   mov di,12*160+36*2
		   mov cx,13
		s: mov al,[si]
		   mov es:[di],al
		   inc si
		   add di,2
		   loop s
		   
		   mov ax,4c00h
		   int 21h
   do0ends:nop
code ends
end start

6. 运行结果：