startup.s 一切从这开始

;/****************************************Copyright (c)**************************************************
;**                                  广州致远电子有限公司
;**
;**                                 http://www.21cm.com.cn
;**
;**--------------文件信息--------------------------------------------------------------------------------
;**文   件   名: startup.s
;**创   建   人: 黄绍斌
;**最后修改日期: 2005年11月11日
;**描        述: S3C2410异常向量表与c语言代码的接口，包括初始化堆栈、堆空间分配、打开/关断中断的代码
;**                
;**--------------历史版本信息----------------------------------------------------------------------------
;** 创建人: 
;** 版  本: 
;** 日　期: 
;** 描　述: 
;**
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/


; /* 定义堆栈的大小 */
;// **** 用户可根据实际需要修改 ****
SVC_STACK_LEGTH     EQU         64
FIQ_STACK_LEGTH     EQU         64
IRQ_STACK_LEGTH     EQU         64
ABT_STACK_LEGTH     EQU         0
UND_STACK_LEGTH     EQU         0


   
; /*************************************************************************/
; /* CPSR寄存器的位域                                                      */
; /*************************************************************************/
; /*                                                                       */
; /* 31  30  29   28         7   6   5   4   3   2   1   0                 */
; /*+---+---+---+---+--ss--+---+---+---+---+---+---+---+---+               */
; /*| N | Z | C | V |      | I | F | T |     M4 ~ M0       |               */
; /*+---+---+---+---+--ss--+---+---+---+---+---+---+---+---+               */
; /*                                                                       */
; /* Processor Mode and Mask                                               */
; /*                                                                       */
; /*************************************************************************/
Mode_USR        EQU     0x10
Mode_FIQ        EQU     0x11
Mode_IRQ        EQU     0x12
Mode_SVC        EQU     0x13
Mode_ABT        EQU     0x17
Mode_UND        EQU     0x1B
Mode_SYS        EQU     0x1F 
I_BIT           EQU     0x80 ; //when I bit is set (1), IRQ is disabled
F_BIT           EQU     0x40 ; //when F bit is set (1), FIQ is disabled




    IMPORT __use_no_semihosting_swi
    


; /************************************************************************/
; /* 引入的外部标号在这声明 */
IMPORT  __main                          ; //C语言主程序入口 
IMPORT  FIQ_Exception ; //FIQ中断服务程序
IMPORT  IRQ_Exception ; //IRQ中断服务程序 
IMPORT  TargetBusInit                   ; //针对目标板的总线系统初始化
IMPORT  TargetResetInit ; //调用main函数前目标板初始化代码

; /* 给外部使用的标号在这声明 */
    EXPORT  vectors    
    EXPORT  ResetInit
        EXPORT  DisableMMU 
        EXPORT  EnableICache  
        EXPORT  DisableICache
        EXPORT  EnableDCache  
        EXPORT  DisableDCache 
        
        EXPORT bottom_of_heap
        EXPORT  StackUsr
        
    ;EXPORT  __rt_div0
    EXPORT Reset
    EXPORT  __user_initial_stackheap    
    


; /************************************************************************/
    CODE32
    AREA    vectors,CODE,READONLY
; /* 异常向量表 */
Reset
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0
        LDR     PC, IRQ_Addr
        LDR     PC, FIQ_Addr


ResetAddr           DCD     ResetInit
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     SoftwareInterrupt
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
Nouse               DCD     0
IRQ_Addr            DCD     IRQ_Exception
FIQ_Addr            DCD     FIQ_Handler




; /* 未定义指令 */
Undefined
        B       Undefined
        


; /* 软中断 */
SoftwareInterrupt                               
        CMP     R0, #4
        LDRLO   PC, [PC, R0, LSL #2]
        MOVS    PC, LR


SwiFunction
        DCD     IRQDisable       ;//0
        DCD     IRQEnable        ;//1
        DCD FIQDisable ;//2
        DCD FIQEnable ;//3


IRQDisable
        ; 关IRQ中断
        MRS     R0, SPSR
        ORR     R0, R0, #I_BIT
        MSR     SPSR_c, R0
        MOVS    PC, LR


IRQEnable
        ; 开IRQ中断
        MRS     R0, SPSR
        BIC     R0, R0, #I_BIT
        MSR     SPSR_c, R0
        MOVS    PC, LR
        
FIQDisable
        ; 关FIQ中断
        MRS     R0, SPSR
        ORR     R0, R0, #F_BIT
        MSR     SPSR_c, R0
        MOVS    PC, LR


FIQEnable
        ; 开FIQ中断
        MRS     R0, SPSR
        BIC     R0, R0, #F_BIT
        MSR     SPSR_c, R0
        MOVS    PC, LR


        
; /* 取指中止 */
PrefetchAbort
        B       PrefetchAbort


; /* 取数据中止 */
DataAbort
        B       DataAbort
        


; /* 快速中断 */
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}        
        BL      FIQ_Exception ; //FIQ中断处理
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4                
                


