王爽《汇编语言》第三版 实验7 代码

欢迎扫码关注微信公众号
回复关键字【资料】获取各种学习资料

assume cs:codesg
;将整个data段看作是一个数组，长度一共为
;21*4+21*4+2*21=168+42=210字节
data segment
    db '1975', '1976', '1977', '1978', '1979', '1980', '1981', '1982', '1983'
    db '1984', '1985', '1986', '1987', '1988', '1989', '1990', '1991', '1992'
    db '1993', '1994', '1995'
    ;长度为84的数组，一个字符一个字节：4X21

    dd 16, 22, 382, 1356, 2390, 8000, 16000, 24486, 50065, 97479, 140417, 197514
    dd 345980, 590827, 803530, 1183000, 1843000, 2759000, 3753000, 4649000, 5937000

    dw 3, 7, 9, 13, 28, 38, 130, 220, 476, 778, 1001, 1442, 2258, 2793, 4037, 5635, 8226
    dw 11542, 14430, 15257, 17800
data ends

;ax+210/16向上取整，即ax+14h
;对于ds，偏移量为16*14=224
table segment
    db 21 dup('year summ ne ?? ')
table ends

stack segment
    dw 1 dup(0)
stack ends

codesg segment
start:  mov ax, data
        mov ds, ax 
        mov bx, table
        mov es, bx  
        mov bx, 0   ;定位结构体数组元素
        mov di, 0   ;定位data中的4字节数据
        mov si, 0   ;定位data中的2字节数据
        mov cx, 15h
    s:  ;转移年份
        mov ax, ds:[di];
        mov es:[bx], ax
        mov ax, ds:[di+2]
        mov es:[bx+2], ax
        ;添加空格 
        mov byte ptr es:[bx+4], 32

        ;转移收入
        ;作为被除数
        mov ax, ds:[di+84];
        mov es:[bx+5], ax
        mov ax, ds:[di+86]
        mov es:[bx+7], ax
        ;添加空格 
        mov byte ptr es:[bx+9], 32

        ;转移雇员数量
        mov ax, ds:[si+168]
        mov es:[bx+10], ax
        ;添加空格 
        mov byte ptr es:[bx+12], 32

        ;计算人均收入，并转移到table中
        mov ax, es:[bx+5]   ;低16位
        mov dx, es:[bx+7]   ;高16位
        div word ptr es:[bx+10]
        mov es:[bx+13], ax  ;商默认存放在ax中 
        ;添加空格 
        mov byte ptr es:[bx+15], 32 

        ;操作完成，bx加16，di加2
        add bx, 16  
        add di, 4
        add si, 2
        loop s

        mov ax, 4c00h
        int 21h
codesg ends
end start

简单分析：

ds段寄存器用来存放data段数据，es段寄存器，用来存放table段数据

观察data段的数据我们可以发现，前168个字节的数据都是双字的（4字节），最后的42字节数据是单字的，所以我们不能用同一个寄存器来同时定位这两种不同的数据
因此，我们是用di寄存器，来定位data段中的双字数据，用si寄存器来定位data段中的单字数据，使用bx寄存器来定位table段中的每一行，使用[bx+idata]的形式，来定位每一行中的每个字节

运行效果：

红色方框圈起来的部分，依次为：收入、雇员数量、人均收入、年份