44b0中断2

44B0的向量中断响应过程是中断发生后芯片会自动跳转到0x00000018处执行指令

ENTRY

b ResetHandler ; 0x00

b HandlerUndef ; 0x04

b HandlerSWI ; 0x08

b HandlerPabort ; 0x0c

b HandlerDabort ; 0x10

b . ; 0x14

b HandlerIRQ ; 0x18

b HandlerFIQ ; 0x1c

ldr pc,=HandlerEINT0 ; 0x20

ldr pc,=HandlerEINT1

ldr pc,=HandlerEINT2

ldr pc,=HandlerEINT3

ldr pc,=HandlerEINT4567

ldr pc,=HandlerTICK ; 0x34

b .

b .

ldr pc,=HandlerZDMA0 ; 0x40

ldr pc,=HandlerZDMA1

ldr pc,=HandlerBDMA0

ldr pc,=HandlerBDMA1

ldr pc,=HandlerWDT

ldr pc,=HandlerUERR01 ; 0x54

b .

b .

ldr pc,=HandlerTIMER0 ; 0x60

ldr pc,=HandlerTIMER1

ldr pc,=HandlerTIMER2

ldr pc,=HandlerTIMER3

ldr pc,=HandlerTIMER4

ldr pc,=HandlerTIMER5 ; 0x74

b .

b .

ldr pc,=HandlerURXD0 ; 0x80

ldr pc,=HandlerURXD1

ldr pc,=HandlerIIC

ldr pc,=HandlerSIO

ldr pc,=HandlerUTXD0

ldr pc,=HandlerUTXD1 ; 0x94

b .

b .

ldr pc,=HandlerRTC ; 0xa0

b .

b .

b .

b .

b .

b .

ldr pc,=HandlerADC ; 0xb4

根据44b0的DATASEET，0x18处放置的指令为b HandlerIRQ ; 当程序跳转到这里执行时，芯片在这个地址取到的代码已经被后面程序中的branch instructions取代了，举个例子，如果芯片EINT3发生中断，芯片会跳转到0x18处执行，先在0x18处取指，这时取到的指令已经不是b HandlerIRQ，b HandlerIRQ已经被芯片自动替换成了ldr pc,=HandlerEINT3，然后芯片再执行此条指令。

而非向量中断的代码如下

ENTRY

b ResetHandler ; for debug

b HandlerUndef ; handlerUndef

b HandlerSWI ; SWI interrupt handler

b HandlerPabort ; handlerPAbort

b HandlerDabort ; handlerDAbort

b . ; handlerReserved

b IsrIRQ

b HandlerFIQ

. . . . . .

IsrIRQ

sub sp,sp,#4 ; reserved for PC

stmfd sp!,{r8-r9}

ldr r9,=I_ISPR

ldr r9,[r9]

mov r8,#0x0

0 movs r9,r9,lsr #1

bcs %F1

add r8,r8,#4

b %B0

1 ldr r9,=HandleADC

add r9,r9,r8

ldr r9,[r9]

