自动生成代码实用工具

最新推荐文章于 2021-07-21 15:43:32 发布
最新推荐文章于 2021-07-21 15:43:32 发布
阅读量521 收藏
点赞数
文章标签： 工具 object 存储 insert delete date 
-- =============================================
-- Author:		shipeng.wang
-- Create date: 2010-12-31
-- Description:	根据表名，自动生成增、删、改参数化存储过程和调用代码
-- =============================================
create proc sp_SendCode
@tablename varchar(30),  --表名
@type int=1,			 --类型（1：存储过程，2：调用代码）
@opertype int=1,         --操作类型（1：查，2：增，3：改，4：删）
@fields varchar(2000)='*',--要操作的列（查、增、改时有效，默认操作所有列，多个列用英文逗号隔开）
@where varchar(500)=''   --要作为条件的列（查、改、删时有效，默认为空，多个列名用英文逗号隔开，如：字段1,字段2，其中主键列可以省略）
as
	--不返回受影响的行数，提高性能
	set nocount on
	
	--分别定义主键列,主键列是否自增列,主键列的类型,最后要生成的代码
	declare @keyfield varchar(20),@iden int,@partype varchar(20),@code varchar(4000)
	select @keyfield=c.name,@iden=c.is_identity,@partype=d.name from sys.indexes a,sys.index_columns b,sys.columns c,systypes d
	where  a.object_id=b.object_id and a.index_id=b.index_id and a.object_id=c.object_id and c.user_type_id=d.xtype
	and b.column_id=c.column_id and a.is_primary_key=1 and d.status=0
	and a.object_id=object_id(@tablename) 
	
	--查询时，是否只返回实体对象(1:是，0:不是)
	declare @isflag bit
	set @isflag=0 
	if(@where=@keyfield)
		set @isflag=1
	
	--进行非空处理
	if(not exists(select 1 from sysobjects where id=OBJECT_ID(@tablename)))
	begin
		print '请输入正确的表名！'
		return
	end
	
	--修改的列集合
	declare @updatefields varchar(1000)
	set @updatefields=''
	
	--如果指定了要操作的列，进行校验。防止出现错误列
	if(@fields!='' and @fields!='*')
	begin
		declare @oldfields varchar(200)
		set @fields=REPLACE(@fields,'，',',')
		if(right(@fields,1)!=',')
			set @fields=@fields+','
		set @oldfields=@fields
		set @fields='' 
		--遍历，筛选出@fields中的有效列
		while(CHARINDEX(',',@oldfields)>0)
		begin
			--获取到字段名
			declare @tempf varchar(50) 
			set @tempf=SUBSTRING(@oldfields,1,charindex(',',@oldfields)-1)
			if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@tempf)
			begin
				set @fields=@fields+@tempf+','
				set @updatefields=@updatefields+@tempf+'=@'+@tempf+','
			end
			set @oldfields=SUBSTRING(@oldfields,charindex(',',@oldfields)+1,LEN(@oldfields))
		end
	end
	--如果没有有效字段，或是操作所有字段
	if(@fields='*' or @fields='')
	begin
		set @fields=''
		select @fields=@fields+name+',',@updatefields=@updatefields+case when name!=@keyfield then name+'=@'+name+',' else '' end  
		from syscolumns where id=OBJECT_ID(@tablename)
	end
	
	if(@updatefields!='')
		set @updatefields=STUFF(@updatefields,LEN(@updatefields),1,'')
	
	--保存条件
	declare @tempwhere varchar(200)
	set @tempwhere=''
	--如果有条件时，也对条件进行相同处理
	if(@where!='')
	begin
		declare @oldwhere varchar(200),@tempfield varchar(50) 
		set @where=REPLACE(@where,'，',',')
		if(right(@where,1)!=',')
			set @where=@where+','
		set @oldwhere=@where
		set @where='' 
		--遍历，筛选出@fields中的有效列
		while(CHARINDEX(',',@oldwhere)>0)
		begin
			set @tempfield=SUBSTRING(@oldwhere,1,charindex(',',@oldwhere)-1)
			if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@tempfield)
			begin
				set @tempwhere=@tempwhere+@tempfield+','
				set @where=@where+' and '+@tempfield+'=@'+@tempfield
			end
			set @oldwhere=SUBSTRING(@oldwhere,charindex(',',@oldwhere)+1,LEN(@oldwhere))
		end
	end
	if(@where='' and (@opertype=3 or @opertype=4))
	begin
		--如果没有有效条件，则将主键作为条件
		set @tempwhere=@keyfield+','
		set @where=' and '+@keyfield+'=@'+@keyfield
	end
	
	--生成存储过程
	if(@type=1)
	begin
		--增加时，如果操作列中 存在主键列，并且主键列为自增列时，排除该列
		if(@opertype=2 and CHARINDEX(@keyfield,@fields)>0 and @iden=1)
		begin
			set @fields=stuff(@fields,charindex(@keyfield+',',@fields),LEN(@keyfield+','),'')
		end
		set @fields=stuff(@fields,LEN(@fields),1,'')
		
		--生成存储过程的参数声明
		declare @paras varchar(1000)
		--生成存储过程
		if(@opertype=1) --查询
		begin
			--根据条件来生成
			select @paras=ISNULL(@paras+',' + CHAR(13),'')+'@'+a.name+' '+b.name
			+case when b.name in('varchar','nvarchar','char','nchar') then '('+LTRIM(a.length)+')' else '' end
			 from syscolumns a,systypes b
			where a.id=OBJECT_ID(@tablename) and a.xtype=b.xtype and CHARINDEX(','+a.name+',',','+@tempwhere+',')>0
			and b.status=0
			set @code ='/*-- ============================================='+CHAR(13)+
					   '-- Author:		shipeng.wang'+CHAR(13)+
					   '-- Create date: '+CONVERT(varchar(10),getdate(),120)+CHAR(13)+
					   '-- Description:	对表'+@tablename+'中数据进行查询'+CHAR(13)+
					   '-- =============================================*/'+CHAR(13)
			
			set @code=@code+'create proc [sp_'+@tablename+'_select'+case @isflag when 0 then '' else '_one' end +']'+CHAR(13)+isnull(@paras+ CHAR(13),'')
					 +'as'+CHAR(13)
					 +CHAR(9)+'select '+@fields+' from ['+@tablename +'] where 1=1'+ @where
					 +CHAR(13)
		end
		else if(@opertype=2)--增加
		begin
			--根据添加的字段来生成
			select @paras=ISNULL(@paras+',' + CHAR(13),'')+'@'+a.name+' '+b.name
			+case when b.name in('varchar','nvarchar','char','nchar') then '('+LTRIM(a.length)+')' else '' end
			 from syscolumns a,systypes b
			where a.id=OBJECT_ID(@tablename) and a.xtype=b.xtype and CHARINDEX(','+a.name+',',','+@fields+',')>0
			and b.status=0
			set @code ='/*-- ============================================='+CHAR(13)+
					   '-- Author:		shipeng.wang'+CHAR(13)+
					   '-- Create date: '+CONVERT(varchar(10),getdate(),120)+CHAR(13)+
					   '-- Description:	对表'+@tablename+'中数据进行添加'+CHAR(13)+
					   '-- =============================================*/'+CHAR(13)
			set @code=@code+'create proc [sp_'+@tablename+'_insert]'+CHAR(13)+isnull(@paras+ CHAR(13),'')
					 +'as'+CHAR(13)
					 +CHAR(9)+'insert into ['+@tablename +'] ('+@fields+') values(@'+REPLACE(@fields,',',',@')+')'
					 +CHAR(13)
		end
		else if(@opertype=3) -- 修改
		begin
			
			--如果没有有效条件，则将主键作为条件
			if(@where='')
			begin
				set @tempwhere=@keyfield
				set @where=' and '+@keyfield+'=@'+@keyfield
			end
		
			--根据添加的字段和条件来生成
			select @paras=ISNULL(@paras+',' + CHAR(13),'')+'@'+a.name+' '+b.name
			+case when b.name in('varchar','nvarchar','char','nchar') then '('+LTRIM(a.length)+')' else '' end
			 from syscolumns a,systypes b
			where a.id=OBJECT_ID(@tablename) and a.xtype=b.xtype and (CHARINDEX(','+a.name+',',','+@fields+',')>0 or CHARINDEX(','+a.name+',',','+@tempwhere+',')>0)
			and b.status=0
			set @code ='/*-- ============================================='+CHAR(13)+
					   '-- Author:		shipeng.wang'+CHAR(13)+
					   '-- Create date: '+CONVERT(varchar(10),getdate(),120)+CHAR(13)+
					   '-- Description:	对表'+@tablename+'中数据进行修改'+CHAR(13)+
					   '-- =============================================*/'+CHAR(13)
			set @code=@code+'create proc [sp_'+@tablename+'_update]'+CHAR(13)+isnull(@paras+ CHAR(13),'')
					 +'as'+CHAR(13)
					 +CHAR(9)+'update ['+@tablename +'] set '+@updatefields+' where 1=1'+@where
					 +CHAR(13)
		end
		else if(@opertype=4)
		begin
			--根据条件来生成
			select @paras=ISNULL(@paras+',' + CHAR(13),'')+'@'+a.name+' '+b.name
			+case when b.name in('varchar','nvarchar','char','nchar') then '('+LTRIM(a.length)+')' else '' end
			 from syscolumns a,systypes b
			where a.id=OBJECT_ID(@tablename) and a.xtype=b.xtype and CHARINDEX(','+a.name+',',','+@tempwhere+',')>0
			and b.status=0
			
			set @code ='/*-- ============================================='+CHAR(13)+
					   '-- Author:		shipeng.wang'+CHAR(13)+
					   '-- Create date: '+CONVERT(varchar(10),getdate(),120)+CHAR(13)+
					   '-- Description:	对表'+@tablename+'中数据进行删除'+CHAR(13)+
					   '-- =============================================*/'+CHAR(13)
			set @code=@code+'create proc [sp_'+@tablename+'_delete]'+CHAR(13)+isnull(@paras+ CHAR(13),'')
					 +'as'+CHAR(13)
					 +CHAR(9)+'delete ['+@tablename +'] where 1=1'+@where
					 +CHAR(13)
		end
	end
	--生成C#方法
	else if(@type=2) 
	begin
		--增加、修改时都需要对操作列和条件列声明为参数化
		declare @sqlparameters varchar(3000),@newfield varchar(400)
		set @sqlparameters=''
		if(@opertype=2 or @opertype=3) 
		begin
			--添加操作时，如果主键列是自增的，不需要指定主键列
			if(CHARINDEX(@keyfield,@fields)>0 and @iden=1)
			begin
				set @fields=stuff(@fields,charindex(@keyfield+',',@fields),LEN(@keyfield+','),'')
			end
			--声明参数
			select @sqlparameters=@sqlparameters+CHAR(9)+CHAR(9)+CHAR(9)+CHAR(9)+CHAR(9)+
			'new SqlParameter("@'+a.name+'",SqlDbType.'+
			case b.name when 'varchar' then 'VarChar' when 'bigint' then 'BigInt'
			when 'datetime' then 'DateTime' when 'nvarchar' then 'NVarChar' when 'numeric' then 'Decimal'
			when 'tinyint' then 'TinyInt'
			else UPPER(left(b.name,1))+RIGHT(b.name,len(b.name)-1) end
			+','+ltrim(a.length)+'),'+CHAR(13)
			from syscolumns a,systypes b where a.id=OBJECT_ID(@tablename) and charindex(','+a.name+',',','+@fields)>0 and a.xtype=b.xtype
			and b.status=0
		end
		
		if(@opertype=1 or @opertype=4 or @opertype=3)--查询、修改、删除时需要添加条件参数
		begin
			--声明参数
			select @sqlparameters=@sqlparameters+CHAR(9)+CHAR(9)+CHAR(9)+CHAR(9)+CHAR(9)+
			'new SqlParameter("@'+a.name+'",SqlDbType.'+
			case b.name when 'varchar' then 'VarChar' when 'bigint' then 'BigInt'
			when 'datetime' then 'DateTime' when 'nvarchar' then 'NVarChar' when 'numeric' then 'Decimal'
			when 'tinyint' then 'TinyInt'
			else UPPER(left(b.name,1))+RIGHT(b.name,len(b.name)-1) end +','+ltrim(a.length)+'),'+CHAR(13)
			from syscolumns a,systypes b where a.id=OBJECT_ID(@tablename) and 
			charindex(','+a.name+',',','+@tempwhere)>0 and a.xtype=b.xtype and b.status=0
		end
		if(@sqlparameters!='')
			set @sqlparameters=STUFF(@sqlparameters,len(@sqlparameters)-1,1,'')
		if(@opertype=1)
		begin
			if(@sqlparameters!='')
			begin
				--参数声明
				declare @parselect varchar(200)
				select @parselect=ISNULL(@parselect+',','')+
				case when b.name in('image','uniqueidentifier','ntext','varchar','ntext','nchar','nvarchar','text','char') then 'string'
					when b.name in('tinyint','smallint','int') then 'int'
					when b.name='bigint' then 'long'
					when b.name in('datetime','smalldatetime') then 'DateTime'
					when b.name in('float','decimal','numeric','money','real','smallmoney') then 'decimal'
					when b.name ='bit' then 'bool'
					else b.name end+' '+a.name
				from syscolumns a,systypes b where a.xtype=b.xtype and a.id=OBJECT_ID(@tablename) and CHARINDEX(','+a.name+',',','+@tempwhere)>0
				and b.status=0
				--如果返回多记录
				if(@isflag=0)
				begin
					--生成参数化
					set @code='/// <summary>'+CHAR(13)
							 +'/// 对表'+@tablename+'中数据进行查询 '+CHAR(13)
							 +'/// </summary>'+CHAR(13)+
							 +'/// 以下代码有shipeng.wang存储过程自动生成 ///'+CHAR(13)
							 +'public DataTable GetList('+@parselect+')'+CHAR(13)
							 +'{'+CHAR(13)
							 +char(9)+'SqlParameter[] paras=new SqlParameter[]{'+CHAR(13)+@sqlparameters+CHAR(9)+'};'+CHAR(13)
							 declare @j int
							 set @j=0
							
							--给参数赋值
							while(CHARINDEX(',',@tempwhere)>0)
							begin
								declare @p1 varchar(30)
								set @p1=substring(@tempwhere,1,CHARINDEX(',',@tempwhere)-1)
								if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@p1)
								begin
									select @p1=name from syscolumns where id=OBJECT_ID(@tablename) and name=@p1
									set @code=@code+char(9)+'paras['+LTRIM(@j)+'].Value='+@p1+';'+CHAR(13)
									set @j=@j+1
								end
								set @tempwhere=SUBSTRING(@tempwhere,CHARINDEX(',',@tempwhere)+1,LEN(@tempwhere))
								
							end
							set @code=@code+CHAR(9)+'return db.ExecuteDataTable("sp_'+@tablename+'_select'+'",CommandType.StoredProcedure,paras);'+CHAR(13)
							 +'}'
				end
				else --返回实体
				begin
					--生成参数化
					set @code='/// <summary>'+CHAR(13)
							 +'/// 根据主键获取'+@tablename+'中实体对象'+CHAR(13)
							 +'/// </summary>'+CHAR(13)
							 +'/// 以下代码有shipeng.wang存储过程自动生成 ///'+CHAR(13)
							 +'public '+@tablename+' GetModel('+@parselect+')'+CHAR(13)
							 +'{'+CHAR(13)
							 +char(9)+'SqlParameter[] paras=new SqlParameter[]{'+CHAR(13)+@sqlparameters+CHAR(13)+CHAR(9)+'};'+CHAR(13)
							 set @code=@code+char(9)+'paras[0].Value='+@keyfield+';'+CHAR(13)
							 set @code=@code+CHAR(9)+'SqlDataReader read=db.ExecuteDataReader("sp_'+@tablename+'_select_one'+'",CommandType.StoredProcedure,paras);'+CHAR(13)
							 set @code=@code+CHAR(9)+'if(read!=null && read.Read())'+CHAR(13)
							 set @code=@code+CHAR(9)+'{'+CHAR(13)
							 set @code=@code+CHAR(9)+CHAR(9)+@tablename+' model = new '+@tablename+'();'+CHAR(13)
							 declare @k int 
							 set @k=0
							 declare @t varchar(50)
							 set @fields=@fields+','
							 while(CHARINDEX(',',@fields)>0)
							 begin
								set @t=substring(@fields,1,CHARINDEX(',',@fields)-1)
								select @code=@code+CHAR(9)+CHAR(9)+'model.'+@t+' = read.Get'+
								case when b.name in('image','uniqueidentifier','ntext','varchar','ntext','nchar','nvarchar','text','char') then 'String'
								when b.name in('tinyint','smallint','int') then 'Int32'
								when b.name='bigint' then 'Int64'
								when b.name in('datetime','smalldatetime') then 'DateTime'
								when b.name in('float','decimal','numeric','money','real','smallmoney') then 'Decimal'
								when b.name ='bit' then 'Boolean'
								else b.name end+'('+ltrim(@k)+')'+';'+CHAR(13)
								from syscolumns a,systypes b where a.id=object_id(@tablename) and a.name=@t and a.xtype=b.xtype and b.status=0
								set @k=@k+1
								set @fields=STUFF(@fields,1,CHARINDEX(',',@fields),'')
							 end
							 set @code=@code+CHAR(9)+CHAR(9)+'read.Close();'+CHAR(13)
							 set @code=@code+CHAR(9)+CHAR(9)+'return model;'+CHAR(13)
							 set @code=@code+CHAR(9)+'}'+CHAR(13)
							 set @code=@code+CHAR(9)+'else'+CHAR(13)
							 set @code=@code+CHAR(9)+CHAR(9)+'return null;'+CHAR(13)
							 +'}'
				end
			end
			else
				--生成参数化
				set @code='/// <summary>'+CHAR(13)
						 +'/// 对表'+@tablename+'中数据进行查询 '+CHAR(13)
						 +'/// </summary>'+CHAR(13)
						 +'/// 以下代码有shipeng.wang存储过程自动生成 ///'+CHAR(13)
						 +'public DataTable GetList()'+CHAR(13)
						 +'{'+CHAR(13)
						 +char(9)+'string sql="select * from '+@tablename+'";'+CHAR(13)
						 +CHAR(9)+'return db.ExecuteDataTable(sql);'+CHAR(13)
						 +'}'
		end
		else if(@opertype=2 or @opertype=3)--增加或者修改
		begin
			--生成参数化
			set @code='/// <summary>'+CHAR(13)
					 +'/// 对表'+@tablename+'中数据进行'+case @opertype when 2 then '添加' else '修改' end +CHAR(13)
					 +'/// </summary>'+CHAR(13)
					 +'/// 以下代码有shipeng.wang存储过程自动生成 ///'+CHAR(13)
					 +'/// <param name="model">要'+case @opertype when 2 then '添加' else '修改' end +'的实体对象</param>'+CHAR(13)
					 +'public bool '+case @opertype when 2 then 'insert' else 'update' end +'('+@tablename+' model)'+CHAR(13)
					 +'{'+CHAR(13)
					 +char(9)+'SqlParameter[] paras=new SqlParameter[]{'+CHAR(13)+@sqlparameters+CHAR(9)+'};'+CHAR(13)
			declare @i int
			set @i=0
			--给参数赋值
			while(CHARINDEX(',',@fields)>0)
			begin
				declare @p varchar(30)
				set @p=substring(@fields,1,CHARINDEX(',',@fields)-1)
				if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@p)
				begin
					set @code=@code+char(9)+'paras['+LTRIM(@i)+'].Value=model.'+@p+';'+CHAR(13)
					set @i=@i+1
				end
				set @fields=SUBSTRING(@fields,CHARINDEX(',',@fields)+1,LEN(@fields))			

	
			end
			if(@opertype=3)--修改时，需要加上条件参数
			begin
				--给参数赋值
				while(CHARINDEX(',',@tempwhere)>0)
				begin
					set @p=substring(@tempwhere,1,CHARINDEX(',',@tempwhere)-1)
					if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@p)
					begin
						set @code=@code+char(9)+'paras['+LTRIM(@i)+'].Value=model.'+@p+';'+CHAR(13)
						set @i=@i+1
					end
					set @tempwhere=SUBSTRING(@tempwhere,CHARINDEX(',',@tempwhere)+1,LEN(@tempwhere))
				end
			end
			set @code=@code+CHAR(9)+'return db.ExecuteNonQuery("sp_'+@tablename+'_'+case @opertype when 2 then 'insert' else 'update' end 
			+'",CommandType.StoredProcedure,paras);'+CHAR(13)
			set @code=@code+'}'
		end
		else if(@opertype=4)--删除
		begin
				declare @parselect1 varchar(200)
				select @parselect1=ISNULL(@parselect1+',','')+
				case when b.name in('image','uniqueidentifier','ntext','varchar','ntext','nchar','nvarchar','text','char') then 'string'
					when b.name in('tinyint','smallint','int') then 'int'
					when b.name='bigint' then 'long'
					when b.name in('datetime','smalldatetime') then 'DateTime'
					when b.name in('float','decimal','numeric','money','real','smallmoney') 
					then 'decimal'
					when b.name ='bit' then 'bool'
					else b.name end+' '+a.name
				from syscolumns a,systypes b where a.xtype=b.xtype and a.id=OBJECT_ID(@tablename) and CHARINDEX(','+a.name+',',','+@tempwhere)>0
				and b.status=0
				
				--生成参数化
				set @code='/// <summary>'+CHAR(13)
						 +'/// 对表'+@tablename+'中数据进行删除'+CHAR(13)
						 +'/// </summary>'+CHAR(13)
						 +'/// 以下代码有shipeng.wang存储过程自动生成 ///'+CHAR(13)
						 +'public bool delete('+@parselect1+')'+CHAR(13)
						 +'{'+CHAR(13)
						 +char(9)+'SqlParameter[] paras=new SqlParameter[]{'+CHAR(13)+@sqlparameters+CHAR(9)+'};'+CHAR(13)
				declare @h int
				set @h=0
				--给参数赋值
				while(CHARINDEX(',',@tempwhere)>0)
				begin
					set @p=substring(@tempwhere,1,CHARINDEX(',',@tempwhere)-1)
					if exists(select 1 from syscolumns where id=OBJECT_ID(@tablename) and name=@p)
					begin
						set @code=@code+char(9)+'paras['+LTRIM(@h)+'].Value='+@p+';'+CHAR(13)
						set @h=@h+1
					end
					set @tempwhere=SUBSTRING(@tempwhere,CHARINDEX(',',@tempwhere)+1,LEN(@tempwhere))
				end
				
				set @code=@code+CHAR(9)+'return db.ExecuteNonQuery("sp_'+@tablename+'_delete",CommandType.StoredProcedure,paras);'+CHAR(13)
				set @code=@code+'}'
		end
	end
	print @code
