批量建立sql server的计划任务

批量建立sql server的计划任务，首先在所在的数据库上建立下面两个存储过程，其中第一个是主存储过程，第二个可以根据自己的需要改写，本例以 IS60DB为数据库名来说明

USE [IS60DB]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

/*
负责建立计划的存储过程
*/
create proc [dbo].[UP_createjob]
@jobname varchar(100),--作业名称
@sql varchar(8000),--要执行的命令
@dbname sysname='',--默认为当前的数据库名
@freqtype varchar(6)='day',--时间周期,month 月,week 周,day 日
@fsinterval int=1,--相对于每日的重复次数
@time int=170000--开始执行时间,对于重复执行的作业,将从0点到23:59分 1点的话 010000(相当于时分秒拼起来)
as
if isnull(@dbname,'')='' set @dbname=db_name()
--判断作业是否存在
if exists(select * from msdb.dbo.sysjobs
where name=@jobname)
begin
--如果作业存在则先删除原来作业
EXECUTE msdb..sp_delete_job @job_name = @jobname
end
--创建作业
exec msdb..sp_add_job @job_name=@jobname
--创建作业步骤
exec msdb..sp_add_jobstep @job_name=@jobname,
@step_name = '数据处理',
@subsystem = 'TSQL',
@database_name=@dbname,
@command = @sql,
@retry_attempts = 5, --重试次数
@retry_interval = 5 --重试间隔
--创建调度
declare @ftype int,@fstype int,@ffactor int
select @ftype=case @freqtype when 'day' then 4
when 'week' then 8
when 'month' then 16 end
,@fstype=case @fsinterval when 1 then 0 else 8 end
if @fsinterval<>1 set @time=0
set @ffactor=case @freqtype when 'day' then 0 else 1 end
--特殊处理，每间隔1小时执行的类型设置
if(@jobname='数据预警每小时')
 set @fstype=8
EXEC msdb..sp_add_jobschedule @job_name=@jobname,
@name = '时间安排',
@freq_type=@ftype , --每天,8 每周,16 每月
@freq_interval=1,--重复执行次数
@freq_subday_type=@fstype,--是否重复执行
@freq_subday_interval=@fsinterval, --重复周期
@freq_recurrence_factor=@ffactor,
@active_start_time=@time --下午17:00:00分执行
-- 添加目标服务器
EXEC msdb..sp_add_jobserver
@job_name = @jobname,
@server_name = N'(local)'

----------
/*
批量建立计划任务
*/
create proc [dbo].[UP_Batchcreatejob]
as
exec UP_createjob '数据校验每天1点','exec Task_DataVerify','IS60DB','day',1,10000
exec UP_createjob '数据预警每小时','exec Task_DataExpectWarn','IS60DB','day',1,00500
exec UP_createjob '统计每年数据每月第一天1点35分','exec Task_SiteDataCountByYear','IS60DB','month',1,13500
exec UP_createjob '统计每天数据1点20分','exec Task_SiteDataCountByDay','IS60DB','day',1,12000
exec UP_createjob '统计每月数据每月第一天1点30分','exec Task_SiteDataCountByMonth','IS60DB','month',1,13000
exec UP_createjob '统计每周数据每周第一天1点25分','exec Task_SiteDataCountByweek','IS60DB','week',1,12500
exec UP_createjob '站点数据统计每天1点15','exec Task_SiteDataCount','IS60DB','day',1,11500

---end---

上面的建好后，就可以 运行 exec UP_Batchcreatejob 来批量建立计划任务了，也可以在安装程序或其它地方调用这个sql来建立计划任务