【树状数组】NOI2004 郁闷的出纳员…

【树状数组】郁闷的出纳员

Time Limit:1000MS  Memory Limit:65536K
Total Submit:10 Accepted:4

Description

【问题描述】

　　OIER公司是一家大型专业化软件公司，有着数以万计的员工。作为一名出纳员，我的任务之一便是统计每位员工的工资。这本来是一份不错的工作，但是令人郁闷的是，我们的老板反复无常，经常调整员工的工资。如果他心情好，就可能把每位员工的工资加上一个相同的量。反之，如果心情不好，就可能把他们的工资扣除一个相同的量。我真不知道除了调工资他还做什么其它事情。
　　工资的频繁调整很让员工反感，尤其是集体扣除工资的时候，一旦某位员工发现自己的工资已经低于了合同规定的工资下界，他就会立刻气愤地离开公司，并且再也不会回来了。每位员工的工资下界都是统一规定的。每当一个人离开公司，我就要从电脑中把他的工资档案删去，同样，每当公司招聘了一位新员工，我就得为他新建一个工资档案。
　　老板经常到我这边来询问工资情况，他并不问具体某位员工的工资情况，而是问现在工资第k多的员工拿多少工资。每当这时，我就不得不对数万个员工进行一次漫长的排序，然后告诉他答案。
　　好了，现在你已经对我的工作了解不少了。正如你猜的那样，我想请你编一个工资统计程序。怎么样，不是很困难吧？

Input

第一行有两个非负整数n和min。n表示下面有多少条命令，min表示工资下界。

接下来的n行，每行表示一条命令。命令可以是以下四种之一：

名称 格式 作用
I命令 I_k 新建一个工资档案，初始工资为k。如果某员工的初始工资低于工资下界，他将立刻离开公司。
A命令 A_k 把每位员工的工资加上k
S命令 S_k 把每位员工的工资扣除k
F命令 F_k 查询第k多的工资
_（下划线）表示一个空格，I命令、A命令、S命令中的k是一个非负整数，F命令中的k是一个正整数。

在初始时，可以认为公司里一个员工也没有。

另外，刚进公司发现工资低就走了的人不算在离开公司的人数里。

数据范围
I命令的条数不超过 100000
A命令和S命令的总条数不超过 100
F命令的条数不超过100000
每次工资调整的调整量不超过1000
新员工的工资不超过100000

Output

输出的行数为F命令的条数加一。
对于每条F命令，你的程序要输出一行，仅包含一个整数，为当前工资第k多的员工所拿的工资数，如果k大于目前员工的数目，则输出-1。
输出的最后一行包含一个整数，为离开公司的员工的总数。

Sample Input

9 10 
I 60 
I 70 
S 50 
F 2 
I 30 
S 15 
A 5 
F 1 
F 2 

Sample Output

10 
20 
-1 
2 

Source

NOI2004

 

 

用树状数组来解题。

因为

1.新员工工资最高不超过100000 

2.A命令和S命令的总条数不超过 100

3.每次工资调整的调整量不超过1000 
所以设置一个长度为400000 的一维数组a，下标表示员工工资数，里面放个树状数组。

 

对于调整工资，可以设置一个变量key,代表0的意思

如果是A命令，dec（key，k）；就相当于在一个数轴中，把原点向左平移了k，其他值就相应加了k

如果是S命令，inc（key，k）；就相当于在一个数轴中，把原点向右平移了k，其他值就相应减了k

这样就可能会有员工离开，就枚举 for i:=原来的k to 改变后的k,如果找到a[i]＝1 就把这个点删掉。这里删点的方法只能是找到一个删一个，不能先统计区间里的点数，在一起删去，用树状数组无法实现。

 

key的最小值是－100000，但如果把a开为[-100000,200000]用树状数组是会产生问题，所以就开一个400000（300000的过不了，我也不知道为什么）的数组，key的初始值为200000，每读入一个初始工资时把它－工资下限得到的是一个差值＋key，这个结果就作为数组下标。

 

寻找第k多的工资，就等于找第 总数－k＋1  少的工资，因为树状数组记录的是有多少个人的工资比该员工的低。用二分法寻找 数值符合的数组下标 ，可能有多个下标都满足该数值，这时就要找最左的下标。当 总数－k＋1  <=0时，就输出－1，因为根本没有k个人。

 

就是这样，还是挺麻烦的。

 

 

const
 maxn=500010;
var
 c:char;
 n,min,m,tot,key,i,now:longint;
 a:array[0..maxn]of longint;

procedure add(x,data:longint);
begin
 if x=0 then exit;
 while x<=maxn do
  begin
   a[x]:=a[x]+data;
   x:=x+x and -x;
  end;
end;

function fin(x:longint):longint;
begin
 fin:=0;
 if x=0 then exit;
 while x>0 do
  begin
   inc(fin,a[x]);
   x:=x-x and -x;
  end;
end;

procedure change(x:longint);
var
 i,key0,s:longint;
begin
 s:=0;
  key0:=key;
  key:=key+x;
  s:=fin(key-1);
  add(key,-s);
  for i:=key0 to key-1 do a[i]:=0;
  inc(tot,s);
  dec(now,s);
end;

procedure insert(x:longint);
begin
 x:=x-min+key;
 add(x,1);
end;

procedure find(x:longint);
var
 l,r,y:longint;
begin
 l:=key; r:=key-min+200000;
 while l<=r do
  begin
  y:=fin((l+r) div 2);
  if y>=x then r:=(l+r) div 2-1
          else l:=(l+r) div 2+1
  end;
  writeln(l-key+min);
end;

begin
 tot:=0;
 now:=0;
 readln(n,min);
 key:=min+200000;
 for i:=1 to n do
  begin
   read(c);
   readln(m);
   if c='I' then
    begin
     if m>=min then
     begin
     insert(m);
     inc(now);
     end;
    end
    else
   if c='A' then
    begin
     key:=key-m;
    end
    else
   if c='S' then
    begin
     change(m);
    end
    else
   if c='F' then
    begin
    if now-m+1>0 then find(now-m+1)
                 else writeln(-1);
    end;
  end;
  writeln(tot);
end.