SAP ABAP ALV进阶

ALV

一．ALV概要

首先介绍下什么是ALV，在R/3 4.6C之前ALV全称为ABAP List Viewer，在其后的版本中，已经正式更名为SAP List Viewer。ALV是SAP系统中心的列表标准，可以在ABAP程序中进行报表输出。除去传统列表的显示和少量交互功能之外，ALV还提供给系统用户多种其它丰富的交互功能。

使用ALV有两种方式，一种为传统的Call Function，另一种为面向对象的编程，为了有良好的编程习惯和跟随SAP技术的发展，在此，强烈推荐使用面向对象的编程来实现ALV，在此，本文档也是根据此来写的。

下面是一个ALV的用户界面（系统例子BCALV_FULLSCREEN_DEMO），可以分为三个部分：

 

1.ALV菜单栏 

2.ALV标题栏 

3.ALV网格控制器

                             （根据用户需要，可以隐藏ALV标题栏以及ALV菜单栏）

 

ALV网格控制器

ALV标题栏

ALV菜单栏

 

 

 

 

1．ALV菜单栏

 

 

 细节按钮，你首先必须选中列表中的一行，然后点击它的话，就会弹出一个窗口，显示选中行的细节内容。（另外：你双击你要选择的行，也可以显示细节）

 按升序排列，首先选中一列，然后再点击它，就可以看到该列是按照升序重新排列。

 按降序排列，首先选中一列，然后再点击它，就可以看到该列是按照降序重新排列。

 设置过滤器，通过设置它可以达到筛选的目的，以列名称作为筛选的筛选标准，填入过滤器相应的标准值，然后就可以筛选出满足自己条件的记录。

 打印预览，点击它之后，就可以预览一下将要打印内容的布局情况。

 Microsoft Excel，调用MS的Excel到当前ALV的列表显示区域。（前提：必须安装了MS的Excel）

 字处理，字处理的相关设置。

 本地文件，将当前表单存储到本地机器上，有几种供选择的存储格式。

 邮件收件人，给系统内用户发邮件

 图形，点击它可以根据表单情况绘制相关图表。

 更改布局，点击它可以对表单中的列项目排列次序的互换，删减等。

 选择布局，从以及保存的布局中选择自己满意的布局。

 保存布局，对于自己满意的布局，可以通过点击它来将布局保存起来。

 

 

 

 

 

 

 

 

2．ALV标题栏

  这个区域主要是用来显示一些抬头信息（总揽信息），类似于WORD中的页眉。我们在使用的时候根据需要来进行相关填写。

 

3．网格控制器

这个区域主要使用来显示我们通过代码写筛选出来的数据，相关的操作在下面的程序编写部分详细介绍。

 

 

二．ALV起步

ALV GRID CONTROL (ALV网格控制器)

 

    ALV GRID CONTROL使用了控制器技术以实现精美的屏幕显示,像所有的控制器一样，ALV GRID CONTROL通过系统中的一个全局类提供的方法,以响应它的动作.

   使用了ABAP的对象以后,列表是通过ALV的一个实例(INSTANCE)来显示的,程序员可以使用ABAP对象的事件管理.

 

ALV GRID相关的几个控制结构

 

1.字段目录  [Field catalog]

字段目录是用来控制ALV显示的网格中每个字段的属性的,比如字段的顺序,对齐方式,可编辑状态,颜色,等等.

参考结构 LVC_S_FCAT

2. 布局控制[layout]

       布局是用来控制整个ALV的一个布局，比如ALV的标题,是否可编辑,行颜色,列颜色.

参照ALV的控制结构[LVC_S_LAYO],以后的例子我将详细介绍如何设置行颜色和列    颜色.

3. 打印和排序,过滤控制（不常用，略过）

     打印的参数控制请参考结构 [LVC_S_PRNT]

     排序的参数控制请参考结构[LVC_S_SORT]

     过滤的参数控制请参考结构[LVC_S_FILT]

创建ALV的必要条件

    创建一个ALV，有两个条件是必须的，布局的话,应该是可以不设置的,使用默认的就可以了。

1,字段目录

这个是必须的,如果没有这个参数,参考一个数据字典也是可以的,就是参数      I_STRUCTURE_NAME.

2.存放数据的内表

最好内表的结构和字段目录是一致的,否则可能会出现一些无法预知的错误,当然你说我非要不一样,那也不一定会出现错误.我建议是最好一样的.

 

ALV简单示例一（例子的实现及各类事件响应都能在28服务器上zalv_test1中找到，     事物代码zalvtest1）

 

面向对象的ALV GRID必须存在于一个容器当中,就是FUNCTION的ALV,其实也是一样的,底层也是使用CL_GUI_ALV_GRID这个类的.

 

第一步:创建个SCREEN,在屏幕上创建个容器,CONTAINER.定义变量.

 

DATA:

WCL_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER,      "存放ALV的容器  WCL_ALV TYPE REF TO CL_GUI_ALV_GRID ,                      "ALV的网格

  GT_FIELDCAT TYPE LVC_T_FCAT ,                              "存放字段目录的内表

  GS_LAYOUT TYPE LVC_S_LAYO .                               "布局结构

*----声明需要显示的内表(以SFLIGHT为例)

DATA BEGIN OF gt_list OCCURS 0 .

     INCLUDE STRUCTURE SFLIGHT .

DATA END OF gt_list .

 

第二步: 创建ALV这个对象，它的父组件是那个容器.

     在PBO中写入如下代码:

 

         PROCESS BEFORE OUTPUT .
             MODULE display_alv .

 

创建DISPLAY_ALV的MODULE后,写下如下代码:        

         PERFORM display_alv .
         

 

在FORM DISPLAY_ALV中,判断ALV实例是否存在,如果不存在,

否存在,如果不存在,则创建:

    IF  WCL_ALV IS INITIAL .

    CREATE OBJECT: WCL_CONTAINER

     EXPORTING

CONTAINER_NAME = 'WCL_CONTAINER'.

    CREATE OBJECT WCL_ALV

     EXPORTING

       I_PARENT = WCL_CONTAINER. 

 

*获取字段目录

PERFORM PREPARE_FIELD_CATALOG CHANGING GT_FIELDCAT .    

*获取样式

PERFORM PREPARE_LAYOUT CHANGING GS_LAYOUT .                  

*获取需要显示的数据

PERFORM GET_DATA TABLES GT_LIST.                                        

 

*-----显示ALV-------------------------------------------（详细的用法在最后附录）

    CALL METHOD WCL_ALV->SET_TABLE_FOR_FIRST_DISPLAY

EXPORTING

* I_BUFFER_ACTIVE =

* I_CONSISTENCY_CHECK =

