联络员(最小生成树)

Description

Tyvj已经一岁了,网站也由最初的几个用户增加到了上万个用户,随着Tyvj网站的逐步壮大,管理员的数目也越来越多,现在你身为Tyvj管理层的联络员,希望你找到一些通信渠道,使得管理员两两都可以联络(直接或者是间接都可以)。Tyvj是一个公益性的网站,没有过多的利润,所以你要尽可能的使费用少才可以。 目前你已经知道,Tyvj的通信渠道分为两大类,一类是必选通信渠道,无论价格多少,你都需要把所有的都选择上;还有一类是选择性的通信渠道,你可以从中挑选一些作为最终管理员联络的通信渠道。数据保证给出的通行渠道可以让所有的管理员联通。

Input

第一行n,m表示Tyvj一共有n个管理员,有m个通信渠道第二行到m+1行,每行四个非负整数,p,u,v,w 当p=1时,表示这个通信渠道为必选通信渠道;当p=2时,表示这个通信渠道为选择性通信渠道;u,v,w表示本条信息描述的是u,v管理员之间的通信渠道,u可以收到v的信息,v也可以收到u的信息,w表示费用。

Output

最小的通信费用

SampleInput

Sample Output

5 6
1 1 2 1
1 2 3 1
1 3 4 1
1 4 1 1
2 2 5 10
2 2 5 5

Hint

样例解释: 
1-2-3-4-1存在四个必选渠道,形成一个环,互相可以到达。需要让所有管理员联通,需要联通2和5号管理员,选择费用为5的渠道,所以总的费用为9 

注意: 
U,v之间可能存在多条通信渠道,你的程序应该累加所有u,v之间的必选通行渠道 

数据范围: 
对于30%的数据,n<=10 m<=100 
对于50%的数据, n<=200 m<=1000 
对于100%的数据,n<=2000m<=10000 

先把必选通信渠道合并,用并查集打最小生成树。

 

var
 p,r:array [1..2001] of longint;
 a:array [1..10001,1..3] of longint;
 n,m,p1,u,v,w,ans,k,i:longint;
function find(x:longint):longint;
 var y,root,w:longint;
 begin
 y:=x;
   while p[y]>0 do
    y:=p[y];
   root:=y;
   y:=x;
   while p[y]>0 do
    begin
     w:=p[y];
     p[y]:=root;
     y:=w;
    end;
   find:=root;
 end;
 
procedure union(x,y:longint);
 var
  u,v:longint;
begin
 u:=find(x);
 v:=find(y);
 if u=v then exit;
 if r[u]<=r[v] then
  begin
   p[u]:=v;
   if r[u]=r[v] then inc(r[v]);
  end
 else p[v]:=u;
end;
 
procedure qsort(l,r:longint);
  var
    i,j,key,temp:longint;
  begin
    if l>=r then exit;
    i:=l;j:=r;
    key:=a[l+random(r-l+1),3];
    repeat
      while  (a[i,3]<key) do inc(i);
      while  (a[j,3]>key) do dec(j);
      if i<=j then
      begin
        temp:=a[i,1];a[i,1]:=a[j,1];a[j,1]:=temp;
        temp:=a[i,2];a[i,2]:=a[j,2];a[j,2]:=temp;
        temp:=a[i,3];a[i,3]:=a[j,3];a[j,3]:=temp;
        inc(i);dec(j);
      end;
    until i>j;
    qsort(l,j);
    qsort(i,r);
  end;
 
 
begin
 readln(n,m);
 for i:=1 to m do
  begin
   readln(p1,u,v,w);
   if p1=1 then
    begin
     ans:=ans+w;
     union(u,v);
    end
  else
   begin
    inc(k);
    a[k,1]:=u;
    a[k,2]:=v;
    a[k,3]:=w;
   end;
  end;
 qsort(1,k);
 for i:=1 to k do
  begin
   if find(a[i,1])<>find(a[i,2]) then
    begin
     union(a[i,1],a[i,2]);
     ans:=ans+a[i,3];
    end;
  end;
 write(ans);
end.

 

阅读更多
版权声明:2333 https://blog.csdn.net/liangzihao1/article/details/51114919
想对作者说点什么? 我来说一句

没有更多推荐了,返回首页

关闭
关闭
关闭