【CodeVS1136】【NOIP2011】Mayan 游戏

【Description】

　　Mayan puzzle 是最近流行起来的一个游戏。游戏界面是一个 7 行 5 列的棋盘，上面堆放 着一些方块，方块不能悬空堆放，即方块必须放在最下面一行，或者放在其他方块之上。游 戏通关是指在规定的步数内消除所有的方块，消除方块的规则如下：
　　1.每步移动可以且仅可以沿横向（即向左或向右）拖动某一方块一格：当拖动这一方 块时，如果拖动后到达的位置（以下称目标位置）也有方块，那么这两个方块将交换位置（参 见输入输出样例说明中的图 6 到图 7）；如果目标位置上没有方块，那么被拖动的方块将从 原来的竖列中抽出，并从目标位置上掉落（直到不悬空，参见下面图 1 和图 2）；

　　　　　　　　图 1　　　　　　　　　　　　　　　　　　　图 2　　 　　　　　　　　　　　　　　　　　 图 3

　　2.任一时刻，如果在一横行或者竖列上有连续三个或者三个以上相同颜色的方块，则 它们将立即被消除（参见图 1 到图 3）。
　　注意：
　　a)如果同时有多组方块满足消除条件，几组方块会同时被消除（例如下面图4，三个颜 色为 1 的方块和三个颜色为 2 的方块会同时被消除，最后剩下一个颜色为 2 的方块）。
　　b)当出现行和列都满足消除条件且行列共享某个方块时，行和列上满足消除条件的所 有方块会被同时消除（例如下面图 5 所示的情形，5 个方块会同时被消除）。

　　3.方块消除之后，消除位置之上的方块将掉落，掉落后可能会引起新的方块消除。注 意：掉落的过程中将不会有方块的消除。
　　上面图 1 到图 3 给出了在棋盘上移动一块方块之后棋盘的变化。棋盘的左下角方块的坐 标为（0, 0），将位于（3, 3）的方块向左移动之后，游戏界面从图 1 变成图 2 所示的状态， 此时在一竖列上有连续三块颜色为 4 的方块，满足消除条件，消除连续 3 块颜色为 4 的方块 后，上方的颜色为 3 的方块掉落，形成图 3 所示的局面。

---

【Input】

　　第一行为一个正整数 n，表示要求游戏通关的步数。
接下来的 5 行，描述 7*5 的游戏界面。每行若干个整数，每两个整数之间用一个空格隔 开，每行以一个 0 结束，自下向上表示每竖列方块的颜色编号（颜色不多于 10 种，从 1 开 始顺序编号，相同数字表示相同颜色）。
　　输入数据保证初始棋盘中没有可以消除的方块。

---

【Output】

　　如果有解决方案，输出 n 行，每行包含 3 个整数 x，y，g，表示一次移动，每两个整数
之间用一个空格隔开，其中（x，y）表示要移动的方块的坐标，g 表示移动的方向，1 表示 向右移动，-1 表示向左移动。注意：多组解时，按照 x 为第一关健字，y 为第二关健字，1 优先于-1，给出一组字典序最小的解。游戏界面左下角的坐标为（0，0）。
　　如果没有解决方案，输出一行，包含一个整数-1。

---

【Sample Input】

3
1 0
2 1 0
2 3 4 0
3 1 0
2 4 3 4 0

---

【Sample Output】

2 1 1
3 1 1
3 0 1

---

【Data Size and Hint】

　　按箭头方向的顺序分别为图 6 到图 11
　　
　　样例输入的游戏局面如上面第一个图片所示，依次移动的三步是：（2，1）处的方格向右移动，（3，1）处的方格向右移动，（3，0）处的方格向右移动，最后可以将棋盘上所有方块消除。
　　对于 30%的数据，初始棋盘上的方块都在棋盘的最下面一行； 对于 100%的数据，0 < n≤5。

---

【Solution】

　　对于本题，直接想到的方法肯定是搜索，但要加一些剪枝不然会TLE2～3个点。
　　剪枝方法如下：
　　1.左右交换只考虑右交换因为$a[i,j]$向右和$a[i+1,j]$交换与$a[i+1,j]$向左与$a[i,j]$交换相同，而输出以向右交换优先所以只考虑右交换
　　2.左右两个相邻相同就不交换（这个剪枝建立在一个基础上，即不会将两个不会影响整体的方块来回交换抵消次数，而根据数据和实际游戏这种情况不会出现）
　　
　　参考代码如下：

