u-boot lds文件详解

 

对于.lds文件,决定一个可执行程序的各个段的存储位置,以及入口地址,这也是链接定位的作用。这里以u-boot的lds为例说明uboot的链接过程。
首先看一下GNU官方网站上对.lds文件形式的完整描述:
SECTIONS {
...
secname start BLOCK(align) (NOLOAD) : AT ( ldadr )
  { contents } >region :phdr =fill
...
}
secname和contents是必须的,前者用来命名这个段,后者用来确定代码中的什么部分放在这个段,以下是对这个描述中的一些关键字的解释。
1、secname:段名
2、contents:决定哪些内容放在本段,可以是整个目标文件,也可以是目标文件中的某段(代码段、数据段等)
3、start:是段的重定位地址,本段连接(运行)的地址,如果代码中有位置无关指令,程序运行时这个段必须放在这个地址上。start可以用任意一种描述地址的符号来描述。
4、AT(ldadr):定义本段存储(加载)的地址,如果不使用这个选项,则加载地址等于运行地址,通过这个选项可以控制各段分别保存于输出文件中不同的位置。
例:
/* nand.lds */
SECTIONS {
firtst 0x00000000 : { head.o init.o }
second 0x30000000 : AT(4096) { main.o }
}
    以上,head.o放在0x00000000地址开始处,init.o放在head.o后面,他们的运行地址也是0x00000000,即连接和存储地址相同(没有AT指定);main.o放在4096(0x1000,是AT指定的,存储地址)开始处,但它的运行地址在0x30000000,运行之前需要从0x1000(加载地址处)复制到0x30000000(运行地址处),此过程也就需要读取 flash,把程序拷贝到相应位置才能运行。这就是存储地址和运行地址的不同,称为加载时域和运行时域,可以在.lds连接脚本文件中分别指定。
编写好的.lds文件,在用arm-linux-ld连接命令时带-Tfilename来调用执行,如
arm-linux-ld –Tnand.lds x.o y.o –o xy.o。也用-Ttext参数直接指定连接地址,如
arm-linux-ld –Ttext 0x30000000 x.o y.o –o xy.o。
既然程序有了两种地址,就涉及到一些跳转指令的区别。
ARM汇编中,常有两种跳转方法:b跳转指令、ldr指令向PC赋值。
要特别注意这两条指令的意思:
(1)       b step:b跳转指令是相对跳转,依赖当前PC的值,偏移量是通过该指令本身的    bit[23:0]算出来的,这使得使用b指令的程序不依赖于要跳到的代码的位置,只看指令本身。
(2)       ldr pc, =step :该指令是一个伪指令编译后会生成以下代码:
        ldr pc, 0x30008000
        <0x30008000>
                        step
    是从内存中的某个位置(step)读出数据并赋给PC,同样依赖当前PC的值,但是偏移量是step的连接地址(运行时的地址),所以可以用它实现从Flash到RAM的程序跳转。
(3) 此外,有必要回味一下adr伪指令,U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中:
         relocate:                                   /* 把U-Boot重新定位到RAM */
              adr r0, _start                       /* r0是代码的当前位置 */
/* adr伪指令,汇编器自动通过当前PC的值算出这条指令中“_start"的值,执行到_start时PC的值放到r0中:
当此段在flash中执行时r0 = _start = 0;当此段在RAM中执行时_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值为0x33F80000,即u-boot在把代码拷贝到RAM中去执行的代码段的开始) */
    ldr r1, _TEXT_BASE                       /* 测试判断是从Flash启动,还是RAM */
/* 此句执行的结果r1始终是0x33FF80000,因为此值是链接指定的 */
    cmp r0, r1                                    /* 比较r0和r1,调试的时候不要执行重定位 */
    结合u-boot.lds谈谈连接脚本。
OUTPUT_FORMAT("elf32&shy;littlearm", "elf32&shy;littlearm", "elf32&shy;littlearm")
                                                        ;指定输出可执行文件是elf格式,32位ARM指令,小端
OUTPUT_ARCH(arm)
                                                        ;指定输出可执行文件的平台为ARM
ENTRY(_start)
                                                        ;指定输出可执行文件的起始代码段为_start.
SECTIONS
{
        . = 0x00000000             ; 定位当前地址为0地址
        . = ALIGN(4)                 ; 代码以4字节对齐
        .text :                                       ;指定代码段
        {
           cpu/arm920t/start.o (.text)  ; 代码的第一个代码部分
          *(.text)                        ;其它代码部分
        }
        . = ALIGN(4)
        .rodata : { *(.rodata) }         ;指定只读数据段
        . = ALIGN(4);
        .data : { *(.data) }             ;指定读/写数据段
        . = ALIGN(4);
        .got : { *(.got) }                        ;指定got段, got段式是uboot自定义的一个段, 非标准段
         __u_boot_cmd_start = .          ;把__u_boot_cmd_start赋值为当前位置, 即起始位置
        .u_boot_cmd : { *(.u_boot_cmd) }          ;指定u_boot_cmd段, uboot把所有的uboot命令放在该段.
         __u_boot_cmd_end = .                          ;把__u_boot_cmd_end赋值为当前位置,即结束位置
        . = ALIGN(4);
         __bss_start = .                                       ; 把__bss_start赋值为当前位置,即bss段的开始位置
        .bss : { *(.bss) }                        ; 指定bss段
         _end = .                                  ; 把_end赋值为当前位置,即bss段的结束位置
}网上大部分u-boot.lds文件的分析大部分都是千遍一律,例如下面就是本人在网上找到的关于u-boot.lds的资料。

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/*指定输出可执行文件是elf格式,32位ARM指令,小端*/
OUTPUT_ARCH(arm)

/*指定输出可执行文件的平台为ARM*/
ENTRY(_start)

