用Parsley实现Flex Ioc的简单例子

随着spring的流行，Ioc的概念开始大范围的普及。而Flex中也有不少实现Ioc的第三方工具，比如：ProfileViewer, Spring ActionScript, Parsley, Flicc, Swiz等等。看过7yue的博文说adobe的咨询团队比较推荐Parsley，不过看到官方文档对第一接触Ioc概念的初学者，个人觉得还是有点晦涩。

 

我用parsley做了个简单的例子，供初学者参考：

parsley官网:http://www.spicefactory.org/parsley/

 

新建Flex工程IoCdemo

 

下载2.0.1的zip包，将里面的parsley-complete-flex-2.0.1.swc, spicelib-complete-flex-2.0.1.swc 放入libs目录下。（spicelib还提供了反射的库，值得学习一下）

 

在src下创建包:net.risesoft.flex.demo（注：此处是包名不是件文件夹名，因为在src下文件名支持字符“.”，FB还不会提示错误）拷入如下的代码。

 

主文件和配置文件放在src下。

 

Company接口： 

package net.risesoft.flex.demo
{
	public interface Company
	{
		function payWagesByEmployeeType(type:String):int;
	}
}

 

Company接口的实现类一：

package net.risesoft.flex.demo
{
	public class RegularCompany implements Company
	{
		public function payWagesByEmployeeType(type:String):int
		{
			trace('按时发工资');
			return 7000;
		}
		
	}
}

 

Company接口的实现类二：

package net.risesoft.flex.demo
{
	public class RiseSoft implements Company
	{
		public var companyName:String = "有生";
		
		public function payWagesByEmployeeType(type:String):int
		{
			if(type=='老总')
			{
				trace('按时发工资。');
				return 3*10000;
			}
			else if(type=='离职员工')
			{
				trace('拖你没商量，人都走了还给你发钱？门都没！告法院都没用，等着吧，等个一年两年的哪天我高兴了给你发点。');
				return 0;
			}
			else if(type=='在职员工')
			{
				trace('能拖则拖，连续6个月不发，这是正常情况。');
				return 0;
			}
			else
			{
				var err : Error = new Error("无理取闹，只有我A别人钱，没有别人A我钱的哦");
				throw err;
			}
		}
	}
}

 

Employee类：

package net.risesoft.flex.demo
{
	public class Employee
	{
		public var type:String;
		
		[Inject(id="company")]
		public var company:Company;
		
		public function getPay():int
		{
			return company.payWagesByEmployeeType(type);
		}
	}
}

 

配置文件contextConfig.mxml:

<?xml version="1.0" encoding="utf-8"?>
<mx:Object 
    xmlns:mx="http://www.adobe.com/2006/mxml"
    xmlns:services="net.risesoft.flex.demo.*" >
 	<services:RiseSoft id="company"/>
 	<services:Employee type="在职员工" id="employee" />
</mx:Object> 

 

主文件IoCdemo.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
				layout="absolute"
				applicationComplete="main()">
	<mx:Script>
		<![CDATA[
			import net.risesoft.flex.demo.Company;
			import net.risesoft.flex.demo.Employee;
			import org.spicefactory.parsley.core.Context;
			import org.spicefactory.parsley.flex.FlexContextBuilder;
			private function main(): void
			{
				var context:Context = FlexContextBuilder.build(contextConfig);
				var employee:Employee = context.getObject("employee") as Employee;
	
				//本月情况
				try
				{
					if(employee.getPay() <= 0)
						trace('我打算去告公司');
				}
				catch (err:Error)
				{
					trace(err.message);
				}
			}
		]]>
	</mx:Script>
</mx:Application>

 

弄完以后按F11，即可看到结果

 

Ioc一个主要好处是通过接口来实现模块之间的解耦，而通过对配置文件的解读来装配具体的实现类。以上面的例子来说，这样的好处就是当我想换新公司的时候，只要将配置文件中的RiseSoft改成RegularCompany即可达到正常发工资的要求。源代码如下，FB3工程

 

Flex Ioc各种实现工具比较：http://www.adobe.com/devnet/flex/articles/ioc_frameworks.html?devcon=f1

7yue博客：http://www.7yue.com/post/358.html

 

 

如果想了解更多Ioc知识可以看看java的Ioc的文章，我就不献丑了