Delphi图像处理 -- 线性亮度/对比度调整

版权声明:本文为博主原创文章,遵循 CC 4.0 BY-SA 版权协议,转载请附上原文出处链接和本声明。
本文链接:https://blog.csdn.net/maozefa/article/details/4778934

阅读提示:

    《Delphi图像处理》系列以效率为侧重点,一般代码为PASCAL,核心代码采用BASM。

    《C++图像处理》系列以代码清晰,可读性为主,全部使用C++代码。

    尽可能保持二者内容一致,可相互对照。

   本文代码必须包括文章《Delphi图像处理 -- 数据类型及公用过程》中的ImageData.pas单元

 

    本文代码是在《Delphi图像处理 -- 亮度/对比度调整》基础上,通过改非亮度为线性亮度而成的。

    图像亮度调整分为非线性和线性两种方法。

    非线性图像亮度是将图像像素的R、G、B分别加上或减去某个值,其优点是代码简单,亮度调整速度快;缺点是图像信息损失较大,调整过的 图像显得平淡,无层次感。

    线性图像亮度一般是将图像像素的RGB转换为HSL(HSV)等颜色空间,对L(V)部分进行增减调整后,再转换为RGB颜色空间,优点是调整过图像层次感很强;缺点是代码较复杂,调整速度慢,而且当图像亮度增减量较大时有很大的失真。

    针对上面两种方法的优缺点,本人参照Photoshop的对比度、饱和度调整原理(可参见本人的有关文章),对图像亮度调整方法进行了改进,经测试,效果还不错,主要有不失真调整范围宽、有较好的层次感、尽可能减少图像信息损失量等;同时,在代码处理上,采用了灰度表查找法,先按制造了一个256个元素大小的线性亮度/对比度查找表,然后对图像数据逐像素按R、G、B分量值在查找表中取得调整后的数据,因此处理速度同《Delphi图像处理 -- 亮度/对比度调整》中的非线性亮度/对比度是基本相同的。

    原理用公式表示为:

    如果亮度增减量value范围为 -1  --  +1,当value > 0时:

      rgb = RGB + RGB * (1 / (1 - value) - 1)

    当value < 0时:

      rgb = RGB + RGB * value

    下面是图像线性亮度/对比度调整代码:

function _CheckRgb(Rgb: Integer): Integer;
asm
    test    eax, eax
    jge     @@1
    xor     eax, eax
    ret
@@1:
    cmp     eax, 255
    jle     @@2
    mov     eax, 255
@@2:
end;

procedure ImageLineBrightContrast(var Data: TImageData; Bright, Contrast, Threshold: Integer);
var
  vs: TGrayTable;
  cv, bv: Single;
  i, v: Integer;
  height, dataOffset: Integer;
begin
  if (Bright = 0) and (Contrast = 0) then Exit;
  if Bright <= -255 then bv := -1 else bv := Bright / 255;
  if (Bright > 0) and (Bright < 255) then
    bv := 1 / (1 - bv) - 1;
  if Contrast <= -255 then cv := -1 else cv := Contrast / 255;
  if (Contrast > 0) and (Contrast < 255) then
    cv := 1 / (1 - cv) - 1;
  for i := 0 to 255 do
  begin
    if Contrast > 0 then v := _CheckRgb(i + Round(i * bv)) else v := i;
    if Contrast >= 255 then
    begin
      if v >= Threshold then v := 255 else v := 0;
    end
    else
      v := _CheckRgb(v + Round((v - Threshold) * cv));
    if Contrast <= 0 then vs[i] := _CheckRgb(v + Round(v * bv)) else vs[i] := v;
  end;
  asm
    mov     eax, Data
    call    _SetDataRegs
    mov     height, edx
    mov     dataOffset, ebx
    lea     esi, vs;
@@yLoop:
    push    ecx
@@xLoop:
    movzx   eax, [edi].TARGBQuad.Blue
    movzx   ebx, [edi].TARGBQuad.Green
    movzx   edx, [edi].TARGBQuad.Red
    mov     al, [esi+eax]
    mov     bl, [esi+ebx]
    mov     dl, [esi+edx]
    mov     [edi].TARGBQuad.Blue, al
    mov     [edi].TARGBQuad.Green, bl
    mov     [edi].TARGBQuad.Red, dl
    add     edi, 4
    loop    @@xLoop
    pop     ecx
    add     edi, dataOffset
    dec     height
    jnz     @@yLoop
@@Exit:
  end;
end;

 

    下面是用RGB非线性亮度调整(中)、HSL线性亮度调整(右)以及本文介绍的改进线性亮度调整方法(左)对同一照片的调整结果贴图:

                      原图:照片原图

3种方法亮度调整对比图

   

    《Delphi图像处理》系列使用GDI+单元下载地址和说明见文章《GDI+ for VCL基础 -- GDI+ 与 VCL》。

    因水平有限,错误在所难免,欢迎指正和指导。邮箱地址:maozefa@hotmail.com

    这里可访问《Delphi图像处理 -- 文章索引》。

 

展开阅读全文

没有更多推荐了,返回首页