Hive DML 数据库定义，表定义等操作

数据导入

向表中装载数据

1．语法

load data [local] inpath '/opt/module/datas/student.txt' [overwrite] | into table student [partition (partcol1=val1,…)];
（1）load data:表示加载数据
（2）local:表示从本地加载数据到 hive 表；否则从 HDFS 加载数据到 hive 表
（3）inpath:表示加载数据的路径
（4）overwrite:表示覆盖表中已有数据，否则表示追加
（5）into table:表示加载到哪张表
（6）student:表示具体的表
（7）partition:表示上传到指定分区

2．实操案例

（1）创建一张表

create table student(id string, name string) row format delimited fields terminated by '\t';

（2）加载本地文件到 hive

load data local inpath 'student.txt' into table student;

（3）加载 HDFS 文件到 hive 中  上传文件到 HDFS

hive(test)> dfs -put 'student.txt' '/hive/student';
加载 HDFS 上数据
load data inpath '/hive/student.txt' into table student;

（4）加载数据覆盖表中已有的数据上传文件到 HDFS

hive(test)> dfs -put 'student.txt' '/hive/student';
加载数据覆盖表中已有的数据
load data inpath 'student.txt' overwrite into table student;

通过查询语句向表中插入数据（Insert）

1．创建一张分区表

create table student_partition(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

2．基本插入数据

insert into table student_partition partition(month='202005')values(1, 'zhangsan');
insert into table student_partition partition(month='202004')values(2, 'lisi');

3．基本模式插入（根据单张表查询结果）

insert overwrite table student_partition partition(month='202005') select id, name from student_partition where month='202004';

4．多插入模式（根据多张表查询结果）

多表插入的关键点在于将所要执行查询的表语句 "from 表名"，放在最开头位置。

from student_partition
insert overwrite table student_partition partition(month='202005') select id,name where month = '202005'
insert overwrite table student_partition partition(month='202004') select id,name where month = '202005';

查询语句中创建表并加载数据（As Select）

根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student_partition;

创建表时通过 Location 指定加载数据路径

1．创建表，并指定在 hdfs 上的位置

create table if not exists student5(id int, name string) 
row format delimited fields terminated by ' '  
location '/hive/student5';

2．上传数据到 hdfs 上

hive> dfs -put student.txt /hive/student5;

3．查询数据

hive> select * from student5;

Import 数据到指定 Hive 表中

注意：先用 export 导出后，再将数据导入。

hive> import table student5 partition(month='202005') from '/hive/student5';

数据导出

Insert 导出

1．将查询的结果导出到本地

insert overwrite local directory '/root/data' select * from student;

2．将查询的结果格式化导出到本地

insert overwrite local directory 'root/data' row format delimited fields terminated by '\t'
select * from student;

3．将查询的结果导出到 HDFS 上(没有 local)

insert overwrite directory '/root/data' row format delimited fields terminated by '\t'
select * from student;

Hive Shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本 > file）

[hive]$ bin/hive -e 'select * from default.student;' > /root/data/student4.txt;

Export 导出到 HDFS 上

export table student to '/hive/student';

清除表中数据（Truncate）

注意：Truncate 只能删除管理表，不能删除外部表中数据

truncate table student;