/*指定输出可执行文件的起始代码段为_start*/
SECTIONS
{

/*指定可执行image文件的全局入口点,通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址,通常都是修改此处来完成*/
 . = 0x00000000;/*;从0x0位置开始*/
 . = ALIGN(4);/*代码以4字节对齐*/
 .text :
 {
  cpu/arm920t/start.o (.text)

    /*代码的第一个代码部分*/ 
  *(.text)

  /*下面依次为各个text段函数*/
 }
 . = ALIGN(4);

/*代码以4字节对齐*/
 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }

 /*指定只读数据段*/
 . = ALIGN(4);

/*代码以4字节对齐*/
 .data : { *(.data) }
 . = ALIGN(4);

/*代码以4字节对齐*/
 .got : { *(.got) }

/*指定got段, got段是uboot自定义的一个段, 非标准段*/
 . = .;
 __u_boot_cmd_start = .;

/*把__u_boot_cmd_start赋值为当前位置, 即起始位置*/
 .u_boot_cmd : { *(.u_boot_cmd) }

 /*指定u_boot_cmd段, uboot把所有的uboot命令放在该段.*/
 __u_boot_cmd_end = .;

 /*把__u_boot_cmd_end赋值为当前位置,即结束位置*/
 . = ALIGN(4);

/*代码以4字节对齐*/
 __bss_start = .;

 /*把__bss_start赋值为当前位置,即bss段的开始位置*/
 .bss (NOLOAD) : { *(.bss) . = ALIGN(4); }

/*指定bss段,告诉加载器不要加载这个段*/
 __bss_end = .;

/*把_end赋值为当前位置,即bss段的结束位置*/
}

 

看完上面的解析思路本来应该是很清晰的,于是乎编译u-boot,查看一下System.map,

 

30100000 T _start

30100020 t _undefined_instruction

30100024 t _software_interrupt

30100028 t _prefetch_abort

3010002c t _data_abort

30100030 t _not_used

30100034 t _irq

30100038 t _fiq

 

发现 _start 的链接地址不是u-boot.lds中.text 的当前地址0x00000000,而是0x30100000,这就产生很多疑问了:

(1)     为什么u-boot.lds指定的 .text 的首地址不起作用?

(2)     0x30100000是什么地址,由谁指定.text的首地址是0x30100000的呢?

(3)     假如有其他动作改变了 .text 的首地址,那么该动作跟u-boot.lds的优先级又是怎么决定的呢?

其实这三个问题都在Makefile的LDFLAGS 变量和u-boot.lds 中找到答案。我们不妨试着修改一下u-boot.lds,把u-boot.lds修改成如下(红色字体部分为修改过部分):

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/*指定输出可执行文件是elf格式,32位ARM指令,小端*/
OUTPUT_ARCH(arm)

/*指定输出可执行文件的平台为ARM*/
ENTRY(_start)

/*指定输出可执行文件的起始代码段为_start*/
SECTIONS
{

/*指定可执行image文件的全局入口点,通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址,通常都是修改此处来完成*/
 . = 0x30000000;/*;从0x0位置开始*/
 . = ALIGN(4);/*代码以4字节对齐*/

.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
 . = ALIGN(4);

/*代码以4字节对齐*/

 .text :
 {
  cpu/arm920t/start.o (.text)

    /*代码的第一个代码部分*/ 
  *(.text)

  /*下面依次为各个text段函数*/
 }

 /*指定只读数据段*/
 . = ALIGN(4);

/*代码以4字节对齐*/
 .data : { *(.data) }
 . = ALIGN(4);

/*代码以4字节对齐*/
 .got : { *(.got) }

/*指定got段, got段是uboot自定义的一个段, 非标准段*/
 . = .;
 __u_boot_cmd_start = .;

/*把__u_boot_cmd_start赋值为当前位置, 即起始位置*/
 .u_boot_cmd : { *(.u_boot_cmd) }

 /*指定u_boot_cmd段, uboot把所有的uboot命令放在该段.*/
 __u_boot_cmd_end = .;

 /*把__u_boot_cmd_end赋值为当前位置,即结束位置*/
 . = ALIGN(4);

/*代码以4字节对齐*/
 __bss_start = .;

 /*把__bss_start赋值为当前位置,即bss段的开始位置*/
 .bss (NOLOAD) : { *(.bss) . = ALIGN(4); }

/*指定bss段,告诉加载器不要加载这个段*/
 __bss_end = .;

/*把_end赋值为当前位置,即bss段的结束位置*/
}

 

上面对u-boot.lds主要做了两点修改

(1)     把0x00000000 改成 0x30000000。

(2)     把 .text 和 .rodata 存放的地址调换了位置。

重新编译 u-boot, 查看System.map

30000000 R version_string

30000028 r C.27.2365

.

.

.

30100000 T _start

30100020 t _undefined_instruction

.

.

.

从上面的System.map部分内容可以看出:

(1)     u-boot.lds设定的地址(0x00000000或0x30000000)是有效的。

(2)     .text的地址仍然是30100000

 

跟着我们查看Makefile中的LDFLAGS变量,发现一条指令

LDFLAGS += -Ttext $(TEXT_BASE)  其中TEXT_BASE 是在u-boot根目录的board文件夹的对应的开发板名字的子目录下的config.mk文件中定义的

TEXT_BASE = 0x30100000

看到这里我们应该明白为什么_start,也就是.text的首地址总是等于0x30100000了,在连接的时候ld命令会把参数-Ttext指定的地址赋给.text,所以.text在u-boot.lds中的默认地址(当前地址)不起作用了

文章出处:飞诺网(www.diybl.com):http://www.diybl.com/course/6_system/linux/linuxjq/20110903/559708.html

评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值