没有无线路由情况下笔记本共享有线网络成无线wifi网络使手机上网

0：目的

在没有无线路由的情况下，通过笔记本共享有线网络使之成为无线网络，方便手机通过这个共享wifi上网

1：前提

笔记本连接有线网络

笔记本wifi打开

或者台式机有无线网卡的也行

2：操作方法

win7系统用笔记本共享网络wifi的批处理文件，全部复制下来，然后放在文本文件中，然后修改后缀名成 .bat，比如  wifi.bat 注意中间有点，然后每次共享双击就行了，有的时候需要用管理员身份运行，此时右键这个批处理文件，选择管理员身份运行即可，然后通过手机连接这个wifi就可以上网了

@echo off
TITLE win7自建wifi
:loop
cls

echo
echo.┏━━━━━━━━━━━━━┳━━━━━━━━━━━━┓
echo.┃   1、 设置向导           ┃    2、开启网络         ┃
echo.┣━━━━━━━━━━━━━╋━━━━━━━━━━━━┫
echo.┃   3、 修改密码           ┃    4、修改无线网络名称 ┃
echo.┣━━━━━━━━━━━━━╋━━━━━━━━━━━━┫
echo.┃   5、 关闭网络           ┃    6、查看配置状态     ┃
echo.┣━━━━━━━━━━━━━╋━━━━━━━━━━━━┫
echo.┃   7、 不能连接问题请选择 ┃    8、删除wifi         ┃
echo.┣━━━━━━━━━━━━━╋━━━━━━━━━━━━┫
echo.┃   9、 检测网卡是否支持   ┃    0、退出程序         ┃
echo.┗━━━━━━━━━━━━━┻━━━━━━━━━━━━┛
set /p input=请选择：
if %input%==1 goto setssid
if %input%==2 goto startnet
if %input%==3 goto Cnp
if %input%==4 goto Ctn
if %input%==5 goto stopnet
if %input%==6 goto View
if %input%==7 goto Problem
if %input%==8 goto Delete the network
if %input%==9 goto Test
if %input%==0 goto exit
:setssid
cls
set /p ssid= 【请输入您的WIFI名称 4位以上英文或数字不能为中文】
cls
set /p password=【请输入您需要设置的WIFI密码 8-10位】
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%password%
echo. 请打开——网络共享中心——更改适配器设置——双击当前连接的适配器——属性——共享——勾选“允许其他网络用户通过此计算机的Internet连接来连接”——选择“无线网络2”——确定。尝试看是否可以连接
echo. 注意:某些window7需要提升管理员权限才能操作，点击右键“以管理员身份运行”
@pause
goto loop

:startnet
cls
netsh wlan start hostednetwork
@pause
goto loop

:Cnp
cls
set /p password=【请输入您需要修改的密码 8-10位】
netsh wlan set hostednetwork mode=allow key=%password%
@pause
goto loop

:Ctn
cls
set /p ssid=【请输入您需要修改的名称 4位以上英文或数字不能为中文】
netsh wlan set hostednetwork mode=allow ssid=%ssid%
@pause
goto loop

:stopnet
cls
netsh wlan stop hostednetwork
@pause
goto loop

:View
cls
netsh wlan show hostednetwork
@pause
goto loop

:Delete the network
cls
netsh wlan set hostednetwork mode= disallow
@pause
goto loop

:Test
cls
echo 运行本命令若在窗口显示“支持承载网络：是”（大概在中间位置）
echo 说明你的网卡支持，然后进行配置！
echo ——————————————————————————————
pause
netsh wlan show drivers
@pause
goto loop

:exit

EXIT


:Problem
cls
echo. 本程序需要有无线网卡，且需要网络认证程序支持双网卡，校园网用户推荐使用mentohust，电信e信认证用户需要破解e信
@pause
goto loop