[分享]dns快速切换器(win适用)

如果你在浏览像google搜索，google地图这样网页时，发现经常出现什么“连接被重置”的错误。这并非google服务器有问题，而是因为当前瓷器国的相关限制导致的。具体原因就不追究了。不过我们可以通过修改dns的办法来跳过这种限制。因为手动修改dns限制实在太麻烦，网上有提供的修改dns的小软件倒是挺方便。不过觉得有点“重量级”没必要。直接写个小脚本就可以实现。

脚本的使用方法：

1.选择你上网使用的适配器
2.选择你要修改的dns配置类型（这里提供自动，google和opendns三种）
3.done

脚本内容（将下面脚本直接复制到文本文件，然后修改扩展名为bat，点击运行即可）：


setlocal enabledelayedexpansion
@echo off
cls
color 5b
echo ================================================================================
echo                           DNS切换小程序
echo                                                       made by:genww    ver 1.11
echo ================================================================================
pause
cls
set /a i=0
set names=

rem 先检查有哪些网络

for /f "tokens=1* delims=: " %%a in ('ipconfig ^|findstr ":$"') do (
set /a i+=1
set tmp=%%b
set names=!names!;!tmp:~,-1!
echo !i!: !tmp:~,-1!

)
echo ________________________________________________________________________________
set /p choose= 请选择要操作的网络适配器(序号)：
set /a choose_num=%choose%

if %choose_num% gtr %i% goto :err1
if %choose_num% leq 0 goto :err1


for /f "tokens=%choose_num% delims=;" %%a in ("%names%") do (
set target=%%a
)
cls
echo 当前%target%的DNS配置：
netsh interface ipv4 show dnsservers %target%
pause
rem 再设置可选的dns配置
cls

echo "1.自动获取DNS服务器(由isp服务提供商提供)"
echo "2.使用google提供的DNS服务器"
echo "3.使用OpenDNS提供的DNS服务器"
echo "0.退出"
echo ________________________________________________________________________________
set /p dns_type= 请选择要切换的DNS服务器(序号)：

set /a dns_type_num=%dns_type%

if %dns_type_num% equ 0 goto :end
if %dns_type_num% gtr 3 goto :err1
if %dns_type_num% lss 0 goto :err1

rem 执行命令

echo 正在操作...

set pre=netsh interface ipv4
if %dns_type%==1 (
call %pre% set dnsservers %target% dhcp
)

if %dns_type%==2 (
call %pre% set dnsservers %target% static 8.8.8.8 primary no
call %pre% add dnsservers %target% 8.8.4.4 index=2 no
)

if %dns_type%==3 (
call %pre% set dnsservers %target% static 208.67.222.222 primary no
call %pre% add dnsservers %target% 208.67.220.220 index=2 no
)

echo 完成!

goto :end

:err1
echo 输入的内容格式错误，请输入序号（数字）
pause
:end