* I_STRUCTURE_NAME =

* IS_VARIANT =

* I_SAVE =

* I_DEFAULT = 'X'

IS_LAYOUT = GS_LAYOUT

* IS_PRINT =

* IT_SPECIAL_GROUPS =

* IT_TOOLBAR_EXCLUDING =

* IT_HYPERLINK =

CHANGING

IT_OUTTAB = GT_LIST[]

IT_FIELDCATALOG = GT_FIELDCAT

* IT_SORT =

* IT_FILTER =

EXCEPTIONS

INVALID_PARAMETER_COMBINATION = 1

PROGRAM_ERROR = 2

TOO_MANY_LINES = 3

OTHERS = 4 .

  ELSE .

*----------------------------刷新ALV----------------------（详细的用法在最后附录）

    CALL METHOD WCL_ALV->REFRESH_TABLE_DISPLAY

* EXPORTING

* IS_STABLE =

* I_SOFT_REFRESH =

    EXCEPTIONS

    FINISHED = 1

    OTHERS = 2 .

    IF SY-SUBRC <> 0.

*--异常处理

    ENDIF.

 

  ENDIF .

 

第三步,获取要显示数据的字段目录.有两种方式.

1.手动创建

FORM prepare_field_catalog CHANGING pt_fieldcat TYPE lvc_t_fcat .
DATA ls_fcat type lvc_s_fcat .
ls_fcat-fieldname = 'CARRID' .
ls_fcat-inttype = 'C' .
ls_fcat-outputlen = '3' .
ls_fcat-coltext = 'Carrier ID' .
ls_fcat-seltext = 'Carrier ID' .
APPEND ls_fcat to pt_fieldcat .
CLEAR ls_fcat .
ls_fcat-fieldname = 'CONNID' .
ls_fcat-ref_table = 'SFLIGHT' .
ls_fcat-ref_table = 'CONNID' .
ls_fcat-outputlen = '3' .
ls_fcat-coltext = 'Connection ID' .
ls_fcat-seltext = 'Connection ID' .
APPEND ls_fcat to pt_fieldcat .
ENDFORM .

2.根据结构自动创建

FORM PREPARE_FIELD_CATALOG  CHANGING GT_FIELDCAT TYPE LVC_T_FCAT.

DATA ls_fcat type lvc_s_fcat .

CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'

EXPORTING

i_structure_name = 'SFLIGHT'  ？？？？ 

CHANGING

ct_fieldcat = GT_FIELDCAT[]

EXCEPTIONS

inconsistent_interface = 1

program_error = 2

OTHERS = 3.

IF sy-subrc <> 0.

*--Exception handling

ENDIF.

ENDFORM .                    "prepare_field_catalog

第四步,设置布局

 

FORM prepare_layout CHANGING ps_layout TYPE lvc_s_layo.
    ps_layout-zebra = 'X' .
    ps_layout-grid_title = 'Flights' .
    ps_layout-smalltitle = 'X' .
ENDFORM. " prepare_layout 

 

第五步，读取数据至内表

 

FORM GET_DATA  TABLES   RT_OUTTAB  LIKE GT_LIST[].

SELECT * FROM SFLIGHT INTO CORRESPONDING FIELDS

OF TABLE RT_OUTTAB UP TO 30 ROWS.

ENDFORM.

 

 

至此，一个最简单的面向对象的ALV创建完毕。

 

 

 

三．ALV进阶

功能一：排除不需要的ALV菜单栏按钮

 

   在你的ALV上，如果你想排除一些你不想要的标准按钮,你可以把需要排除的按钮填入到表UI_FUNCTIONS中,然后传给set_table_for_first_display方法的参数"IT_TOOLBAR_EXCLUDING".这些按钮的功能码一般都可以通过查看类cl_gui_alv_grid的常量属性中获取到,或者自己加个断点，在after_user_command事件中.

 

    如果你要隐藏全部的工具条,你可以把layout中的no_toolbar设置为"X".

 

FORM exclude_tb_functions CHANGING pt_exclude TYPE ui_functions .
     DATA ls_exclude TYPE ui_func.
     ls_exclude = cl_gui_alv_grid=>mc_fc_maximum .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_fc_minimum .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_fc_subtot .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_fc_sum .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_fc_average .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_mb_sum .
     APPEND ls_exclude TO pt_exclude.
     ls_exclude = cl_gui_alv_grid=>mc_mb_subtot .
ENDFORM .

 

功能二:设置排序条件

 

   有时候我们需要使用到数据的排序.这个可以通过填充参考结构LVC_T_SORT创建的内表来实现，这个内表中包含了排序的标准.可以传递给set_table_for_first_display这个方法的IT_SORT参数来初始化一个排序.

 

 FORM prepare_sort_table CHANGING pt_sort TYPE lvc_t_sort .
  DATA LS_SORT TYPE LVC_S_SORT .

  LS_SORT-SPOS = '1' .

  LS_SORT-FIELDNAME = 'PAYMENTSUM' .

  LS_SORT-UP = 'X' . "A to Z

  LS_SORT-DOWN = SPACE .

  APPEND LS_SORT TO PT_SORT .
ENDFORM. " prepare_sort_table

 

如果这边排序的字段名，不存在于字段目录中，那将出现ABAP DUMP.

    也可以通过使用方法“get_sort_criteria” 和“set_sort_criteria”来获取和设置排序的标准.

 

功能三:设置过滤

  

   ALV的标准按钮中已经有过滤的功能,我们也可以在初始显示的时候就设置过滤条件.我们需要把过滤条件填充到参考表类型"LVC_T_FILT"创建的内表中.过滤条件是类似一个RANGES结构的.然后把这个内表传递给方法"SET_TABLE_FOR_FIRST_DISPLAY"中的参数"IT_FILTER"

 

FORM PREPARE_FILTER_TABLE CHANGING PT_FILT TYPE LVC_T_FILT .

  DATA LS_FILT TYPE LVC_S_FILT .

  LS_FILT-FIELDNAME = 'FLDATE' .

  LS_FILT-SIGN = 'E' .

  LS_FILT-OPTION = 'BT' .

  LS_FILT-LOW = '20080101' .     “最高日期    

  LS_FILT-HIGH = '20001231' .     “最低日期    

  APPEND LS_FILT TO PT_FILT .

ENDFORM. " preparefiltertable

    我们可以使用"get_filter_criteria" 和"set_filter_criteria"来获取过滤条件和设置过滤条件.

功能四:选择方式

 

   有时候，我们需要选择一些单元格,行或者列,在布局中，有个参数"SEL_MODE"可以设置我们不同的选择方式.下面是参数的介绍.和不同的地方.

 

