配合视频学习效果更好!https://www.bilibili.com/video/BV15o4y157Wm/?vd_source=701807c4f8684b13e922d0a8b116af31
仓库地址:https://github.com/xukanshan/the_truth_of_operationg_system
在8086计算机开机时,CPU的cs:ip寄存器被强制初试化为0xF000:0xFFF0,在实模式下由于CPU访问的内存是段地址+偏移地址的方式来实现的,所以0xF000:0xFFF0,访问的地址是0xF000*16+0xFFF0=0xFFFF0。
0xFFFF0这个地址存放着一条指令,该指令内容是跳转至BIOS程序的入口(该指令由跳转指令与BIOS程序的入口地址组成,共16B)。BIOS有四个主要功能:1、硬件自检;2、建立一些需要用到的数据结构与中断向量表;3、校验启动盘中位于0盘0道1扇区(其实就是0扇区,只不过CHS方法用1开头)的内容,校验这里是不是放着主引导记录MBR,校验方法是检测这个扇区最后两个字节是不是0x55与0xaa(所以我们编写的主引导记录MBR最后两个字节应该是这两个);4、在3的基础上是,那么就将该扇区内容加载至0x7c00内存处,这个位置是由于历史遗留导致的兼容,由最初的操作系统本身所占内存大小与布局所决定(书p58)。加载完毕后,然后跳转过去执行。
MBR的任务就是加载loader,由loader加载操作系统到指定位置,然后执行加载过来的操作系统。MBR大小必须是512字节,这是为了占满硬盘0盘0道1扇区,且最最后两个字节必须是0x55与0xaa。
p61代码mbr.S剖析:
1、代码功能
编写”MBR“实验文件,该MBR并不用于加载,而是在屏幕上显示几个字符、
2、实现原理
用8086汇编语言编写显示字符的程序。该程序共512字节(不足部分补0),且最后两个字节是0x55与0xaa。该程序用NASM编译后,用dd命令写入bochs启动硬盘的0盘0道1扇区,BIOS会自动加载程序到内存中,然后自动跳转执行该程序。
3、代码逻辑:
A、清屏
B、获取光标位置
C、在光标位置处打印字符串
4、怎么写代码?
查询:BIOS中断使用用法:https://blog.csdn.net/MENGmei0219/article/details/126785698,然后根据具体中断的需求,往所需要的所有寄存器送入值。
A、指定本程序的起始地址0x7c00,为的是告诉编译器把本程序的起始地址编译为0x7c00;
B、调用bios中断清屏;
C、调用bios中断获取光标位置;
D、调用bios中断打印字符;
E、死循环;然后填入MBR规定510字节大小剩下的0;固定结尾两字节0x55,0xaa
5、代码实现如下 (myos/boot/mbr.S)
;主引导程序
;------------------------------------------------------------
SECTION MBR vstart=0x7c00
mov ax,cs ;此时cs寄存器为0,自然可以用来将ax寄存器置0
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00
; 清屏 利用0x06号功能,上卷全部行,则可清屏。
; -----------------------------------------------------------
;INT 0x10 功能号:0x06 功能描述:上卷窗口
;------------------------------------------------------
;输入:
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值:
mov ax, 0x600 ;ah中输入功能号
mov bx, 0x700 ;设置上卷行属性,0x70表示用黑底白字的属性填充空白行
mov cx, 0 ;左上角: (0, 0)
mov dx, 0x184f ;右下角: (80,25),
;VGA文本模式中,一行只能容纳80个字符,共25行。
;下标从0开始,所以0x18=24,0x4f=79
int 0x10 ;int 0x10
;;;;;;;;; 下面这三行代码是获取光标位置 ;;;;;;;;;
mov ah, 3 ;输入: 3号子功能是获取光标位置,需要存入ah寄存器
mov bh, 0 ;bh寄存器存储的是待获取光标的页号
int 0x10 ;输出: ch=光标开始行,cl=光标结束行
;dh=光标所在行号,dl=光标所在列号
;;;;;;;;; 获取光标位置结束 ;;;;;;;;;;;;;;;;
;;;;;;;;; 打印字符串 ;;;;;;;;;;;
;还是用10h中断,不过这次是调用13号子功能打印字符串
mov ax, message
mov bp, ax ; es:bp 为串首地址, es此时同cs一致,
; 开头时已经为sreg初始化
; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
mov cx, 5 ; cx 为串长度,不包括结束符0的字符个数
mov ax, 0x1301 ; 子功能号13是显示字符及属性,要存入ah寄存器,
; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
mov bx, 0x2 ; bh存储要显示的页号,此处是第0页,
; bl中是字符属性, 属性黑底绿字(bl = 02h,07是黑底白字)
int 0x10 ; 执行BIOS 0x10 号中断
;;;;;;;;; 打字字符串结束 ;;;;;;;;;;;;;;;
jmp $ ; 使程序悬停在此
message db "1 MBR"
times 510-($-$$) db 0
db 0x55,0xaa
6、其他代码详解查看书p61
然后使用nasm编译该.s文件
nasm -o mbr mbr.S
然后用dd命令写入bochs的虚拟硬盘,命令:
dd if=/home/rlk/Desktop/the_truth_of_operationg_system/chapter_2/a/boot/mbr of=/home/rlk/Desktop/bochs/hd60M.img bs=512 count=1 conv=notrunc
bs是要读写的块大小,这里是要读写一个512字节的块;count是指定拷贝的块数,这里是1;conv是指定如何转换文件,这里就不转换。