type step = record
              x,y,dir:longint;
            end;
     state = array[1..35] of longint;
var n:longint;
    stack:array[0..6] of state;
    temp:array[1..6] of step;
    ans:array[1..6] of step;
    can:array[1..35] of boolean;
procedure init; //读入并初始化
  var i,j,tmp:longint;
  begin
    readln(n);
    fillchar(stack,sizeof(stack),0);
    for i:=1 to 5 do begin
      read(tmp); j:=0;
      while tmp<>0 do begin
        inc(j); stack[0][(i-1)*7+j]:=tmp;
        read(tmp);
      end;
      readln;
    end;
    fillchar(ans,sizeof(ans),0);
    fillchar(temp,sizeof(temp),0);
  end;
function check:boolean;  //检查是否消除完成
  var i:longint;
  begin
    for i:=1 to 35 do
      if stack[n][i]<>0 then exit(false);
    exit(true);
  end;
procedure drop(dep:longint);  //下落操作
  var i,j,k:longint;
  begin
    for i:=0 to 4 do begin
      j:=2;
      while (j<=7) do begin
        if (stack[dep][i*7+j]<>0) and (stack[dep][i*7+j-1]=0) then begin
          k:=j;
          while (k>1) and (stack[dep][i*7+k-1]=0) do dec(k);
          stack[dep][i*7+k]:=stack[dep][i*7+j];
          stack[dep][i*7+j]:=0;
        end;
        inc(j);
      end;
    end;
  end;
procedure swap(var x,y:longint);  //交换两个方块
  var tmp:longint;
  begin
    tmp:=x; x:=y; y:=tmp;
  end;
procedure print;  //找到最优解立即输出
  var i:longint;
  begin
    for i:=1 to n do
      with temp[i] do
        writeln(x,' ',y,' ',dir);
    halt;
  end;
function clear(dep:longint):boolean;  //清除相同方块
  var i,j:longint;
  begin
    fillchar(can,sizeof(can),false);
    clear:=true;
    for i:=0 to 4 do
      for j:=1 to 7 do begin
        if stack[dep][i*7+j]=0 then continue;
        if (j>1) and (j<7)
          and (stack[dep][i*7+j]=stack[dep][i*7+j-1])
          and (stack[dep][i*7+j]=stack[dep][i*7+j+1])
          then begin
            can[i*7+j]:=true; can[i*7+j-1]:=true; can[i*7+j+1]:=true;
          end;
        if (i>0) and (i<4)
          and (stack[dep][i*7+j]=stack[dep][(i-1)*7+j])
          and (stack[dep][i*7+j]=stack[dep][(i+1)*7+j])
          then begin
            can[i*7+j]:=true; can[(i-1)*7+j]:=true; can[(i+1)*7+j]:=true;
          end;
      end;
    for i:=1 to 35 do
      if can[i] then begin
        clear:=false;
        stack[dep][i]:=0;
      end;
  end;
procedure process(dep,pos,dir:longint);  //处理当前操作（向左移动/交换，向右移动/交换）
  begin
    stack[dep]:=stack[dep-1];
    swap(stack[dep][pos],stack[dep][pos+dir]);
    repeat
      drop(dep);
    until clear(dep);
  end;
procedure dfs(dep:longint);  //深度优先搜索
  var i:longint;
  begin
    if dep=n+1 then begin
      if check then print;
      exit;
    end;
    for i:=1 to 35 do begin
      if stack[dep-1][i]=0 then continue;
      if (i+7<=35) and (stack[dep-1][i]<>stack[dep-1][i+7]) then begin
        process(dep,i,7);
        with temp[dep] do begin
          x:=(i-1) div 7; y:=i-x*7-1; dir:=1;
        end;
        dfs(dep+1);
      end;
      if (i-7>=1) and (stack[dep-1][i-7]=0) then begin
        process(dep,i,-7);
        with temp[dep] do begin
          x:=(i-1) div 7; y:=i-x*7-1; dir:=-1;
        end;
        dfs(dep+1);
      end;
    end;
  end;
begin
  init;
  dfs(1);
  writeln(-1);
end.