譬如我们用鼠标在某个窗口上双击了一次, 或者给某个窗口输入了一个字母 A;首先发现这些事件的不是窗口, 而是系统!
然后系统告诉窗口: 喂! 你让人点了, 并且是连续点了两鼠标, 你准备怎么办?或者是系统告诉窗口: 喂! 有人向你家里扔砖头了, 不信你看看, 那块砖头是 A.
这时窗口的对有些事件会忽略、对有些事件会做出反应:譬如, 可能对鼠标单击事件忽略, 窗口想: 你单击我不要紧, 累死你我不负责;但一旦谁要双击我, 我会马上行动, 给你点颜色瞧瞧!这里窗口准备要采取的行动, 就是我们提前写好的事件.用 Windows 的话说, 窗口的事件就是系统发送给窗口的消息; 窗口要采取的行动(事件代码)就是窗口的回调函数.
但是! 往往隔墙有耳. 系统要通知给窗口的"话"(消息), 可能会被另一个家伙(譬如是一个贼)提前听到!有可能这个贼就是专门在这等情报的, 贼知道后, 往往在窗口知道以前就采取了行动!并且这个贼对不同的消息会采取不同的行动方案, 它的行动方案一般也是早就准备好的;当然这个贼也不是对什么消息都感兴趣, 对不感兴趣的消息也就无须制定相应的行动方案.
总结: 这个"贼"就是我们要设置的钩子; "贼"的"行动方案"就是钩子函数, 或者叫钩子的回调函数.钩子分两种, 一种是系统级的全局钩子; 一种是线程级的钩子.全局钩子函数需要定义在 DLL 中, 从线程级的钩子开始比较简单.
其实钩子函数就三个:
设置钩子: SetWindowsHookEx
释放钩子: UnhookWindowsHookEx
继续钩子: CallNextHookEx
在线程级的钩子中经常用到 GetCurrentThreadID 函数来获取当前线程的 ID.
下面例子中设定了一个线程级的键盘钩子, 专门拦截字母 A.
- unit Unit1;
- interface
- uses
- Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
- Dialogs;
- type
- TForm1 = class(TForm)
- procedure FormCreate(Sender: TObject);
- procedure FormDestroy(Sender: TObject);
- end;
- {声明键盘钩子回调函数; 其参数传递方式要用 API 的 stdcall}
- function KeyHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
- var
- Form1: TForm1;
- implementation
- {$R *.DFM}
- var
- hook: HHOOK; {定义一个钩子句柄}
- {实现键盘钩子回调函数}
- function KeyHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT;
- begin
- if (wParam = 65) then Beep; {每拦截到字母 A 会发声}
- Result := CallNextHookEx(hook, nCode, wParam, lParam);
- end;
- {设置键盘钩子}
- procedure TForm1.FormCreate(Sender: TObject);
- begin
- hook := SetWindowsHookEx(WH_KEYBOARD, @KeyHook, 0, GetCurrentThreadID);
- end;
- {释放键盘钩子}
- procedure TForm1.FormDestroy(Sender: TObject);
- begin
- UnhookWindowsHookEx(hook);
- end;
- end.
钩子函数虽然不多, 但其参数复杂, 应该从参数入手才能深入进去.
UnhookWindowsHookEx 只需要 SetWindowsHookEx 返回的钩子句柄作参数, 这个简单;
先看看 SetWindowsHookEx 的声明:
SetWindowsHookEx(
idHook: Integer; {钩子类型}
lpfn: TFNHookProc; {函数指针}
hmod: HINST; {包含钩子函数的模块(EXE、DLL)的句柄}
dwThreadId: DWORD {关联的线程}
): HHOOK;
第一个参数非常麻烦, 从后面说:
参数四 dwThreadId : 在设置全局钩子时这个参数一般是 0, 表示关联所有线程; 本例是线程级的钩子, 所以是GetCurrentThreadId.
参数三 hmod: 是模块实例的句柄, 在 EXE 和 DLL 中都可以用 HInstance 得到当前实例的句柄; 直接用 API 也可以:GetModuleHandle(nil).
参数二 lpfn: 是钩子函数的指针, 用 @ 和 Addr 函数都可以得到函数指针; 这里的关键是那个钩子函数:首先不同的钩子类型对应着不同的钩子函数结构, Win32 共有 14 种钩子类型, 这是 详细注释;本例用的是键盘钩子, 键盘钩子的回调函数的参数结构在 这里, 我们定义的函数名无所谓, 参数必须按照Windows的规定来.还有, 这个回调函数的调用惯例必须是: stdcall; 我们在上例中是先在接口区声明, 如果不要声明直接实现, 也不能忘了这个 stdcall.
根据以上说明, 做如下修改:SetWindowsHookEx 的参数有变通;并且取消了钩子函数在接口区的声明, 是直接实现的;取消了拦截条件, 现在只要是键盘消息全都拦截.
- unit Unit1;
- interface
- uses
- Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
- Dialogs;
- type
- TForm1 = class(TForm)
- procedure FormCreate(Sender: TObject);
- procedure FormDestroy(Sender: TObject);
- end;
- var
- Form1: TForm1;
- implementation
- {$R *.DFM}
- var
- hook: HHOOK; {定义一个钩子句柄}
- {现在这个钩子函数没有在接口区声明, 这里必须指定参数调用方式: stdcall}
- function KeyHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
- begin
- Beep;
- Result := CallNextHookEx(hook, nCode, wParam, lParam);
- end;
- {设置键盘钩子}
- procedure TForm1.FormCreate(Sender: TObject);
- begin
- hook := SetWindowsHookEx(WH_KEYBOARD, Addr(KeyHook), HInstance, GetCurrentThreadId);
- end;
- {释放键盘钩子}
- procedure TForm1.FormDestroy(Sender: TObject);
- begin
- UnhookWindowsHookEx(hook);
- end;
- end.
建立一个全局的鼠标钩子: 先建立一个 DLL 工程, 自动初始的代码如下(这里可以参考这篇文章中建立dll部分 [delphi之调用外部dll中的函数] )
- library Project1;
- uses
- SysUtils,
- Classes;
- {$R *.res}
- begin
- end.
- //把工程保存为 MyHook.dpr, 并实现如下:
- library MyHook;
- uses
- SysUtils,
- Windows, {钩子函数都来自 Windows 单元}
- Messages, {消息 WM_LBUTTONDOWN 定义在 Messages 单元}
- Classes;
- {$R *.res}
- var
- hook: HHOOK; {钩子变量}
- {钩子函数, 鼠标消息太多(譬如鼠标移动), 必须要有选择, 这里选择了鼠标左键按下}
- function MouseHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
- begin
- if wParam = WM_LBUTTONDOWN then
- begin
- MessageBeep(0);
- end;
- Result := CallNextHookEx(hook, nCode, wParam, lParam);
- end;
- {建立钩子}
- function SetHook: Boolean; stdcall;
- begin
- hook := SetWindowsHookEx(WH_MOUSE, @MouseHook, HInstance, 0);
- Result := hook <> 0;
- end;
- {释放钩子}
- function DelHook: Boolean; stdcall;
- begin
- Result := UnhookWindowsHookEx(hook);
- end;
- {按 DLL 的要求输出函数}
- exports
- SetHook name 'SetHook',
- DelHook name 'DelHook',
- MouseHook name 'MouseHook';
- //SetHook, DelHook, MouseHook; {如果不需要改名, 可以直接这样 exports}
- begin
- end.
第二步: 调用
新建工程后, 保存, 并把刚才制作的 MyHook.dll 复制到这个工程目录下;然后添加两个按钮, 实现如下:
测试: 点击第一个按钮后, 钩子就启动了; 这是不管鼠标在哪点一下鼠标左键都会 "呯" 的一下; 点击第二个按钮可以收回钩子.
- unit Unit1;
- interface
- uses
- Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
- Dialogs, StdCtrls;
- type
- TForm1 = class(TForm)
- Button1: TButton;
- Button2: TButton;
- procedure Button1Click(Sender: TObject);
- procedure Button2Click(Sender: TObject);
- end;
- {DLL 中的函数声明}
- function SetHook: Boolean; stdcall;
- function DelHook: Boolean; stdcall;
- var
- Form1: TForm1;
- implementation
- {$R *.dfm}
- {DLL 中的函数实现, 也就是说明来自那里, 原来叫什么名}
- function SetHook; external 'MyHook.dll' name 'SetHook';
- function DelHook; external 'MyHook.dll' name 'DelHook';
- {建立钩子}
- procedure TForm1.Button1Click(Sender: TObject);
- begin
- SetHook;
- end;
- {销毁钩子}
- procedure TForm1.Button2Click(Sender: TObject);
- begin
- DelHook;
- end;
- end.
下面是动态调用的方法, 功能和上面完全一直:
- unit Unit1;
- interface
- uses
- Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
- Dialogs, StdCtrls;
- type
- TForm1 = class(TForm)
- Button1: TButton;
- Button2: TButton;
- procedure Button1Click(Sender: TObject);
- procedure Button2Click(Sender: TObject);
- end;
- var
- Form1: TForm1;
- implementation
- {$R *.dfm}
- {要先要定义和 DLL 中同样参数和返回值的的函数类型}
- type
- TDLLFun = function: Boolean; stdcall;
- {现在需要的 DLL 中的函数的格式都是这样, 定义一个就够了}
- var
- h: HWND; {声明一个 DLL 句柄}
- SetHook, DelHook: TDLLFun; {声明两个 TDLLFun 变量}
- {载入 DLL 并调用其函数}
- procedure TForm1.Button1Click(Sender: TObject);
- begin
- h := LoadLibrary('MyHook.dll'); {载入 DLL 并获取句柄}
- if h<>0 then
- begin
- SetHook := GetProcAddress(h, 'SetHook'); {让 SetHook 指向 DLL 中相应的函数}
- DelHook := GetProcAddress(h, 'DelHook'); {让 DelHook 指向 DLL 中相应的函数}
- end else ShowMessage('Err');
- SetHook; {执行钩子建立函数, 这里的 SetHook 和它指向的函数是同名的, 也可以不同名}
- end;
- {销毁钩子, 并释放 DLL}
- procedure TForm1.Button2Click(Sender: TObject);
- begin
- DelHook; {执行钩子释放函数}
- FreeLibrary(h); {释放 DLL 资源}
- end;
- end.
为什么全局钩子非要在 DLL 中呢?
因为每个 EXE 都是一个独立而封闭的进程; 而 DLL 则是面向系统的公用资源.如果一个钩子不是面向系统的, 恐怕意义不大; 所以在实用中, 钩子是离不开 DLL 的.
钩子链和 CallNextHookEx 的返回值
SetWindowsHookEx 函数的第一个参数表示钩子类型, 共有 14 种选择, 前面我们已经用过两种:WH_KEYBOARD、WH_MOUSE.
系统会为每一种类型的钩子建立一个表(那就是 14 个表), 譬如某个应用程序启动了键盘钩子, 我们自己的程序也启动了键盘钩子, 同样是键盘钩子就会进入同一个表. 这个表(可能不止一个, 可能还会有鼠标钩子等等)就是传说中的"钩子链".
假如某个钩子链中共进来了三个钩子(譬如是: 钩子A、钩子B、钩子C 依次进来), 最后进来的 "钩子C" 会先执行.是不是先进后出? 我觉得应该说成: 后进先出! 这有区别吗? 有! 因为先进来的不一定出得来.最后进了的钩子会最先得到执行, 先前进来的钩子(钩子A、钩子B)能不能得到执行那还得两说, 这得有正在执行的 "钩子C" 说了算.如果 "钩子C" 的函数中包含了 CallNextHookEx 语句, 那么 "钩子A、钩子B" 就有可能得以天日; 不然就只有等着相应的UnhookWindowsHookEx 来把它们带走(我想起赵本山的小品...).
这时你也许会想到: 这样太好了, 我以后就不加 CallNextHookEx , 只让自己的钩子"横行"; 但如果是你的钩子先进去的呢?所以 Windows 建议: 钩子函数要调用 CallNextHookEx, 并把它的返回值当作钩子函数自己的返回值.
CallNextHookEx 同时要给钩子链中的下一个(或许应该叫上一个)钩子传递参数(譬如在键盘消息中按了哪个键). 一个键盘钩子和鼠标钩子的参数一样吗? 当然不一样, 所以它们也不在一个 "链" 中啊; 同一个链中的钩子的类型肯定是一样的.
再聊聊钩子函数的返回值:
在这之前, 钩子函数的返回值, 我们都是遵循 Windows 的惯例, 返回了 CallNextHookEx 的返回值.如果 CallNextHookEx 成功, 它会返回下一个钩子的返回值, 是个连环套;如果 CallNextHookEx 失败, 会返回 0, 这样钩子链也就断了, 只有当前钩子还在执行任务.
不同类型的钩子函数的返回值是不同的, 对键盘钩子来讲如果返回一个非 0 的值, 表示它处理完以后就把消息给消灭了.换句话说:如果给键盘的钩子函数 Result := 0; 说明消息被钩子拦截并处理后就给 "放" 了;如果给键盘的钩子函数 Result := 1; 说明消息被钩子拦截并处理后又给 "杀" 了.
在下面的例子中, 我们干脆不使用 CallNextHookEx (反正暂时就我一个钩子), 直接给返回值!这是接下来例子的演示动画:
动画中, 我在三种状态下分别给 Memo 输入了字母 a当没启动钩子时, Memo 是可以正常输入的;
当钩子函数返回 0, 钩上以后, 先执行了钩子函数的功能(返回键值), 字母 a 也能输入成功;
当钩子函数返回非 0 值(譬如1), 钩上以后, 就只执行了钩子函数的功能(返回键值), 可怜的 Memo 不知道发生了什么.
但这里又有了新问题: 钩子函数返回键值时怎么...不是一个?
先提醒: 在前面用 Beep 测试时, 你有没有发现那个声音也不只一次, 这是一个道理.
因为按一次键就会发出两个消息: WM_KEYDOWN、WM_KEYUP, 我们没有指定拦截哪个, 就都拦截了.
那怎么区分这两个消息呢? 秘密在键盘钩子函数的第三个参数 lParam 里面, 等下一个话题再研究吧.
- //示例代码:
- unit Unit1;
- interface
- uses
- Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
- Dialogs, StdCtrls;
- type
- TForm1 = class(TForm)
- Button1: TButton;
- Button2: TButton;
- Memo1: TMemo;
- procedure FormDestroy(Sender: TObject);
- procedure Button1Click(Sender: TObject);
- procedure Button2Click(Sender: TObject);
- end;
- {钩子函数声明}
- function MyKeyHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
- var
- Form1: TForm1;
- implementation
- {$R *.dfm}
- var
- hook: HHOOK;
- function MyKeyHook(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT;
- begin
- Form1.Memo1.Lines.Add(IntToStr(wParam)); {参数二是键值}
- Result := 0; {分别测试返回 0 或非 0 这两种情况}
- end;
- {派出钩子}
- procedure TForm1.Button1Click(Sender: TObject);
- begin
- hook := SetWindowsHookEx(WH_KEYBOARD, MyKeyHook, HInstance, GetCurrentThreadId);
- Memo1.Clear;
- Text := '钩子启动';
- end;
- {收回钩子}
- procedure TForm1.Button2Click(Sender: TObject);
- begin
- UnhookWindowsHookEx(hook);
- Text := '钩子关闭';
- end;
- {如果忘了收回钩子...}
- procedure TForm1.FormDestroy(Sender: TObject);
- begin
- if hook<>0 then UnhookWindowsHookEx(hook);
- end;
- end.