自动配置IP工具

每次上班和回寝室上网，由于IP设置不同不能正常上网，每次都要做重新配置IP。在Windows 操作系统上，控制面板—网络连接—本地连接右击属性—常规—Internet 协议（TCP/IP） 进行手动的设置。一两次操作还好，每每这么操作感觉有点傻瓜化，自己都是学软件开发的，能这么跟它玩，所以早上还没开始上班就想想通过什么简便的方式来简化这一系列的操作。

本来想上传附件IPset.bat ——就是生成的 bat 批处理程序，但好像不允许，所以就把代码贴出来。

IPset.bat 文件的详细代码如下：

@echo off
rem 关闭回显

cls
rem 清屏幕命令（CLS，CLear Screen）：清除屏幕上的所有显示。

color 0A
rem color [attr] :设置默认的控制台前景和背景颜色。
rem attr :指定控制台输出的颜色属性,颜色属性由两个十六进制数字表示——第一个为背景，第二个则为前景。每个数字可以为一下任何值之一：
rem 0=黑 ，1=蓝 ，2=绿 ，3=湖蓝 ，4=红 ，5=紫 ，6=黄 ，7=白 ，8=灰 ，9=淡蓝 ，A=淡绿 ，B=淡浅绿 ，C=淡红 ，D=淡紫 ，E=淡黄 ，F=亮白

echo ########################################################################
echo IP地址配置工具
echo ########################################################################
set IP=192.168.137.7
set MASK=255.255.0.0
set GATEWAY=192.168.137.1
set NAME="本地连接"

:DefaultIP
echo 默认IP配置信息如下：
echo IP地址 = 192.168.137.7 子网掩码 = 255.255.0.0 网关地址 = 192.168.137.1

:help
echo.
echo.
echo 命令参数帮助如下：
echo 根据默认的IP配置信息,自动更改IP：请按 1
echo 手动更改IP：请按 2
echo 将静态地址切换为 DHCP 地址：请按 3
echo 查看IP信息：请按 4
echo 帮助：请按 5
echo 退出：请按 6
echo 查看默认IP配置信息：请按 7
echo 清屏：请按 8
echo.

:start
set /p KEY= 命令参数输入：
rem set /p var=请输入变量的值: 是命令语法,其中var是变量名，=号右边的"请输入变量的值: ",这个是提示语,不是变量的值。
if %KEY% == 1 goto ChangeIP
if %KEY% == 2 goto ManualSetting
if %KEY% == 3 goto Auto
if %KEY% == 4 goto IPMessage
if %KEY% == 5 goto help
if %KEY% == 6 goto exit
if %KEY% == 7 goto DefaultIP
if %KEY% == 8 goto cleanS
if %KEY% GEQ 9 goto error
if %KEY% LEQ 0 goto error

:ManualSetting
ECHO 您选择了手工修改设置IP。
ECHO.
echo 默认IP地址是：%IP%，回车输入默认地址
set /p IP= [请输入IP地址:]
echo.
echo 默认MASK是：%MASK%，回车输入默认值
set /p MASK= [请输入 子网掩码 地址:]
echo.
echo 默认GATEWAY是：%GATEWAY%，回车输入默认值
set /p GATEWAY= [请输入 网关 地址:]
goto ChangeIP

:ChangeIP
echo 正在更改IP，请稍候......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY% 1
rem 也可以使用详细命令：netsh interface ip set address name=%NAME% source=static addr=%IP% mask=%MASK% gateway=%GATEWAY% gwmetric=1
rem Netsh是Windows 2000/XP/2003操作系统自身提供的命令行脚本实用工具，它允许用户在本地或远程显示或修改当前正在运行的计算机的网络配置。
echo IP地址/子网掩码/网关设置完成
echo.
echo.
goto start

:Auto
echo 正在将指定适配器的静态地址切换为 DHCP 地址......
netsh interface ip set address "本地连接" dhcp
rem 也可以使用详细命令：netsh interface ip set address name="本地连接" source=dhcp
echo 切换为 DHCP 地址设置完成
goto start

:IPMessage
ipconfig
echo.
echo.
goto start

:error
echo 输入参数不合法
echo.
echo.
goto start

:cleanS
cls
goto start

:exit

还有更好的处理方法望大家指教，若其中有什么不足的需要改进的，欢迎指正。。。