COMMIT TRANSACTION (Transact-SQL)

本主题适用于:是SQL Server(从 2008 开始)否Azure SQL 数据库否Azure SQL 数据仓库否并行数据仓库

标志一个成功的隐性事务或显式事务的结束。 如果 @@TRANCOUNT 为 1,COMMIT TRANSACTION 使得自从事务开始以来所执行的所有数据修改成为数据库的永久部分,释放事务所占用的资源,并将 @@TRANCOUNT 减少到 0。 如果 @@TRANCOUNT 大于 1,则 COMMIT TRANSACTION 使 @@TRANCOUNT 按 1 递减并且事务将保持活动状态。

 
适用范围:SQL Server(SQL Server 2008 至当前版本),Azure SQL Database。

Topic link icon Transact-SQL 语法约定

  
COMMIT [ { TRAN | TRANSACTION } [ transaction_name | @tran_name_variable ] ] [ WITH ( DELAYED_DURABILITY = { OFF | ON } ) ]  
[ ; ]  

transaction_name
SQL Server 数据库引擎忽略此参数。 transaction_name 指定由前面的 BEGIN TRANSACTION 分配的事务名称。 transaction_name 必须符合标识符规则,但不能超过 32 个字符。 transaction_name 通过向程序员指明 COMMIT TRANSACTION 与哪些 BEGIN TRANSACTION 相关联,可作为帮助阅读的一种方法。

@tran_name_variable
用户定义的、含有有效事务名称的变量的名称。 必须用 charvarcharnchar 或 nvarchar 数据类型声明变量。 如果传递给该变量的字符数超过 32,则只使用 32 个字符,其余的字符将被截断。

DELAYED_DURABILITY
请求将此事务与延迟持续性一起提交的选项。 如果已用 DELAYED_DURABILITY = DISABLED 或 DELAYED_DURABILITY = FORCED 更改了数据库,则忽略该请求。 有关详细信息,请参阅主题控制事务持续性

仅当事务引用的所有数据在逻辑上都正确时,Transact-SQL 程序员才应发出 COMMIT TRANSACTION 命令。

如果所提交的事务是 Transact-SQL 分布式事务,COMMIT TRANSACTION 将触发 MS DTC 使用两阶段提交协议,以便提交所有涉及该事务的服务器。 如果本地事务跨越同一数据库引擎实例上的两个或多个数据库,则该实例将使用内部的两阶段提交来提交所有涉及该事务的数据库。

当在嵌套事务中使用时,内部事务的提交并不释放资源或使其修改成为永久修改。 只有在提交了外部事务时,数据修改才具有永久性,而且资源才会被释放。 当 @@TRANCOUNT 大于 1 时,每发出一个 COMMIT TRANSACTION 命令只会使 @@TRANCOUNT 按 1 递减。 当 @@TRANCOUNT 最终递减为 0 时,将提交整个外部事务。 因为 transaction_name 被数据库引擎忽略,所以当存在显著内部事务时,发出一个引用外部事务名称的 COMMIT TRANSACTION 只会使 @@TRANCOUNT 按 1 递减。

当 @@TRANCOUNT 为 0 时发出 COMMIT TRANSACTION 将会导致出现错误;因为没有相应的 BEGIN TRANSACTION。

不能在发出一个 COMMIT TRANSACTION 语句之后回滚事务,因为数据修改已经成为数据库的一个永久部分。

仅当事务计数在语句开始处为 0 时,数据库引擎才会增加语句内的事务计数。

要求具有 public 角色的成员身份。

A.提交事务

以下示例删除候选作业。

USE AdventureWorks2012;  
GO  
BEGIN TRANSACTION;  
GO  
DELETE FROM HumanResources.JobCandidate  
    WHERE JobCandidateID = 13;  
GO  
COMMIT TRANSACTION;  
GO  

B.提交嵌套事务

以下示例创建一个表,生成三个级别的嵌套事务,然后提交该嵌套事务。 虽然每个 COMMIT TRANSACTION 语句都具有一个 transaction_name 参数,但 COMMIT TRANSACTION 与 BEGIN TRANSACTION 语句之间没有关系。 transaction_name 参数仅是帮助阅读的方法,可帮助程序员确保提交的正确号码被编码以便将 @@TRANCOUNT 减少到 0,从而提交外部事务。

USE AdventureWorks2012;  
GO  
IF OBJECT_ID(N'TestTran',N'U') IS NOT NULL  
    DROP TABLE TestTran;  
GO  
CREATE TABLE TestTran (Cola int PRIMARY KEY, Colb char(3));  
GO  
-- This statement sets @@TRANCOUNT to 1.  
BEGIN TRANSACTION OuterTran;  
GO  
PRINT N'Transaction count after BEGIN OuterTran = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  
INSERT INTO TestTran VALUES (1, 'aaa');  
GO  
-- This statement sets @@TRANCOUNT to 2.  
BEGIN TRANSACTION Inner1;  
GO  
PRINT N'Transaction count after BEGIN Inner1 = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  
INSERT INTO TestTran VALUES (2, 'bbb');  
GO  
-- This statement sets @@TRANCOUNT to 3.  
BEGIN TRANSACTION Inner2;  
GO  
PRINT N'Transaction count after BEGIN Inner2 = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  
INSERT INTO TestTran VALUES (3, 'ccc');  
GO  
-- This statement decrements @@TRANCOUNT to 2.  
-- Nothing is committed.  
COMMIT TRANSACTION Inner2;  
GO  
PRINT N'Transaction count after COMMIT Inner2 = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  
-- This statement decrements @@TRANCOUNT to 1.  
-- Nothing is committed.  
COMMIT TRANSACTION Inner1;  
GO  
PRINT N'Transaction count after COMMIT Inner1 = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  
-- This statement decrements @@TRANCOUNT to 0 and  
-- commits outer transaction OuterTran.  
COMMIT TRANSACTION OuterTran;  
GO  
PRINT N'Transaction count after COMMIT OuterTran = '  
    + CAST(@@TRANCOUNT AS nvarchar(10));  
GO  

BEGIN DISTRIBUTED TRANSACTION (Transact-SQL)
BEGIN TRANSACTION (Transact-SQL)
COMMIT WORK (Transact-SQL)
ROLLBACK TRANSACTION (Transact-SQL)
ROLLBACK WORK (Transact-SQL)
SAVE TRANSACTION (Transact-SQL)
@@TRANCOUNT (Transact-SQL)

评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值