go

调用示例

1、比如要生成对Customer表的增加操作，因为增加时，是不需要条件的，所以不需要指定where参数，@field不指定就是添加所有字段。

首先生成增加的存储过程：

exec sp_SendCode 'Customer',1,2

其次生成调用的c#代码（其中有使用到dbhelper类，这个就自己封装下吧）：

exec sp_SendCode 'Customer',2,2

 

2、如果要生成对Customer表的查询操作，根据ID进行查询，且返回所有字段

首先生成查询的存储过程：

exec sp_SendCode 'Customer',1,1,'*','id'

其次生成调用的c#代码（其中有使用到dbhelper类，这个就自己封装下吧）：

exec sp_SendCode 'Customer',2,1,'*','id'

 

修改和删除大家可以自行根据参数说明去传参，如果在条件字段或者是返回字段中有错误字段，会自行排除。。。

huijunliang
关注
代码自动生成工具
10-15
文件是我优化过的代码自动生成工具，相关教程可以查看我的博客https://blog.csdn.net/qq_25814003/article/details/83062246
自动生成前端代码工具（所见即所得）.zip
09-16
标题中的“自动生成前端代码工具（所见即所得）”指的是一个软件或程序，它能够帮助开发者快速生成前端代码，而无需手动编写每一行代码。这种工具通常具有图形用户界面，用户可以通过拖拽、选择预设样式或者设置参数...
.NET代码生成工具
weixin_33670713的博客
06-13 155
当前版本1.1.0.0 功能概述： 1.根据数据库架构生成代码：利用NVelocity模板引擎，支持自定义模板内置标签方法。     可以根据个人业务需求，生成任何格式的代码。     自定义标签方法放在程序InsideStaticLabel\PowerEasy.CodeMakerLibrary.InsideStaticLabel.cs文件。该文件的方法会动...
生成生成代码的工具（python实现）
weixin_30622181的博客
10-29 264
在应用开发中，我们经常会通过工具生成一些代码以提高开发效率，而本文则通过python将正常代码转成生成该代码的工具，并自动将原始代码类名、函数名等转成参数，目前只支持c#语言（待优化），一下是python工具代码： 1 #!/usr/bin/ python 2 # -*- coding:utf-8 -*- 3 #操作同路径下的所有.cs .lua文件，并生成自动生成该cs文件的...
代码生成工具
Connie1451的博客
04-09 216
补充一个java版本的代码生成器,功能十分强大,适合生成各种语言的代码包括但不限于增删改查,高级特性中甚至可以结合IDE调试模板;作者通过了很多现成的开放模板;工具操作起来十分简单易懂官方网站:magicalcoder.com...
自动生成代码工具
12-05
在IT行业中，自动生成代码工具是一种能够显著提升开发效率、减少人为错误的实用技术。"自动生成代码工具"，如标题所示，主要是针对WCF（Windows Communication Foundation）框架中的常见类进行自动化创建，以帮助...
单片机代码自动生成工具
08-26
单片机代码自动生成工具是针对STM32单片机学习成本高、底层代码设计重复繁琐、移植和使用不方便、以及Keil5开发收费等问题而开发，通过代码自动生成技术根据用户需求完成单片机底层代码的自动生成，并提供了一些常用...
Java 代码生成工具
09-29
基于数据库表，根据模板一键生成dao层、service层、controller层代码，可以直接拷贝到项目里面就可以运行访问添加的接口 生成工具类的源码也已经提供可以参考，这个我自己5年Java开发一直使用的代码生成工具
SQL语句自动生成工具
04-16
支持几乎所有类型的数据库，包括小型（桌面）数据库：Fox DBF、Microsoft Execl、Text、Borland Paradox、中型数据库：Microsoft Access大型数据库：Microsoft SQL Server、Sybase、Oracle数据库的连接采取ADO方式故而使用本工具，无需安装和卸载 支持几乎所有的SQL语法：排序(Order By)条件(Where)分组(Group By)分组条件(Having)计算字段SQL查询表SQL查询子句丰富的函数表别名字段别名(包括计算字段和非计算字段)联合(Union，对于Oracle 支持Union All,Minus,Intersect)支持将SQL查询语句，替换为插入(Insert into)和更新(Update)语句 附属工具内嵌入Delphi IDE
DBHelper
06-03
DBHelper简单介绍：<br/><br/>　　1.为你显示数据库中表、存储过程、函数信息、视图信息。<br/><br/>　　2.你可以在DBHelper程序中使用查询分析器中的添加、删除、修改表、存储过程、函数、视图功能.<br/><br/>　　3.你可以使用DBHelper根据表、视图来生成C#或VB.NET类代码.<br/><br/>　　4.你可以使用DBHelper根据表、视图自动生成存储过程,为你节约手写存储过程的时间.<br/><br/>　　5.你可以使用DBHelper根据表、视图自动生成C#或VB.NET操作方法,让DBHelper自动为你生成操作方法和操作数据库的SQL语句.<br/><br/>　　6.你可以使用DBHelper根据数据库中已有的存储过程生成C#或VB.NET操作方法,让你不用再小心翼翼的进行存储过程参数定义或赋值.
代码生成工具：
专注Java（全栈）应用开发，求知若渴，虚心若愚，talk is cheap, show me the code.
09-20 146
代码自动生成工具layuicodetool
简单代码生成工具
热门推荐
一只秋田犬
07-21 1万+
代码生成 我们做项目的时候，经常会碰到写一些基础的增删改查代码，所以就写了个代码生成的工具，可根据自己的需求编写相应的代码模板。 大致思路 查询表信息，通过字段类型映射出 java 类型，然后通过模板生成 java 文件 1. 查看表信息 通过执行 SHOW FULL COLUMNS FROM table_name可以看到表的详细信息 所关注的字段有3个：FieId,Type,Comment 字段、类型、备注，有了这三个字段后，就可以进行下一步操作了，类型映射生成实体类。 2. 生成实体类 首先把
FairyGUI与Unity集成代码自动生成插件详解
资源摘要信息:"FairyGUI & Unity 代码自动生成工具及自定义编辑包" FairyGUI 是一款功能强大的游戏UI编辑工具，它允许游戏开发者通过可视化的方式快速创建复杂的UI界面，并且支持多种平台和游戏引擎。Unity作为最...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值