值	模式	可能的选择	注释
SPACE	等同于B	参考B	默认设置
'A'	行和列的选择,无法选择单元格	多行，多列	用户可以使用最左边的选择按钮来选择多行
'B'	单选,不可以多选行,不可以多选单元格	多行，多列
'C'	多选,可以多选行,不可以多选单元格	多行，多列
'D'	单元格的选择,可以多选单元格	多行，多列,任何单元格多选	用户可以使用最左边的选择按钮来选择多行

 

WARNING!!!

  1.如果你设置了ALV是可编辑的,可能会覆盖你在布局中选择方式的设置的.

  2.设置了选择方式以后,我们可以使用很多方法来获取用户的选择.比如"GET_SELECTED_CELLS","GET_SELECTED_CELLS_ID","GET_SELECTED_ROWS","GET_SELECTED_COLUMNS"

  3.在执行PAI以后,用户所选择的单元格,行或者列可能丢失.你可以在PBO中,使用对应的SET方法来恢复这些选择.

 

功能五:颜色设置

 

有的时候,我们需要在ALV网格上绘上一些颜色.可以给特定的行，某个特定的列,某个特定的单元格绘制颜色.如果某列被设置为关键列,这列的颜色将被自动绘制,而不需要我们额外的指定.

    先介绍ALV的色码.就是颜色编码,4位CHAR型.

常见的色码是Cxxx，第一位C代表英文Color的缩写，第二位则是颜色的代码，可以参照下表，第三位是加强设置，第四位是相反，个人理解，在强化关闭的情况下，相反的作用是背景和字体的变化。

 

x	颜色	主要使用在
1	Gray-blue	headers
2	Light gray	List bodies
3	yellow	totals
4	Blue-green	Key columns
5	green	Positive threshold value
6	red	Negative threshold value
7	orange	Control levels

 

A)设置列的颜色.

 

   我们可以通过字段目录的"emphasize"控制字段来控制某列的颜色.这个字段同样是4位的CHAR型,传入上述的颜色编码.例如:

 

LS_FCAT-EMPHASIZE = 'C701'.

 

如果这列被设置为关键列,就是    LS_FCAT-KEY = 'X' ,那么颜色设置就不会起作用.请注意,自动产生的字段目录中，KEY的设置是自动获取的.

 

B)设置行的颜色

  

  为某行设置颜色,是有点复杂的,我们需要在要显示的数据内表中增加一个字段,这个字段不需要在字段目录中存在.同样,这个字段也是4位的CHAR型,符合颜色编码的定义.

  那我们就需要这样来定义我们的数据内表:

 

DATA BEGIN OF  CC_SFLIGHT  OCCURS 0 .
     ……..                             
     DATA rowcolor(4) TYPE c .
DATA END OF CC_SFLIGHT .

 

  很明显，填入颜色编码以后,ALV怎么知道它是我们用来设置颜色的呢,在布局中，有个控制字段"INFO_FNAME",我们可以设置这个字段来告诉ALV,我们的颜色字段是哪个.

 

ps_layout-info_fname = 'ROWCOLOR'.

 

  请注意,这个字段随便你起名字,但是记住,一定是数据内表里的字段，而且这边设置的时候一定要大写.你可以在任何时候设置行的颜色,只需要去修改内表里的这个字段的值,但是记得,一定要刷新以后才起作用.

 

功能六:插入超链接

 

    插入超链接是通过一个含有超级链接和句柄的表来实现的.这个表类型为"LVC_T_HYPE" ,句柄是一个INT4类型的字段,我们需要在数据显示的内表中，加入这样的字段，来告诉ALV,我们的字段指定的句柄,从而找到对应的超级链接.在字段目录中,WEB_FIELD是用来指定对应的句柄名的.

 

   下面举个例子来说明,我们要为字段CARRID建立超级链接:

 

首先,内表定义中，我们加入2个句柄字段:

DATA BEGIN OF CC_SFLIGHT OCCURS 0 .
………………
DATA carrid_handle TYPE int4 .
DATA END OF CC_SFLIGHT .

第二: 建立一个超级链接内表,里面存放句柄所对应的超级链接.创建的时候注意,它参考的表类型,一定是"LVC_T_HYPE".

 

FORM prepare_hyperlinks_table CHANGING pt_hype TYPE lvc_t_hype .
DATA ls_hype TYPE lvc_s_hype .
   ls_hype-handle = '1' .
   ls_hype-href = 'http://www.company.com/carrids/car1' .
   APPEND ls_hype TO pt_hype .
   ls_hype-handle = '2' .
   ls_hype-href = 'http://www.company.com/carrids/car1' .
   APPEND ls_hype TO pt_hype .
ENDFORM .

 

第三.通过字段目录FIELDCATLOG来指定相应的句柄字段.

 

对于CARRID的field catalog

Ls_fieldcat-web_field = ‘CARRID_HANDLE’.

在方法"SET_TABLE_FOR_FIRST_DISPLAY"中把句柄内表传给参数it_hyperlink。

 

 

第四:在数据显示的内表中，指定对应的句柄:

 

  LOOP AT CC_SFLIGHT INTO WA_SFLIGHT.

    IF WA_SFLIGHT-CARRID = 'AA'.

WA_SFLIGHT-CARRID_HANDLE = '1'.

    ELSE.

WA_SFLIGHT-CARRID_HANDLE = '2'.

    ENDIF.

    MODIFY CC_SFLIGHT FROM WA_SFLIGHT.

  ENDLOOP.

 

功能七:把字段设置为下拉

 

     有时候我们可以把一些字段设置为下拉，比如一些类型，一些字段的值是比较固定的一些值,当然,我们也可以通过搜索帮助来做,这些只是看各自的爱好和需要了.

   设置为下拉,和上一篇设置超级链接是类似的,也是使用了一个内表存放了句柄和对应的值,这个表类型为"LVC_T_DROP".不过传递给ALV的方式有点区别.超级链接是通过方法"SET_TABLE_FOR_FIRST_DISPLAY"的参数来传递的,而下拉的内表传递需要使用方法"SET_DROP_DOWN_TABLE".

   如果我们希望把这个列都设置为下拉,那么我们可以在字段目录中，把控制字段"DRDN_HNDL"指向对应的下拉内表的句柄就可以了.例如:

 

     LS_FCAT-drdn_hndl = '1' .

 

如果是某个单元格设置为下拉，那我们就需要在数据显示的内表中增加一个句柄字段(如果是有多个不同的字段需要设置下拉,可以增加多个字段),同时得在字段目录里设置"DRDN_FIELD".例如:

 

    LS_FCAT-drdn_field = 'PTYP_DD_HNDL' .

 

