Sqlserver 字符串分割

--字符串分割，返回字符串按指定分割符分割后长度
--使用：select dbo.Fun_Get_StrArrayLength('1,2,3,4',',')

CREATE function [dbo].[Fun_Get_StrArrayLength]
(
 @str varchar(1024),  --要分割的字符串
 @split varchar(10)   --分隔符号
)
returns int
as
 begin
  declare @location int
  declare @start int
  declare @length int
  set @str=ltrim(rtrim(@str))  --去左右空格
 /*
 charindex()
 CHARINDEX (<’substring_expression’>， <expression>)
 返回字符串中某个指定的子串出现的开始位置。
 其中substring _expression 是所要查找的字符表达式，expression 可为字符串也可为列名表达式。如果没有发现子串，则返回0 值。
 */
  set @location=charindex(@split,@str) --找到第一个分割符所在的位置 如不存在返回0
  set @length=1
   while @location<>0
     begin
      set @start=@location+1
      set @location=charindex(@split,@str,@start)
      set @length=@length+1
     end
   return @length
 end

GO

--字符串分割，返回字符串指定位置字符

--select [dbo].[Fun_Get_StrArrayStrOfIndex]('1,2,3,4',',',3)
CREATE function [dbo].[Fun_Get_StrArrayStrOfIndex]
(
 @str varchar(1024),  --要分割的字符串
 @split varchar(10),  --分隔符号
 @index int --取第几个元素
)
returns varchar(1024)
as
begin
 declare @location int
 declare @start int
 declare @next int
 declare @seed int
 set @str=ltrim(rtrim(@str))
 set @start=1
 set @next=1
 set @seed=len(@split)
 set @location=charindex(@split,@str)
 while @location<>0 and @index>@next
   begin
    set @start=@location+@seed
    set @location=charindex(@split,@str,@start)
    set @next=@next+1
   end
 if @location =0 select @location =len(@str)+1

--这儿存在两种情况：1、字符串不存在分隔符号 2、字符串中存在分隔符号，跳出while循环后，@location为0，那默认为字符串后边有一个分隔符号。
 return substring(@str,@start,@location-@start)
end
GO