Shader 学习笔记(10) Transparent Cutout效果

版权声明:如果你真的要转,请告诉我,让我嘚瑟一下 https://blog.csdn.net/qq_26365139/article/details/79957699

开始学习透明和半透明相关Shader效果,对于美术来讲是非常重要的部分.Transparent  Cutout在视觉效果和实体物体一样.透明度只能选择0和1.最终的返回的frag值在A上 还是默认的1.0

Shader "wx/Alpha Test"{
	Properties{
		_Color("Main Tint",Color)=(1,1,1,1)
		_MainTex("Main Tex",2D)="white"{}
		_Cutoff("Alpha Cutof",Range(0,1))=0.5
	}
	SubShader{
		
		Tags{"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"} //这里决定了透明的方法和效果
		Pass{
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _Cutoff;
			struct a2v
			{
				float4 vertex:POSITION;
				float4 normal:NORMAL;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f
			{
				float4 pos:SV_POSITION;
				float3 worldNormal:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float2 uv:TEXCOORD2;
			};
			v2f vert(a2v v){
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex);
				o.worldNormal=UnityObjectToWorldNormal(v.normal);
				o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
				o.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
				return o;
			}
			fixed4 frag(v2f i):SV_Target{
				fixed3 worldNormal=normalize(i.worldNormal);
				fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed4 texColor=tex2D(_MainTex,i.uv);
				clip(texColor.a-_Cutoff);    //用图片的alpha减去_Cutoff的值,判断,如果小于0,则透明值为0.
				fixed3 albedo=texColor.rgb*_Color.rgb;
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
				fixed3 diffuse=_LightColor0.rgb*albedo*max(0,dot(worldNormal,worldLightDir));
				return fixed4(ambient+diffuse,1.0);
			}
			ENDCG
		}
		
	}
	FallBack "VertexLit"
}

图1为shader效果,图2为_MainTex图片的alpha通道.


但这个shader还有个问题,如果图片本身没有alpha通道的话,_Cutoff就完全失去作用了.留着后续学习解决.

阅读更多
想对作者说点什么? 我来说一句

没有更多推荐了,返回首页