数据显示内表定义为:

 

DATA BEGIN OF CC_SFLIGHT OCCURS 0 .
………………
DATA ptype_dd_hndl TYPE int4 .
DATA END OF CC_SFLIGHT .

 

定义下拉的句柄内表:

 

  FORM PREPARE_DRILLDOWN_VALUES.

  DATA LT_DDVAL TYPE LVC_T_DROP .

  DATA LS_DDVAL TYPE LVC_S_DROP .

  LS_DDVAL-HANDLE = '1' .

  LS_DDVAL-VALUE = 'JFK-12' .

  APPEND LS_DDVAL TO LT_DDVAL .

  LS_DDVAL-HANDLE = '1' .

  LS_DDVAL-VALUE = 'JSF-44' .

  APPEND LS_DDVAL TO LT_DDVAL .

  LS_DDVAL-HANDLE = '1' .

  LS_DDVAL-VALUE = 'KMDA-53' .

  APPEND LS_DDVAL TO LT_DDVAL .

  LS_DDVAL-HANDLE = '1' .

  LS_DDVAL-VALUE = 'SS3O/N' .

  APPEND LS_DDVAL TO LT_DDVAL .

  CALL METHOD WCL_ALV->SET_DROP_DOWN_TABLE

    EXPORTING

      IT_DROP_DOWN = LT_DDVAL.

ENDFORM. " prepare_drilldown_values

 

 

准备好内表，以后,使用方法set_drop_down_table来传递给ALV.

 

 

 

 

 

ALV高级使用

    作为使用面向对象的方法开发的一个组件,ALV GRID控制器有很多响应用户交互的事件.这些事件经常被用来增强一些用户响应的功能.为实现这样的功能，我们必须在程序中创建一个类的实例来作为ALV GRID实例的事件处理者.

 

    下表列出了一些ALV GRID的事件,后面的HTML列用来说明是否在HTML形式SAP GUI上支持.

 

用户定义文本输出:

 

Event	Application	HTML
Print_end_of_list	Define output text to be printed at the end of the entire list	√
Print_top_of_list	Define output text to be printed at begin of the entire list	√
Print_top_of_page	Define output text to be printed at begin of each page	√
Print_end_of_page	Define output text to be printed at the end of each page	√
Subtotal_text	Define self-defined subtotal   texts	√

 

ALV GRID的鼠标动作事件

 

Event	Application	HTML
Button_click	Query click on a push button in the ALV GRID control	√
Double_click	Query a double click on a cell of the ALV GRID	√
Hotspot_click	Query a hotspot click on columns defined for this purpose in advance	√
Ondrag	Collect information when elements of the ALV GRID Control are dragged	×
Ondrop	Process information when elements of the ALV GRID Control are dropped	×
ondropComplete	Perform final actions after successful drag&drop	×
ondropGetFlavor	Distinguish between options for drag&drop behavior	×

 

自定义和标准功能实现

 

Event	Application	HTML
Before_user_command	Query self-defined and standard functions	√
User_command	Query self-defined function codes	√
After_user_command	Query self-defined and standard functions codes	√

 

自定义功能的定义(自定义按钮,菜单等等)

 

Event	Application	HTML
Tool bar	Change,delete or add gui elements on alv grid	√
Menu_button	Define menus for menu buttons in the toolbar	√
Context_menu_request	Change context menu	×
Onf1	Define self-defined f1 help	√

 

下面是一段代码,例举说明如果定义我们的事件处理类，可以根据实际需求定制。

 

首先声明类

 

CLASS lcl_event_handler DEFINITION.

 PUBLIC SECTION.

METHODS:

*--在ALV的工具条上增加新的按钮

Handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid

    IMPORTING e_object e_interactive,

*--实现用户命令

Handle_user_command

       FOR EVENT user_command OF cl_gui_alv_grid

IMPORTING e_ucomm,

*--热点点击控制

Handle_hotspot_click

       FOR EVENT hotspot_click OF cl_gui_alv_grid

IMPORTING e_row_id e_column_id es_row_no,

*--在用户命令触发之前

Handle_before_user_command

   FOR EVENT before_user_command OF cl_gui_alv_grid

IMPORTING e_ucomm,

*--在用户命令触发之后

Handle_after_user_command

   FOR EVENT after_user_command OF cl_gui_alv_grid

IMPORTING e_ucomm,

*--在ALV可修改的情况下,控制数据修改

Handle_data_changed

   FOR EVENT data_changed OF cl_gui_alv_grid

IMPORTING er_data_changed,

*--在数据修改完成之后

 Handle_data_changed_finished

   FOR EVENT data_changed_finished OF cl_gui_alv_grid

IMPORTING e_modified,

*--管理菜单

Handle_menu_button

   FOR EVENT menu_button OF cl_gui_alv_grid

IMPORTING e_object e_ucomm,

*--管理按钮点击

Handle_button_click

   FOR EVENT button_click OF cl_gui_alv_grid

IMPORTING e_objec e_ucomm.

ENDCLASS.

 

其次是类的实现的一些概要代码,参数可以从ALV的事件中直接获取出来。

 

CLASS lcl_event_handler IMPLEMENTATION.

*-- Handle toolbar

 METHOD handle_toolbar.

    PERFORM handle_toolbar USING e_object e_interactive.

 ENDMETHOD.

*-- Handle hotspot click

 METHOD handle_hotspot_click.

    PERFORM handle_hotspot_click USING e_row_id e_column_id es_row_no.

 ENDMETHOD.

*-- Handle double click

 METHOD handle_double_click.

    PERFORM handle_double_click USING e_row e_column es_row_no.

 ENDMETHOD.

*-- Handle after user command

 METHOD handle_after_user_command.

    PERFORM handle_after_user_command USING e_object.

 ENDFORM.

*-- Handle before user command

 METHOD handle_before_user_command.

    PERFORM handle_before_user_command.

 ENDMETHOD.

*--Handle data changed

 METHOD handle_data_changed.

    PERFORM handle_data_changed USING er_data_changed.

 ENDMEHTOD.

*--Handle data changed finished

 METHOD handle_data_changed_finished.

     PERFORM handle_data_chaged USING e_modified.

 ENDMETHOD.

*--Handle menu button

 METHOD handle_menu_button.

     PERFORM handle_menu_button USING e_object e_ucomm.

 ENDMEHTOD.

*--Handle button click

 MEHTOD handle_button_click.

     PERFORM handle_button_click USING e_objcet e_ucomm.

 ENDMETHOD.

ENDCALSS.

 

光定义了这些还不够,我们需要把事件管理类注册到ALV GRID的实例事件.

 

DATA gr_event_handler TYPE REF TO lcl_event_handler .