str r9,[sp,#8]

ldmfd sp!,{r8-r9,pc}

. . . . . .

HandleADC # 4

HandleRTC # 4

HandleUTXD1 # 4

HandleUTXD0 # 4

. . . . . .

HandleEINT3 # 4

HandleEINT2 # 4

HandleEINT1 # 4

HandleEINT0 # 4 ; 0xc1(c7)fff84

当发生中断时，芯片自动跳转到0x18处执行，0x18处指令为b IsrIRQ，IsrIRQ程序的作用是检查I_ISPR的各位，判断是何种中断发生，然后根据中断的种类跳转到相应的中断服务程序去执行，各种中断服务程序的地址定义如下：

HandleADC # 4

HandleRTC # 4

HandleUTXD1 # 4

HandleUTXD0 # 4

. . . . . .

HandleEINT3 # 4

 

 

值得一提的是在44binit代码中，向量中断跳转到HandlerEINT0处而非向量中断跳转到HandleEINT0，程序利用一个宏将这两个标号等同起来，无论采取向量中断还是非向量中断，无论是跳到HandleEINT0还是HandlerEINT0，得到的效果是一样的 ，都是跳到了中断服务程序的地址去执行。

另外顺便说一下飞利浦的LPC系列ARM芯片的中断的方法，当LPC芯片得到中断信号后，在中断初始化时，程序将中断服务程序的入口地址放到中断向量地址寄存器中，每个中断源有一个中断向量地址寄存器和他相对应，另外还有一个叫做VICVectAddr(0xffff0030)的寄存器，当发生中断时，硬件自动判断该执行哪一个中断，然后将该中断源对应的中断向量地址寄存器中的地址放到寄存器VICVectAddr中。程序中断向量表里的代码为跳转到VICVectAddr中的地址执行。一旦发生中断，自动跳转到VICVectAddr中的地址去执行，因为此时VICVectAddr已经被替换成中断源的中断服务程序地址了。

       上述HandleADC # 4是在数据区中分配4个字节的存储空间，等同于HandleADC FEILD 4，这四个字节的存储空间中存的是中断服务程序的地址。在C语言编写的main程序中，如何将中断服务程序的入口地址放入到这个存储空间中呢？细心的读者 可以发现这段数据区的起始地址是_ISR_STARTADDRESS，在MAIN函数中只要让(*(unsigned *)(_ISR_STARTADDRESS+0x74)) =(int)MyIsr(MyIsr是中断服务程序的名称);但是_ISR_STARTADDRESS是一个非定值，这个值只有在连接器连接的时候才赋 值，在编译阶段他是个不定值，所以编译的时候会报错。#define _ISR_STARTADDRESS 成一个在SDRAM中的地址值。在本例中是0xc7fff00。

          中断的初始化包括对INTMSK ,INTCON进行初始化，如果是EINT0~7 还需要对PCONG、EXTINT进行初始化，对(*(unsigned *)(_ISR_STARTADDRESS+0x74（或者其他偏移量）))赋值。在中断服务程序结尾要对I_ISPC写数清除INTPND。如果是 EINT0~7还要在写I_ISPC之前对EXTINTPND寄存器写数。

 

 

顺便转另外一篇文章;

*******************************************************
; * NAME : 44BINIT.S *
; * Version : 10.JAn.2003 *
; * Description: *
; * C start up codes *
; * Configure memory, Initialize ISR ,stacks *
; * Initialize C-variables *
; * Fill zeros into zero-initialized C-variables *
; *******************************************************

GET option.s ;相当于c语言中的＃i nclude "option.s"
GET memcfg.s

;Interrupt Control
;声明一些符号常量，这些符号常量和地址相应寄存器的地址对应
INTPND EQU 0x01e00004 ;指示中断请求状态寄存器 每一位代变一种中断请求具体表一种中断请参考44b0 spec
INTMOD EQU 0x01e00008 ;中断模式寄存器 有两种中断模式对应位为1代表fip mode 0代表riq mode
INTMSK EQU 0x01e0000c ;确定哪个中断源被屏蔽 屏蔽的中断源将不被服务
I_ISPR EQU 0x01e00020 ;中断服务挂起寄存器
I_CMST EQU 0x01e0001c ;当前主寄存器irq优先级

;Watchdog timer
WTCON EQU 0x01d30000 ;看门狗定时器控制寄存器

;Clock Controller
PLLCON EQU 0x01d80000 ;pll控制寄存器
CLKCON EQU 0x01d80004 ;时钟控制寄存器
LOCKTIME EQU 0x01d8000c ;锁定时间计数值寄存器

;Memory Controller
REFRESH EQU 0x01c80024 ;Dram/sdram刷新控制寄存器
;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器 它的后五位决定目前的处理器模式
;Pre-defined constants
USERMODE EQU 0x10 ;0b10000用户模式
FIQMODE EQU 0x11 ;0b10001FIQ模式
IRQMODE EQU 0x12 ;0b10010IRQ模式
SVCMODE EQU 0x13 ;0b10011管理模式
ABORTMODE EQU 0x17 ;0b10111中止模式
UNDEFMODE EQU 0x1b ;0b11011未定义
MODEMASK EQU 0x1f ;0b11111系统模式
NOINT EQU 0xc0 ;

;check if tasm.exe is used.
;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状态执行半字对准的Thumb指令
;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用于根据处理器工作状态确定编译器编译方式
;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
;code32伪指令指示汇编编译器后面的指令为32位的arm指令
;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe译）
GBLL THUMBCODE ;设置一个全局变量
[ {CONFIG} = 16 ;if config==16 这里表示你的目前处于领先地16位编译方式
THUMBCODE SETL {TRUE} ;设置THUMBCODE 为 true
CODE32 ;转入32位编译模式
| 次 ;else
THUMBCODE SETL {FALSE} ;设置THUMBCODE 为 false
]

[ THUMBCODE ;if THUMBCODE==TRUE
CODE32 ;for start-up code for Thumb mode;转入32位编译方式
]
;注意下面这段程序是个宏定义 很多人对这段程序不理解 我再次强调这是一个宏定义 所以大家要注意了下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开
;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字空间都有一个标号，以Handle***命名。
;在向量中断模式下使用“加载程序”来执行中断服务程序。
;这里就必须讲一下向量中断模式和非向量中断模式的概念
;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
;函数中 节省了中断处理时间提高了中断处理速度标 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
;自动跳转到HandlerADC函数中
;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断
;函数中 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到对应中断源的处理代码中
MACRO
＄HandlerLabel HANDLER ＄HandleLabel

＄HandlerLabel
sub sp,sp,#4 ;decrement sp(to store jump address)
stmfd sp!,{r0} ;PUSH the work register to stack
;将要使用的r0寄存器入栈
ldr r0,=＄HandleLabel;load the address of HandleXXX to r0
ldr r0,[r0] ;
str r0,[sp,#4] ;store the contents(ISR) of HandleXXX to stack
;将对应的中断函数首地址入栈
ldmfd sp!,{r0,pc} ;POP the work register and pc(jump to ISR)
;将中断函数首地址出栈 放入程序指针中 系统将跳转到对应中断处理函数
MEND
;一个arm由RO,RW,ZI三个断组成 其中RO为代码段，RW是已经初始化的全局变量，ZI是未初始化的全局变量（对于GNU工具 对应的概念是TEXT ,DATA,BSS）bootloader
;bootloader要将RW段复制到ram中并将ZI段清零 编译器使用下列段来记录各段的起始和结束地址
; |Image＄＄RO＄＄Base| ; RO段起始地址
; |Image＄＄RO＄＄Limit| ; RO段结束地址加1
; |Image＄＄RW＄＄Base| ; RW段起始地址
; |Image＄＄RW＄＄Limit| ; RW段结束地址加1
; |Image＄＄ZI＄＄Base| ; ZI段起始地址
; |Image＄＄ZI＄＄Limit| ; ZI段结束地址加1
;这些标号的值是通过编译器的设定来确定的 如编译软件中对ro-base和rw-base的设定，例如 ro-base=0xc000000 rw-base=0xc5f0000


IMPORT |Image＄＄RO＄＄Limit| ; End of ROM code (=start of ROM data)
IMPORT |Image＄＄RW＄＄Base| ; Base of RAM to initialise
IMPORT |Image＄＄ZI＄＄Base| ; Base and limit of area
IMPORT |Image＄＄ZI＄＄Limit| ; to zero initialise

IMPORT Main ; The main entry of mon program
;下面为代码段
AREA Init,CODE,READONLY

;异常中断矢量表（每个表项占4个字节） 下面是中断向量表 一旦系统运行时有中断发生 即使移植了操作系统 如linux 处理器已经把控制权交给了操作系统 一旦发生中断 处理器还是会跳转到从0x0开始
;中断向量表中某个中断表项（依据中断类型）开始执行
;具体中断向量布局请参考s3c44b0 spec 例如 adc中断向量为 0x000000c0下面对应表中第49项位置 向量地址0x0+4*(49-1)=0x000000c0
ENTRY
;扳子上电和复位后 程序开始从位于0x0处开始执行硬件刚刚上电复位后 程序从这里开始执行跳转到标号为ResetHandler处执行
b ResetHandler ;for debug
b HandlerUndef ;handlerUndef
b HandlerSWI ;SWI interrupt handler
b HandlerPabort ;handlerPAbort
b HandlerDabort ;handlerDAbort
b . ;handlerReserved
b HandlerIRQ
b HandlerFIQ
;***IMPORTANT NOTE***
;If the H/W vectored interrutp mode is enabled, The above two instructions should
;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controler.
; b HandlerIRQ -> subs pc,lr,#4
; b HandlerIRQ -> subs pc,lr,#4

VECTOR_BRANCH
ldr pc,=HandlerEINT0 ;mGA H/W interrupt vector table
ldr pc,=HandlerEINT1 ;
ldr pc,=HandlerEINT2 ;
ldr pc,=HandlerEINT3 ;
ldr pc,=HandlerEINT4567 ;
ldr pc,=HandlerTICK ;mGA
b .
b .
ldr pc,=HandlerZDMA0 ;mGB
ldr pc,=HandlerZDMA1 ;
ldr pc,=HandlerBDMA0 ;
ldr pc,=HandlerBDMA1 ;
ldr pc,=HandlerWDT ;
ldr pc,=HandlerUERR01 ;mGB
b .
b .
ldr pc,=HandlerTIMER0 ;mGC
ldr pc,=HandlerTIMER1 ;
ldr pc,=HandlerTIMER2 ;
ldr pc,=HandlerTIMER3 ;
ldr pc,=HandlerTIMER4 ;
ldr pc,=HandlerTIMER5 ;mGC
b .
b .
ldr pc,=HandlerURXD0 ;mGD
ldr pc,=HandlerURXD1 ;
ldr pc,=HandlerIIC ;
ldr pc,=HandlerSIO ;
ldr pc,=HandlerUTXD0 ;
ldr pc,=HandlerUTXD1 ;mGD
b .
b .
ldr pc,=HandlerRTC ;mGKA
b . ;
b . ;
b . ;
b . ;
b . ;mGKA
b .
b .
ldr pc,=HandlerADC ;mGKB
b . ;
b . ;
b . ;
b . ;
b . ;mGKB
b .
b .
;0xe0=EnterPWDN
ldr pc,=EnterPWDN

LTORG
;下面是具体的中断处理函数跳转的宏，通过上面的＄HandlerLabel的宏定义展开后跳转到对应的中断处理函数（对于向量中断）
HandlerFIQ HANDLER HandleFIQ
HandlerIRQ HANDLER HandleIRQ
HandlerUndef HANDLER HandleUndef
HandlerSWI HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort

HandlerADC HANDLER HandleADC
HandlerRTC HANDLER HandleRTC
HandlerUTXD1 HANDLER HandleUTXD1
HandlerUTXD0 HANDLER HandleUTXD0
HandlerSIO HANDLER HandleSIO
HandlerIIC HANDLER HandleIIC
HandlerURXD1 HANDLER HandleURXD1
HandlerURXD0 HANDLER HandleURXD0
HandlerTIMER5 HANDLER HandleTIMER5
HandlerTIMER4 HANDLER HandleTIMER4
HandlerTIMER3 HANDLER HandleTIMER3
HandlerTIMER2 HANDLER HandleTIMER2
HandlerTIMER1 HANDLER HandleTIMER1
HandlerTIMER0 HANDLER HandleTIMER0
HandlerUERR01 HANDLER HandleUERR01
HandlerWDT HANDLER HandleWDT
HandlerBDMA1 HANDLER HandleBDMA1
HandlerBDMA0 HANDLER HandleBDMA0
HandlerZDMA1 HANDLER HandleZDMA1
HandlerZDMA0 HANDLER HandleZDMA0
HandlerTICK HANDLER HandleTICK
HandlerEINT4567 HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0


;One of the following two routines can be used for non-vectored interrupt.
;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务
;中断就将pc置为中断服务函数首地址
IsrIRQ ;using I_ISPR register.
sub sp,sp,#4 ;reserved for PC
stmfd sp!,{r8-r9}

;IMPORTANT CAUTION
;if I_ISPC isn't used properly, I_ISPR can be 0 in this routine.

ldr r9,=I_ISPR
ldr r9,[r9]
mov r8,#0x0
0
movs r9,r9,lsr #1
bcs %F1
add r8,r8,#4
b %B0

1
ldr r9,=HandleADC
add r9,r9,r8
ldr r9,[r9]
str r9,[sp,#8]
ldmfd sp!,{r8-r9,pc}


;****************************************************
;* START *
;****************************************************
;扳子上电和复位后 程序开始从位于0x0执行b ResetHandler 程序从跳转到这里执行
;板子上电复位后 执行几个步骤这里通过标号在注释中加1，2，3....标示 标号表示执行顺序
;1.禁止看门狗 屏蔽所有中断
ResetHandler
ldr r0,=WTCON ;watch dog disable
ldr r1,=0x0
str r1,[r0]

ldr r0,=INTMSK
ldr r1,=0x07ffffff ;all interrupt disable
str r1,[r0]
;2.根据工作频率设置pll
;这里介绍一下计算公式
;Fpllo=(m*Fin)/(p*2^s)
;m=MDIV+8,p=PDIV+2,s=SDIV
;Fpllo必须大于20Mhz小于66Mhz
;Fpllo*2^s必须小于170Mhz
;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
;#elif (MCLK==40000000)
;#define PLL_M (0x48)
;#define PLL_P (0x3)
;#define PLL_S (0x2)
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2
;硬件使用晶振为10Mhz,即Fin=10Mhz
;Fpllo=80*10/5*2^2=40Mhz

;****************************************************
;* Set clock control registers *
;****************************************************
ldr r0,=LOCKTIME
ldr r1,=800 ; count = t_lock * Fin (t_lock=200us, Fin=4MHz) = 800
str r1,[r0]

[ PLLONSTART
ldr r0,=PLLCON ;temporary setting of PLL
ldr r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV) ;Fin=10MHz,Fout=40MHz
str r1,[r0]
]

ldr r0,=CLKCON
ldr r1,=0x7ff8 ;All unit block CLK enable
str r1,[r0]
;3.置存储相关寄存器的程序
;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.s程序
;具体寄存器各位含义请参考s3c44b0 spec

;****************************************************
;* Set memory control registers *
;****************************************************
ldr r0,=SMRDATA
ldmia r0,{r1-r13}
ldr r0,=0x01c80000 ;BWSCON Address
stmia r0,{r1-r13}

;****************************************************
;* Initialize stacks *
;****************************************************
ldr sp, =SVCStack ;Why?
bl InitStacks
;5.设置缺省中断处理函数
;****************************************************
;* Setup IRQ handler *
;****************************************************
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
;6.将数据段拷贝到ram中 将零初始化数据段清零 跳入C语言的main函数执行 到这步结束bootloader初步引导结束
;********************************************************
;* Copy and paste RW data/zero initialized data *
;********************************************************
LDR r0, =|Image＄＄RO＄＄Limit| ; Get pointer to ROM data
LDR r1, =|Image＄＄RW＄＄Base| ; and RAM copy
LDR r3, =|Image＄＄ZI＄＄Base|
;Zero init base => top of initialised data

CMP r0, r1 ; Check that they are different
BEQ %F1
0
CMP r1, r3 ; Copy init data
LDRCC r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4
STRCC r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4
BCC %B0
1
LDR r1, =|Image＄＄ZI＄＄Limit| ; Top of zero init segment
MOV r2, #0
2
CMP r3, r1 ; Zero init
STRCC r2, [r3], #4
BCC %B2

[ :LNOT:THUMBCODE
BL Main ;Don't use main() because ......;跳入main函数
B .
]

[ THUMBCODE ;for start-up code for Thumb mode
orr lr,pc,#1
bx lr
CODE16
bl Main ;Don't use main() because ......;跳入main函数
b .
CODE32
]
;4.初始化各模式下的栈指针
;****************************************************
;* The function for initializing stack *
;****************************************************
InitStacks
;Don't use DRAM,such as stmfd,ldmfd......
;SVCstack is initialized before
;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

mrs r0,cpsr
bic r0,r0,#MODEMASK
orr r1,r0,#UNDEFMODE|NOINT
msr cpsr_cxsf,r1 ;UndefMode
ldr sp,=UndefStack

orr r1,r0,#ABORTMODE|NOINT
msr cpsr_cxsf,r1 ;AbortMode
ldr sp,=AbortStack

orr r1,r0,#IRQMODE|NOINT
msr cpsr_cxsf,r1 ;IRQMode
ldr sp,=IRQStack

orr r1,r0,#FIQMODE|NOINT
msr cpsr_cxsf,r1 ;FIQMode
ldr sp,=FIQStack

bic r0,r0,#MODEMASK|NOINT
orr r1,r0,#SVCMODE
msr cpsr_cxsf,r1 ;SVCMode
ldr sp,=SVCStack

;USER mode is not initialized.
mov pc,lr ;The LR register may be not valid for the mode changes.
;下面是pwdn模式下的相关寄存器的定义
;****************************************************
;* The function for entering power down mode *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
mov r2,r0 ;r0=CLKCON
ldr r0,=REFRESH
ldr r3,[r0]
mov r1, r3
orr r1, r1, #0x400000 ;self-refresh enable
str r1, [r0]

nop ;Wait until self-refresh is issued. May not be needed.
nop ;If the other bus master holds the bus, ...
nop ; mov r0, r0
nop
nop
nop
nop

;enter POWERDN mode
ldr r0,=CLKCON
str r2,[r0]

;wait until enter SL_IDLE,STOP mode and until wake-up
mov r0,#0xff
0 subs r0,r0,#1
bne %B0

;exit from DRAM/SDRAM self refresh mode.
ldr r0,=REFRESH
str r3,[r0]

mov pc,lr

LTORG
;这是上面提到的对存储寄存器初始化的数据map
SMRDATA DATA
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized. *
;*****************************************************************

;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.


DCD 0x11110090 ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;
DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0
DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1
DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2
DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3
DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4
DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5
DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6
DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7
DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT) ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
DCD 0x16 ;SCLK power mode, BANKSIZE 32M/32M
DCD 0x20 ;MRSR6 CL=2clk
DCD 0x20 ;MRSR7

ALIGN

;下面是对ram区域map的定义
AREA RamData, DATA, READWRITE
;这里定义了处理器工作于各模式的堆栈区在ram中map
^ (_ISR_STARTADDRESS-0x500)

UserStack # 256 ;c1(c7)ffa00
SVCStack # 256 ;c1(c7)ffb00
UndefStack # 256 ;c1(c7)ffc00
AbortStack # 256 ;c1(c7)ffd00
IRQStack # 256 ;c1(c7)ffe00
FIQStack # 0 ;c1(c7)fff00

;这里将中断异常向量建立在sdram中
^ _ISR_STARTADDRESS
HandleReset # 4
HandleUndef # 4
HandleSWI # 4
HandlePabort # 4
HandleDabort # 4
HandleReserved # 4
HandleIRQ # 4
HandleFIQ # 4

;Don't use the label 'IntVectorTable',
;because armasm.exe cann't recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
HandleADC # 4
HandleRTC # 4
HandleUTXD1 # 4
HandleUTXD0 # 4
HandleSIO # 4
HandleIIC # 4
HandleURXD1 # 4
HandleURXD0 # 4
HandleTIMER5 # 4
HandleTIMER4 # 4
HandleTIMER3 # 4
HandleTIMER2 # 4
HandleTIMER1 # 4
HandleTIMER0 # 4
HandleUERR01 # 4
HandleWDT # 4
HandleBDMA1 # 4
HandleBDMA0 # 4
HandleZDMA1 # 4
HandleZDMA0 # 4
HandleTICK # 4
HandleEINT4567 # 4
HandleEINT3 # 4
HandleEINT2 # 4
HandleEINT1 # 4
HandleEINT0 # 4 ;0xc1(c7)fff84
END