;/*********************************************************************************************************
;** 函数名称: DisableMMU
;** 功能描述: 禁止MMU
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 黄绍斌
;** 日　期: 2005年11月30日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/ 
DisableMMU
        MRC     p15,0,R0,c1,c0,0
        BIC     R0,R0,#(1<<0)
        MCR     p15,0,R0,c1,c0,0
        MOV     PC, LR
        


;/*********************************************************************************************************
;** 函数名称: EnableICache
;** 功能描述: 使能指令CACHE
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 黄绍斌
;** 日　期: 2005年11月30日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/ 
EnableICache        
        MRC     p15,0,R0,c1,c0,0
        ORR     r0,R0,#(1<<12)
        MCR     p15,0,R0,c1,c0,0
        MOV     PC, LR
        


;/*********************************************************************************************************
;** 函数名称: DisableICache
;** 功能描述: 禁止指令CACHE
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 黄绍斌
;** 日　期: 2005年11月30日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
DisableICache       
        MRC     p15,0,R0,c1,c0,0
        BIC     R0,R0,#(1<<12)
        MCR     p15,0,R0,c1,c0,0
        MOV     PC, LR
   
   
;/*********************************************************************************************************
;** 函数名称: EnableDCache
;** 功能描述: 使能数据CACHE
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 黄绍斌
;** 日　期: 2005年11月30日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
EnableDCache        
        MRC     p15,0,R0,c1,c0,0
        ORR     R0,R0,#(1<<2)
        MCR     p15,0,R0,c1,c0,0
        MOV     PC, LR




;/*********************************************************************************************************
;** 函数名称: DisableDCache
;** 功能描述: 禁止数据CACHE
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 黄绍斌
;** 日　期: 2005年11月30日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
DisableDCache       
        MRC     p15,0,R0,c1,c0,0
        BIC     R0,R0,#(1<<2)
        MCR     p15,0,R0,c1,c0,0
        MOV     PC,LR


      
;/*********************************************************************************************************
;** 函数名称: InitStack
;** 功能描述: 初始化堆栈
;** 输　入:   无
;** 输　出 :  无
;** 全局变量: 无
;** 调用模块: 无
;** 
;** 作　者: 陈明计
;** 日　期: 2004年2月2日
;**-------------------------------------------------------------------------------------------------------
;** 说  明: 给CPSR_c赋值采用宏的方式
;** 修　改: 黄绍斌
;** 日　期: 2005年11月11日
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
InitStack    
        MOV     R0, LR


; /* 设置管理模式堆栈 */
        MSR     CPSR_c, #(Mode_SVC | I_BIT | F_BIT) ; 0xd3
        LDR     SP, StackSvc
; /* 设置中断模式堆栈 */
        MSR     CPSR_c, #(Mode_IRQ | I_BIT | F_BIT) ; 0xd2
        LDR     SP, StackIrq
; /* 设置快速中断模式堆栈 */
        MSR     CPSR_c, #(Mode_FIQ | I_BIT | F_BIT) ; 0xd1
        LDR     SP, StackFiq
; /* 设置中止模式堆栈 */
        MSR     CPSR_c, #(Mode_ABT | I_BIT | F_BIT) ; 0xd7
        LDR     SP, StackAbt
; /* 设置未定义模式堆栈 */
        MSR     CPSR_c, #(Mode_UND | I_BIT | F_BIT) ; 0xdb
        LDR     SP, StackUnd
; /* 设置系统模式堆栈 */
        MSR     CPSR_c, #(Mode_SYS | I_BIT | F_BIT) ; 0xdf
        LDR     SP, =StackUsr


        MOV     PC, R0
        
               
        
;/*********************************************************************************************************
;** 函数名称: ResetInit
;** 功能描述: 复位入口
;** 
;** 输　入: 无
;**
;** 输　出: 无
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 陈明计
;** 日　期: 2004年2月2日
;**-------------------------------------------------------------------------------------------------------
;** 修改人: 
;** 日　期: 
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
ResetInit
        BL      InitStack               ; //初始化堆栈                                              
        BL      TargetBusInit           ; //总线系统初始化 (函数中不允许堆栈操作)
  BL TargetResetInit ; //针对目标板的系统初始化  
 
  MRC p15,0,R1,c1,c0,0 ; //(MMU设置，异步总线模式) 读控制寄存器
ORR R1,R1,#0xC0000000    ; //当HDIVN=1时操作有效
MRC p15,0,R1,c1,c0,0

        B       __main ; //跳转到c语言入口  
 
 
;/*********************************************************************************************************
;** 函数名称: __user_initial_stackheap 
;** 功能描述: 库函数初始化堆和栈，不能删除
;** 
;** 输　入: 参考库函数手册
;**
;** 输　出: 参考库函数手册
;**         
;** 全局变量: 无
;** 调用模块: 无
;**
;** 作　者: 陈明计
;** 日　期: 2004年2月2日
;**-------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日　期:
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
__user_initial_stackheap    
    LDR   r0,=bottom_of_heap
    MOV   pc,lr
         


StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4






; /* 分配堆栈空间 */
        AREA    MyStacks, DATA, NOINIT, ALIGN=2
SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;//管理模式堆栈空间
IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;//中断模式堆栈空间
FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;//快速中断模式堆栈空间
AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;//中止义模式堆栈空间
UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;//未定义模式堆栈






        AREA    Heap, DATA, NOINIT
bottom_of_heap    SPACE   1






        AREA    Stacks, DATA, NOINIT
StackUsr




END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/