.. ..

*--Creating an instance for the event handler

CREATE OBJECT gr_event_handler .

*--Registering handler methods to handle ALV Grid events

SET HANDLER gr_event_handler->handle_user_command FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_toolbar FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_menu_button FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_double_click FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_hotspot_click FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_button_click FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_before_user_command

FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_context_menu_request

FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_data_changed FOR gr_alvgrid .

SET HANDLER gr_event_handler->handle_data_changed_finished

FOR gr_alvgrid .

 

1.热点事件(单击事件)

 

    前面在介绍字段目录的时候,我们说到,在某个字段的控制字段"HOTSPOT"设置为"X",那么这个字段就可以接受单击事件HOTSPOT_CLICK.这个HOTSPOT_CLICK事件有三个参数,其中第一个参数"E_ROW_ID"已经作废,另外2个参数是:参考类型LVC_S_COL定义的"E_COLUMN_ID",可以通过E_COLUMN_ID-FIELDNAME来反映当前点击的字段名. 参考类型LVC_S_ROID定义的"ES_ROW_NO",可以通过ES_ROW_NO-ROW_ID来反映当前点击的行号,从而可以定位鼠标的位置.

 

1．  首先定义抽象类

CLASS lcl_event_handler DEFINITION.

PUBLIC SECTION.

METHODS:

*--热点点击控制

Handle_hotspot_click

FOR EVENT hotspot_click OF cl_gui_alv_grid

IMPORTING e_row_id e_column_id es_row_no.

ENDCLASS.

 

2．  然后实现该类

CLASS lcl_event_handler IMPLEMENTATION.

*-- Handle hotspot click

 METHOD handle_hotspot_click.

    PERFORM handle_hotspot_click USING e_row_id e_column_id es_row_no.

 ENDMETHOD.

ENDCLASS.

 

3．  注册ALV GRID事件实例

FORM EVENTLOAD .

  DATA GR_EVENT_HANDLER TYPE REF TO LCL_EVENT_HANDLER .

  CREATE OBJECT GR_EVENT_HANDLER .

  SET HANDLER GR_EVENT_HANDLER->HANDLE_HOTSPOT_CLICK FOR WCL_ALV .

ENDFORM.                    " EVENTLOAD

 

4.       实现单击方法

FORM HANDLE_HOTSPOT_CLICK  USING    P_E_ROW_IDTYPE lvc_s_row

                                    P_E_COLUMN_ID TYPE lvc_s_col

                                    P_ES_ROW_NO TYPE lvc_s_roid.

   READ TABLE CC_SFLIGHT INTO wa_SFLIGHT INDEX P_E_ROW_ID.

    IF sy-subrc = 0 AND P_E_COLUMN_ID-fieldname = 'PRICE'.

       MESSAGE S001(Test).

    ENDIF.

ENDFORM.                    " handle_hotspot_click

 

   2.双击事件

 

     双击事件和单击事件的处理是类似的,同样也是3个参数.我们不需要设置字段目录就可以响应双击事件了.

 

     下面是示例:

 

FORM handle_double_click USING i_row TYPE lvc_s_row

                              I_column TYPE lvc_s_col

                              Is_row_no TYPE lvc_s_rowid.

    READ TABLE gt_list INDEX is_row_no-row_id.

    IF sy-subrc = 0 AND i_column-fieldname = ‘SEATSOCC’.

      MESSAGE S001(Test).

    ENDIF.

ENDFORM.

 

3.添加自定义的按钮和响应命令

 

     我们在ALV的工具条上增加一些按钮来增加我们自定义的功能,当然也可以在GUI状态中增加,2种的处理方式是不一样的.

     我们通过toolbar事件来增加按钮,然后通过user_command事件来实现我们自定义的功能.

 

     在TOOLBAR事件里,我们把自定义的按钮加到参数"e_object"的表属性"mt_toolbar"中可以了.下面是一段示例代码:

 

FORM HANDLE_TOOLBAR  USING    P_E_OBJECT TYPE REF TO CL_ALV_EVENT_TOOLBAR_SET
                              P_E_INTERACTIVE.
DATA: LS_TOOLBAR TYPE STB_BUTTON.
CLEAR LS_TOOLBAR.
MOVE 3 TO LS_TOOLBAR-BUTN_TYPE.
APPEND LS_TOOLBAR TO P_E_OBJECT->MT_TOOLBAR.
CLEAR LS_TOOLBAR.
MOVE 'PER' TO LS_TOOLBAR-FUNCTION.
MOVE ICON_DISPLAY_TEXT TO LS_TOOLBAR-ICON.
MOVE 'Passenger Info'(201) TO LS_TOOLBAR-QUICKINFO.
MOVE 'Passenger Info'(201) TO LS_TOOLBAR-TEXT.
MOVE ' ' TO LS_TOOLBAR-DISABLED.
APPEND LS_TOOLBAR TO P_E_OBJECT->MT_TOOLBAR.
CLEAR LS_TOOLBAR.
MOVE 'EXCH' TO LS_TOOLBAR-FUNCTION.
MOVE 2 TO LS_TOOLBAR-BUTN_TYPE.
MOVE ICON_CALCULATION TO LS_TOOLBAR-ICON.
MOVE 'Payment in other Curencies'(202) TO LS_TOOLBAR-QUICKINFO.
MOVE ' ' TO LS_TOOLBAR-TEXT.
MOVE ' ' TO LS_TOOLBAR-DISABLED.
APPEND LS_TOOLBAR TO P_E_OBJECT->MT_TOOLBAR.
ENDFORM.                    " handle_toolbar

 

增加自定义按钮的结构如下:

Field	Description
FUNCTION	功能代码
BUTN_TYPE	按钮类型 可用的按钮类型: 0Button(normal) 1Menu and default button 2Menu 3分割符 4Radio button 5Checkbox 6Menu entry
ICON	按钮图标(可选)
TEXT	按钮文本(可选)
QUICKINFO	按钮的悬停文本(可选)
DISABLED	灰化

 

4.覆盖标准的功能.

 

      ALV也给我们提供了修改标准功能的机会.为了实现这个目的,我们需要在"before_user_command"事件中截取标准的功能,然后使用方法"set_user_command"来修改功能码,可以指向自己定义的功能码.

 

   下面是示例:

 

 FORM handle_before_user_command USING i_ucomm TYPE syucomm .
   CASE e_ucomm .
     WHEN '&INFO' .
        CALL FUNCTION 'ZSFLIGHT_PROG_INFO' .
        CALL METHOD gr_alvgrid->set_user_command
            EXPORTING i_ucomm = space.
   ENDCASE .
 ENDFORM .

 

