批处理中使输入隐藏的代码及解释

: by Herbert Kleebauer 
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
@echo off 
echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com
set /p password=Enter password:<nul
for /f "tokens=*" %%i in ('in.com') do set password=%%i
pause
del in.com
echo.
echo The Password is:"%password%"
pause

解释:http://www.cn-dos.net/forum/viewthread.php?tid=29806

这个代码中的文件名是加了单引号，这就意味着这是一个外部命令，
也就是说，它是要被执行的。
in.com经过反汇编后，代码如下：

00000000: 685031                    push 3150 
00000003: 58                        pop ax     ; AX=3150
00000004: 353030                    xor ax,3030 ; AX=0160
00000007: 50                        push ax 
00000008: 5B                        pop bx ; BX=0160
00000009: 50                        push ax 
0000000A: 5A                        pop dx ; DX=0160
0000000B: 42                        inc dx 
0000000C: 42                        inc dx 
0000000D: 42                        inc dx  ; DX=0163
0000000E: 666823622323              push 23236223 
00000014: 6658                      pop eax ; EAX=23236223
00000016: 662D56406024              sub eax,24604056 ; EAX=FEC321CD
0000001C: 6650                      push eax 
0000001E: 665D                      pop ebp ; EBP=FEC321CD
00000020: 66332F                    xor ebp,dword ptr [bx] ; EBP=EBP ^ [0160]
00000023: 66312F                    xor dword ptr [bx],ebp ; [0160]=FEC321CD
                                                           ; +0160 CD
                                                           ; +0161 21
                                                           ; +0162 C3
                                                           ; +0163 FE
其中+0160 与 +0161中的两个字节CD 21反汇编出来就是int 21h指令
+0162中的C3反汇编出来就是ret指令
最后那个+163中的FE是DOS输入功能0Ah的参数(前面的DX=0163就是指向了这个FE)，
表示最多允许输入254个字符(包括回车在内)
00000026: 352B2B                    xor ax,2B2B  ; AX=0AE6，其中0Ah是DOS功能号，
                                                 ; E6没有用处
00000029: 7535                      jnz 00000060 ; 这里肯定会发生跳转，相当于jmp 160
0000002B: 78                                     ; 最后的78无用
0000002C: 0D                                     ; 0D与0A是echo时自动
0000002D: 0A                                     ; 产生的回车换行符
程序跳转到160后，就会执行以下指令：
int 21h ; 此时AH=0Ah, DX=0163h, 因此执行DOS的输入功能，
       ; 输入内容自动保存到+165开始的缓冲区中，而for循环会把各个字符逐个读出
ret     ; 程序返回到操作系统，自动结束

总结一下，这个in.com的作用是通过键盘输入一串字符，长度不超过254个(含回车)。
这个批处理还是比较巧妙的，它用一串可显示的字符串构造了一个可执行代码，实现了
键盘输入功能，配合for循环使得在批处理中可以实现不回显输入。

P.S.: 根据分析，这个批处理中的echo语句所包含的一堆乱码里的最后
     那个字符(即>前面++u5x中的x)可以删除不要。也可就是说，
         echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com
     可以改成
         echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5>in.com

支持中文显示的代码:

@echo off 
chcp 437>nul&graftabl 936>nul
echo hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com
set  /p password=请输入密码:<nul
for /f "tokens=*" %%i in ('in.com') do set password=%%i
del in.com
echo.
echo The Password is:"%password%"
pause