if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_GetStr]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_GetStr]
GO
/*--得到字符串列表指定位置的字符
可以自定义字符串列表的分隔符
如果取数位置超出的范围,返回空字符串
--邹建 2004.07(引用请保留此信息)--*/
/*--调用示例
--测试数据
declare @t table(FITEM varchar(100))
insert @t select '100..10.'
union all select '20.140.10'
union all select '150.124.150.10'
--查询
select fitem1=dbo.f_GetStr(fitem,1,'.')
,fitem2=dbo.f_GetStr(fitem,2,'.')
,fitem3=dbo.f_GetStr(fitem,3,'.')
,fitem4=dbo.f_GetStr(fitem,4,'.')
,fitem4=dbo.f_GetStr(fitem,5,'.')
,fitem4=dbo.f_GetStr(fitem,6,'.')
from @t
--*/
CREATE FUNCTION f_GetStr(
@s varchar(8000), --字符串列表
@pos int, --要获取的数据信息段
@split varchar(10) --分隔符
)RETURNS varchar(100)
AS
BEGIN
IF @s IS NULL RETURN(NULL)
DECLARE @splitlen int
SELECT @splitlen=LEN(@split+'a')-2
WHILE @pos>1 AND CHARINDEX(@split,@s+@split)>0
SELECT @pos=@pos-1,
@s=STUFF(@s,1,CHARINDEX(@split,@s+@split)+@splitlen,'')
RETURN(ISNULL(LEFT(@s,CHARINDEX(@split,@s+@split)-1),''))
END
GO