5.设置单元格的风格

style不知道符合翻译为好,这里的style可以在CL_GUI_ALV_GRID的属性中可以查到,分MC_STYLE4_LINK, MC_STYLE4_LINK_NO, MC_STYLE_BUTTON, MC_STYLE_DISABLED,....),包含单元格级别的可编辑/不可编辑,是否有F4,是否有链接,把单元格设置为按钮,单元格级别的热点......

 

     5.1 把单元格设置为PUSHBUTTON

 

      要想实现这个功能，我们需要在数据显示内表增加一个表字段,参考表类型"LVC_T_STYL". 数据实现内表定义增加一条:

 

DATA: CELLSTYLES TYPE LVC_T_STYL. 

 

把需要设置为按钮的字段填进内表字段中:

 

FORM PUSHBUTTON .
DATA LS_STYLE TYPE LVC_S_STYL.
LOOP  AT CC_SFLIGHT INTO WA_SFLIGHT.
  LS_STYLE-FIELDNAME = 'SEATSOCC'.
  LS_STYLE-STYLE = CL_GUI_ALV_GRID=>MC_STYLE_BUTTON.
APPEND LS_STYLE TO WA_SFLIGHT-CELLSTYLES.
MODIFY CC_SFLIGHT FROM WA_SFLIGHT.
ENDLOOP.
ENDFORM.                    " PUSHBUTTON

然后在布局中指定对应的STYLE内表字段,注意字段名字一定要对上:

 

    P_GS_LAYOUT-STYLEFNAME = 'CELLSTYLES'.

 

这里的按钮点击事件和单击事件类似,也是需要2个参数来确定位置.

 

 

5.2 设置单元格级别的可编辑和不可编辑

 

     单元格级别的可编辑和不可编辑是个非常有用的功能,在SAP标准的一些事务中，经常可以看到这些方面的应用.通常用到的比较多的地方,是需要数据验证的,比如输入类型A,后面的某个字段才可以编辑,如果输入了类型B,后面的这个字段就不可编辑.

 

    想让一列可以编辑,我们可以在字段目录中设置EDIT为"X".在可编辑的情况下,ALV会自动多出来几个编辑按钮,删除,新增，插入,复制. 

单元格级别的可编辑和不可编辑，实现起来和5.1是类似的,也是内表字段,参考表类型"LVC_T_STYL".不过填入的style应该为

CL_GUI_ALV_GRID=>MC_STYLE_ENABLED使字段可以编辑,而CL_GUI_ALV_GRID=>MC_STYLE_DISABLED使字段不可以编辑.代码如下:

 

FORM ADJUST_EDITTABLES .
  DATA LS_STYLEROW TYPE LVC_S_STYL.
  DATA LT_STYLETAB TYPE LVC_T_STYL.

  LOOP  AT CC_SFLIGHT INTO WA_SFLIGHT.
    CLEAR:LS_STYLEROW.
    REFRESH:LT_STYLETAB.
    IF WA_SFLIGHT-CARRID = 'AA'.
      LS_STYLEROW-FIELDNAME = 'PAYMENTSUM'.
      LS_STYLEROW-STYLE = CL_GUI_ALV_GRID=>MC_STYLE_DISABLED.
      INSERT LS_STYLEROW INTO TABLE LT_STYLETAB.
    ENDIF.
    IF WA_SFLIGHT-SEATSMAX = 280.
      LS_STYLEROW-FIELDNAME = 'SEATSOCC'.
      LS_STYLEROW-STYLE = CL_GUI_ALV_GRID=>MC_STYLE_DISABLED.
      INSERT LS_STYLEROW INTO TABLE LT_STYLETAB.
    ENDIF.
    WA_SFLIGHT-CELLSTYLES =  LT_STYLETAB .
    MODIFY CC_SFLIGHT FROM WA_SFLIGHT.
  ENDLOOP.
ENDFORM.                    "adjust_edittables 

 

当然也是一样，需要告诉ALV哪个字段是控制STYLE的内表字段.

 

  gs_layout-stylefname = 'CELLSTYLES'.

 

一般情况下,单元格的设置会覆盖整列的设置。如果想在程序里动态切换各种模式。只需要修改内表里关于STYLE设置的值然后刷新.使用方法set_ready_for_input传入参数i_ready_for_input = 1可以是ALV进入编辑状态。

使用这个方法可以使ALV在编辑和不可编辑模式之间切换。显然如果把参数i_ready_for_input设置为0就进入不可编辑状态。

 

 FORM SWITCH_EDIT_MODE.
  IF WCL_ALV->IS_READY_FOR_INPUT( ) = 0.
    CALL METHOD WCL_ALV->SET_READY_FOR_INPUT
      EXPORTING
        I_READY_FOR_INPUT = 1.
  ELSE.
    CALL METHOD WCL_ALV->SET_READY_FOR_INPUT
      EXPORTING
        I_READY_FOR_INPUT = 0.
  ENDIF.
ENDFORM.                               " SWITCH_EDIT_MODE

 

 

 

 

 

 

6. 控制数据变化

 

       我们可以设置alv处于可编辑状态，当然ALV也提供给我们控制数据的输入。Alv grid有两个事件:data_changed和data_changed_finished.第一个事件在可编辑字段的数据发生变化时触发，可用来检查数据的输入，第二个事件是当数据修改完成后触发。

    

我们可以通过方式REGISTER_EDIT_EVENT来设置,如何触发数据改变事件.2种方式:

     1.按回车触发:      i_event_id = cl_gui_alv_grid=>mc_event_enter

     2.单元格失去焦点: i_event_id = cl_gui_alv_grid=>mc_event_modifies

 

必须设置一种方式,要不然数据变化事件不会被触发.

 

为了获取ALV里字段修改的一些信息,DATA_CHANGED事件会把参考CL_ALV_CHANGED_DATA_PROTOCOL创建的实例通过参数ER_DATA_CHANGED传递给ALV.通过这个参数我们可以知道哪些单元格被修改了，修改了什么值.下面是类CL_ALV_CHANGED_DATA_PROTOCOL的一些方法:

Get_cell_value	获取单元格的值
Modify_cell	修改单元格
Add_protocol_entry	增加日志记录
Protocol_is_visible	是否允许错误表可见
Refresh_protocol	刷新日志记录

 

  通过这个类的属性，我们可以查到一些修改信息:

MT_MOD_CELLS	Contains address of modified cells with rowed and field name
MT_MOD_ROWS	Contain modified rows Its type is genric
MT_GOOD_CELLS	Contain cells have proper values
MT_DELETED_ROWS	Contain rows deleted from the list
MT_INSERTED_ROWS	Contain rows deleted from the list

通过上述一系列方式和属性，可以获取修改的值,而进行一些输入的检查.

 

 

下面是一段示例代码:

 

1．类中增加一个事件的方法

HANDLE_DATA_CHANGED FOR EVENT DATA_CHANGED OF CL_GUI_ALV_GRID

            IMPORTING ER_DATA_CHANGED E_ONF4 E_ONF4_BEFORE E_ONF4_AFTER E_UCOMM.

 2．实现这个方法

  METHOD HANDLE_DATA_CHANGED.

    PERFORM HANDLE_DATA_CHANGED USING ER_DATA_CHANGED.

  ENDMETHOD.                    "handle_data_changed

3．注册事件

  SET HANDLER GR_EVENT_HANDLER->HANDLE_DATA_CHANGED FOR WCL_ALV.

4．方法具体实现

FORM HANDLE_DATA_CHANGED USING IR_DATA_CHANGED

                        TYPE REF TO CL_ALV_CHANGED_DATA_PROTOCOL.

  DATA: LS_MOD_CELL TYPE LVC_S_MODI,

         LV_VALUE   TYPE LVC_VALUE.

 

  SORT IR_DATA_CHANGED->MT_MOD_CELLS BY ROW_ID.

  LOOP AT IR_DATA_CHANGED->MT_MOD_CELLS

                         INTO LS_MOD_CELL

                        WHERE FIELDNAME = 'PAYMENTSUM'.

    CALL METHOD IR_DATA_CHANGED->GET_CELL_VALUE

      EXPORTING

        I_ROW_ID    = LS_MOD_CELL-ROW_ID

        I_FIELDNAME = 'PAYMENTSUM'

      IMPORTING

        E_VALUE     = LV_VALUE.

    IFLS_MOD_CELL-VALUE > '999999999'.

      CALL METHOD IR_DATA_CHANGED->ADD_PROTOCOL_ENTRY

        EXPORTING

          I_MSGID     = 'SU'

          I_MSGNO     = '000'

          I_MSGTY     = 'E'

          I_MSGV1     = 'This number can not exceed 999999999 for '

          I_MSGV2     = LV_VALUE

          I_MSGV3     = 'The value is et to ''999999999'''

          I_FIELDNAME = LS_MOD_CELL-FIELDNAME

          I_ROW_ID    = LS_MOD_CELL-ROW_ID.

      CALL METHOD IR_DATA_CHANGED->MODIFY_CELL

        EXPORTING

          I_ROW_ID    = LS_MOD_CELL-ROW_ID

          I_FIELDNAME = LS_MOD_CELL-FIELDNAME

          I_VALUE     = '999999999'.

    ENDIF.

  ENDLOOP.

ENDFORM.                    "handle_data_changed

 

 

 

附件

  1．常用的控制字段如下

2	ROW_POS	ALV 控制: 输出行 (内部使用)
3	COL_POS	ALV 控制: 输出列	列的位置,第几列,例如1,2,…..
4	FIELDNAME	ALV 控制: 内部表字段的字段名称	字段名称
5	TABNAME	LVC 标签名称	表名，如果是内表，是1
6	CURRENCY	ALV 控制: 货币单位
7	CFIELDNAME	ALV 控制: 参考的当前单位的字段名称
8	QUANTITY	ALV 控制: 计量单位
9	QFIELDNAME	ALV 控制: 参考计量单位的字段名称
10	IFIELDNAME	ALV 控制: 内部表字段的字段名称
11	ROUND	ALV 控制: ROUND 值
12	EXPONENT	ALV 控制：流动表示的指数
13	KEY	ALV 控制: 关键字段	关键字段,前面变蓝色
14	KEY_SEL	ALV 控制: 可以被隐藏的关键列	可以被隐藏的关键列
15	ICON	ALV 控制: 作为图标输出	此列作为图标输出
16	SYMBOL	ALV 控制: 输出作为符号
17	CHECKBOX	ALV 控制: 作为复选框输出	复选框输出
18	JUST	ALV 控制: 对齐	对齐方式: 'R': right justified 'L': left justified 'C': centered
19	LZERO	ALV 控制: 输出前导零	X'
20	NO_SIGN	ALV 控制：输出抑制符号	X',不输出符号
21	NO_ZERO	ALV 控制: 为输出隐藏零	X',隐藏0
22	NO_CONVEXT	ALV 控制: 不考虑输出的转换退出
23	EDIT_MASK	ALV 控制: 为输出编辑掩码	格式
24	EMPHASIZE	ALV 控制: 带有颜色的高亮列	列的颜色
25	FIX_COLUMN	ALV 控制: 固定列
26	DO_SUM	ALV 控制: 总计列值	X',合计
27	NO_SUM	ALV 控制: 没有总计列值	X' ,没有合计
28	NO_OUT	ALV 控制: 列没有输出	X' ,隐藏此列
29	TECH	ALV 控制: 技术字段	X'.也是隐藏，但是有点不一样
30	OUTPUTLEN	ALV 控制: 列的字符宽度	输出的长度
31	CONVEXIT	转换例程
32	SELTEXT	ALV 控制: 对话功能的列标识符
33	TOOLTIP	ALV 控制: 列抬头的工具提示
34	ROLLNAME	ALV 控制: F1 帮助的数据元素
35	DATATYPE	ABAP 字典中的数据类型	ABAP 字典中的数据类型
36	INTTYPE	ABAP 数据类型(C,D,N,...)	ABAP 数据类型(C,D,N,...)
37	INTLEN	以字节计的内部长度	内容的长度
38	LOWERCASE	允许/不允许小写字母	X' 允许大小写
39	REPTEXT	标题
40	HIER_LEVEL	ALV 控制: 内部使用
41	REPREP	ALV 控制: 价值是补充/补充接口的选择标准
42	DOMNAME	定义域名
43	SP_GROUP	组代码
44	HOTSPOT	ALV 控制: 单击敏感	X',下面出现下划线,响应单击
45	DFIELDNAME	ALV 控制: 数据库中列组的字段名称
46	COL_ID	ALV 控制: 列 ID
47	F4AVAILABL	字段有输入帮助吗	X'.此列有搜索帮助
48	AUTO_VALUE	ALV 控制: 自动复制值
49	CHECKTABLE	表名
50	VALEXI	固定值存在
51	WEB_FIELD	ALV 控制: 内部表字段的字段名称
52	HREF_HNDL	自然数	热点连接的句柄
53	STYLE	ALV 控制: 样式	下面有例子会介绍,比如PUSHBUTTION
54	STYLE2	ALV 控制: 样式
55	STYLE3	ALV 控制: 样式
56	STYLE4	ALV 控制: 样式
57	DRDN_HNDL	自然数	下拉的句柄
58	DRDN_FIELD	ALV 控制: 内部表字段的字段名称	下拉的字段
59	NO_MERGING	字符字段长度 1	相同的值不合并
60	H_FTYPE	ALV 树控制: 功能类型 (总计,平均,最大.最小, ...)
61	COL_OPT	可选列优化的条目
62	NO_INIT_CH	字符字段长度 1
63	DRDN_ALIAS	字符字段长度 1
64	REF_FIELD	ALV 控制: 内部表字段的参考字段名称
65	REF_TABLE	ALV 控制: 内部表字段的参考表名称
66	TXT_FIELD	ALV 控制: 内部表字段的字段名称
67	ROUNDFIELD	ALV 控制: 带有 ROUND 说明的字段名称
68	DECIMALS_O	ALV 控制: 输出小数位的编号
69	DECMLFIELD	ALV 控制: 带有 DECIMALS 说明的字段名称
70	DD_OUTLEN	ALV 控制: 输出字符长度
71	DECIMALS	小数点后的位数	设置小数的位数
72	COLTEXT	ALV 控制: 列标题	列标题
73	SCRTEXT_L	长字段标签
74	SCRTEXT_M	中字段标签
75	SCRTEXT_S	短字段标签
76	COLDDICTXT	ALV 控制: 确定 DDIC 文本参考
77	SELDDICTXT	ALV 控制: 确定 DDIC 文本参考
78	TIPDDICTXT	ALV 控制: 确定 DDIC 文本参考
79	EDIT	ALV 控制: 准备输入	输出状态.'X'可输入
80	TECH_COL	ALV 控制: 内部使用
81	TECH_FORM	ALV 控制: 内部使用
82	TECH_COMP	ALV 控制: 内部使用
83	HIER_CPOS	ALV 控制: 层次列位置
84	H_COL_KEY	树控制: 列名称/项目名称
85	H_SELECT	标识是否可以选择树控制中的列
86	DD_ROLL	数据元素 (语义域)
87	DRAGDROPID	ALV 控制: 拖&放处理拖放对象
88	MAC	字符字段长度 1
89	INDX_FIELD	自然数
90	INDX_CFIEL	自然数
91	INDX_QFIEL	自然数
92	INDX_IFIEL	自然数
93	INDX_ROUND	自然数
94	INDX_DECML	自然数
95	GET_STYLE	字符字段长度 1
96	MARK	字符字段长度 1

 

2．布局控制[layout]详细的结构说明

 

字段名	描述	Value range
CWIDTH_OPT	最优化宽度	SPACE, 'X'
SMALLTITLE	小标题,如果设置了这个字段， 则标题与列标题大小一样	SPACE, 'X'
GRID_TITLE	标题,在网格和工具条之间	最长70个字符
NO_HEADERS	如果被设置,列标题隐藏	SPACE, 'X'
NO_HGRIDLN	隐藏水平线	SPACE, 'X'
NO_MERGING	禁用单元格合并	SPACE, 'X'
NO_ROWMARK	如果被设置,选择列在选择模式 为D和A的时候隐藏	SPACE, 'X'
NO_TOOLBAR	隐藏工具条	SPACE, 'X'
NO_VGRIDLN	隐藏垂直线	SPACE, 'X'
SEL_MODE	选择模式	SPACE, 'A', 'B', 'C', 'D'
EXCP_CONDS	合计例外	SPACE, 'X'
EXCP_FNAME	字段名称带有例外编码	最长30个字符
EXCP_LED	例外作为 LED	SPACE, 'X'
EXCP_ROLLN	例外文档的数据元素	SPACE, 'X'
CTAB_FNAME	带有复杂单元格颜色编码的字段名称	最长30个字符
INFO_FNAME	带有简单行彩色代码的字段名称	最长30个字符
ZEBRA	可选行颜色,如果设置了，出现了间隔色带	SPACE, 'X'
NO_TOTLINE	没有总计	SPACE, 'X'
NUMC_TOTAL	可以对NUMC字段进行合计	SPACE, 'X'
TOTALS_BEF	总计输出在第一行,小计在新的值之前	SPACE, 'X'
STYLEFNAME	设置单元格,比如PUSHBUTTON	最长30个字符

 

3．方法"set_table_for_first_display"的参数说明

 

参数	含义
I_BUFFER_ACTIVE	如果方法调用是静态的,可以设置这个标记,这表示,如果每次显示ALV都是 相同的字段目录.既然这样，那么字段目录会被放到一个特殊的缓存里, 这样加速了ALV的显示
I_STRUCTURE_NAME	输出数据参考的数据字典的结构名,例如'SFLIGHT'.如果指定了这个参数,字段 目录会自动生成,下面的参数IT_FIELDCATALOG不需要传值.
IS_VARIANT	决定布局显示的变式
I_SAVE	决定用户是否可以保存变式: 'X' 只能保存全局变式 'U' 只能保存特定变式 'A' 都可以保存 SPACE 不可以保存变式
I_DEFAULT	决定用户是否可以定义默认的布局: 'X' 可以定义默认布局,这个参数是默认的 SPACE 不可以定义默认布局
IS_LAYOUT	布局参数,传递布局控制的一些信息
IS_PRINT	后台打印属性的参数
IT_SPECIAL_GROUPS	如果在字段目录中，一些字段通过SP_GROUP被分组在一起.我们就必须为这些 组传递一个组的文本内表进去
IT_TOOLBAR_EXCLUDING	需要隐藏的标准的按钮的内表
IT_HYPERLINK	为每个句柄分配了超连接的内表,LVC_S_HYPE中的HREF存放了超连接的地址, HANDLE指定了句柄,使用这些句柄，你可以在GRID中使用超连接
IT_ALV_GRAPHICS	比较复杂，没有用过,意思好象是可以在图表中显示ALV.
IT_OUTTAB	输出数据存放的内表,数据都是存放在这个内表里
IT_FIELDCATALOG	字段目录
IT_SORT	排序的标准
IT_FILTER	过滤的标准

  

 

4．方法"REFRESH_TABLE_DISPLAY"的参数说明

 

参数	含义
IS_STABLE	刷新的稳定性，有2个参数，一个是行，一个是列.如果设置了相应的值, 那么对应的行，或者列，在刷新的时候,将会保持稳定，就是滚动条保持不动.
I_SOFT_REFRESH	这个参数只是在异常情况下被使用,如果设置了这个参数,任何创建的合计, 任何排序次序,任何为了显示数据而设置的过滤都将保持不变.这个是非常 有意义的.例如:当然你没有修改数据内表里的数据而想刷新ALV,仅仅只是 改变一下布局和字段目录.