魔数:Class文件的标志
友情提示：字节码的二进制文件存的是16进制
官方文档位置
https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-4.html
Class类的本质（就是二进制流）
-
任何一个Class文件都对应着唯一 一个类或接口的定义信息，但反过来说，Class文件实际上它并不一定以磁盘文件的形式存在，也可能是二进制流。
-
Class文件是一组以8位字节为基础单位的二进制流。
Class文件格式
-
Class的结构不像XML等描述语言，由于它没有任何分隔符号。所以在其中的数据项，无论是字节顺序还是数量，都是被严格限定的，哪个字节代表什么含义，长度是多少，先后顺序如何，都不允许改变。
-
Class文件格式采用一种类似于C语言结构体的方式进行数据存储，这种结构中只有两种数据类型：无符号数和表。
-
无符号数属于基本的数据类型，以u1、u2、u4、u8来分别代表1个字节、2个字节、4个字节和8个字节的无符号数，无符号数可以用来描述数字、索引引用、数量值或者按照UTF-8编码构成字符串值。
-
表是由多个无符号数或者其他表作为数据项构成的复合数据类型，所有表都习惯性地以“_info”结尾（也就是常量池中存储的那么多_Info）。表用于描述有层次关系的复合结构的数据，整个Class文件本质上就是一张表。由于表没有固定长度，所以通常会在其前面加上个数说明
-
代码举例
public class Demo {
private int num = 1;
public int add(){
num = num + 2;
return num;
}
}
Class文件结构
Class文件的标识：魔数
- ·每个Class文件开头的4个字节的无符号整数称为魔数（Magic Number）
- 它的唯一作用是确定这个文件是否为一个能被虚拟机接受的有效合法的Class文件。即：魔数是Class文件的标识符。
- 魔数值固定为0xCAFEBABE。不会改变。
- 如果一个Class文件不以0xCAFEBABE开头，虚拟机在进行文件校验的时候就会直接抛出以下错误：
- 使用魔数而不是扩展名来进行识别主要是基于安全方面的考虑，因为文件扩展名可以随意地改动。
相同的文件类型，一般开头是有一样的标识
Class文件版本号
-
紧接着魔数的4个字节存储的是Class文件的版本号。同样也是4个字节。第5个和第6个字节所代表的含义就是编译的副版本号minor_version，而第7个和第8个字节就是编译的主版本号major_version。
-
它们共同构成了class文件的格式版本号。譬如某个Class文件的主版本号为M，副版本号为m，那么这个Class文件的格式版本号就确定为M.m。
-
版本号和Java编译器的对应关系如下表：
-
Java的版本号是从45开始的，JDK1.1之后的每个JDK大版本发布主版本号向上加1。
-
不同版本的Java编译器编译的Class文件对应的版本是不一样的。目前，高版本的Java虚拟机可以执行由低版本编译器生成的Class文件，但是低版本的Java虚拟机不能执行由高版本编译器生成的Class文件。否则JVM会抛出java.lang.UnsupportedClassVersionError异常。（向下兼容）
-
在实际应用中，由于开发环境和生产环境的不同，可能会导致该问题的发生。因此，需要我们在开发时，特别注意开发编译的JDK版本和生产环境中的JDK版本是否一致。
虚拟机JDK版本为1.k（k>=2）时，对应的class文件格式版本号的范围为45.0-44+k.0（含两端）。- 1
常量池：存放所有常量
- 常量池是Class文件中内容最为丰富的区域之一。常量池对于Class文件中的字段和方法解析也有着至关重要的作用。
- 随着Java虚拟机的不断发展，常量池的内容也日渐丰富。可以说，常量池是整个Class文件的基石。
- 在版本号之后，紧跟着的是常量池的数量，以及若干个常量池表项。
- 常量池中常量的数量是不固定的，所以在常量池的入口需要放置一项u2类型的无符号数，代表常量池容量计数值（constant_pool_count）。与Java中语言习惯不一样的是，这个容量计数是从1而不是0开始的。
- 由上表可见，Class文件使用了一个前置的容量计数器（constant_pool_count）加若干个连续的数据项（constant_pool）的形式来描述常量池内容。我们把这一系列连续常量池数据称为常量池集合。
- 常量池表项中，用于存放编译时期生成的各种字面量和符号引用，这部分内容将在类加载后进入方法区的运行时常量池中存放。
常量池计数器
- 由于常量池的数量不固定，时长时短，所以需要放置两个字节来表示常量池容量计数值。
- 常量池容量计数值（u2类型）：从1开始，表示常量池中有多少项常量。即constant_pool_count=1表示常量池中有0个常量项
举例
其值为0x0016，掐指一算，也就是22。
需要注意的是，这实际上只有21项常量。索引为范围是1-21。
通常我们写代码时都是从0开始的，但是这里的常量池却是从1开始，因为它把第0项常量空出来了。这是为了满足后面某些指向常量池的索引值的数据在特定情况下需要表达“不引用任何一个常量池项目”的含义，这种情况可用索引值0来表示。
常量池
- constant_pool是一种表结构，以1~constant_pool_count-1为索引。表明了后面有多少个常量项。
- 常量池主要存放两大类常量：字面量（Literal）和符号引用（Symbolic References）
- 它包含了class文件结构及其子结构中引用的所有字符串常量、类或接口名、字段名和其他常量。常量池中的每一项都具备相同的特征。第1个字节作为类型标记，用于确定该项的格式，这个字节称为tag byte（标记字节、标签字节）。
字面量和符号引用
在对这些常量解读前，我们需要搞清楚几个概念。
常量池主要存放两大类常量：字面量（Literal）和符号引用（Symbolic References）。如下表：
比如字面量， String str=“atguigu”; final int NUM=10;
com/atguigu/test/Demo这个就是类的全限定名，仅仅是把包名的“。“替换成“/”，为了使连续的多个全限定名之间不产生混淆，在使用时最后一般会加入一个“；”表示全限定名结束。
简单名称是指没有类型和参数修饰的方法或者字段名称，上面例子中的类的add()方法和num字段的简单名称分别是add和num。
描述符的作用是用来描述字段的数据类型、方法的参数列表（包括数量、类型以及顺序）和返回值。根据描述符规则，基本数据类型（byte、char、double、float、int、long、short、boolean）以及代表无返回值的void类型都用一个大写字符来表示，而对象类型则用字符L加对象的全限定名来表示，详见下表：
public class ArrayTest {
public static void main(String[] args) {
Object obj = new Object[1];
System.out.println(obj); // [Ljava.lang.Object;@1b6d3586
String[] str = new String[1];
System.out.println(str); // [Ljava.lang.String;@4554617c
long[] longs = new long[1];
System.out.println(longs); // [J@74a14482
}
}
描述符：方法的形参列表类型、返回值类型
虚拟机在加载Class文件时才会进行动态链接，也就是说，Class文件中不会保存各个方法和字段的最终内存布局信息，因此，这些字段和方法的符号引用不经过转换是无法直接被虚拟机使用的。当虚拟机运行时，需要从常量中获得对应的符号引用，再在类加载过程中的解析阶段将其替换为直接引用，并择到具体的内存地址中。
这里说明下符号引用和直接引用的区别与关联：
- 符号引用(这个没有加载到方法区)：符号引用以一组符号来描所引用的目标，符号可以是任何形式的字面量，只要使用时能无歧义地定位到目标即可。符号引用与虚拟机实现的内存布局无关，引用的目标并不一定已经加载到了内存中。
- 直接引用（这个已经加载到方发区）：直接引用可以是直接指向目标的指针、相对偏移量或是一个能间接定位到目时句构。直接引用是与拟机实现的内存有局相关的，同一个符号引用在不同虚拟机实例上翻译出来的直接引用一般不会相同。如果有了直接引用，那说明引用的目标必定已经存在于内存之中了。
常量类型和结构
课件+模拟课件：链接: https://pan.baidu.com/s/1JqlfuHxyLGkdS8H4dk2MOA 提取码: jfxe
魔数 小版本 大版本 常量池计数器(索引-1=常量项)
0A十六进制转10进制的值是10，10对应常量类型和结构表的tag(或者标志)，有u2 u2
tag=1，比较特殊，长度不固定
标志为10，和对应的常量一致
举列，查询第一个常量的第一个索引(指向声明方法的类描述符)
用Binary Viewer/Show Bytecode With Jclasslib直接看
- 一个字节一个字节的解析
- 使用javap命令解析：javap -verbose Demo.class 或jclasslib工具会更方便
- final常量直接显示值，没用指向索引
- byte,short,char,boolean标志为3的CONSTANT_Integer_info常量
- 这14种表（或者常量项结构）的共同点是：表开始的第一位是一个u1类型的标志位（tag），代表当前这个常量项使用的是哪种表结构，即哪种常量类型。
- 在常量池列表中，CONSTANT_Utf8_info常量项是一种使用改进过的UTF-8编码格式来存储诸如文字字符串、类或者接口的全限定名、字段或者方法的简单名称以及描述符等常量字符串信息。
- 这14种常量项结构还有一个特点是，其中13个常量项占用的字节固定，只有CONSTANT_Utf8_info占用字节不固定，其大小由1ength决定。为什么呢？因为从常量池存放的内容可知，其存放的是字面量和符号引用，最终这些内容都会是一个字符串，这些字符串的大小是在编写程序时才确定，比如你定义一个类，类名可以取长取短，所以在没编译前，大小不固定，编译后，通过utf-8编码，就可以知道其长度。(常量类型和结构表的第一个)
- 常量池：可以理解为class文件之中的资源仓库，它是Class文件结构中与其他项目关联最多的数据类型（后面的很多数据类型都会指向此处），也是占用Class文件空间最大的数据项目之一。
Java代码在进行Javac编译的时候，并不像C和C++那样有“连接”这一步骤，而是在虚拟机加载Class文件的时候进行动态链接。也就是说，在Class文件中不会保存各个方法、字段的最终内存布局信息，因此这些字段、方法的符号引用不经过运行期转换的话无法得到真正的内存入口地址，也就无法直接被虚拟机使用。当虚拟机运行时，需要从常量池获得对应的符号引用，再在类创建时或运行时解析、翻译到具体的内存地址之中。关于类的创建和动态链接的内容，在虚拟机类加载过程时再进行详细讲解
访问标识
占用两个字节
- 访问标识（access_flag、访问标志、访问标记）
- 在常量池后，紧跟着访问标记。该标记使用两个字节表示用于识别一些类或者接口层次的访问信息，包括：这个Class是类还是接口；是否定义为public类型；是否定义为abstract类型；如果是类的话，是否被声明为final等。各种访问标记如下所示：
- 类的访问权限通为ACC_开头的常量。
- 每一种类型的表示都是通过设置访问标记的32位中的特定位来实现的。比如，若是public final的类，则该标记为ACC_PUBLIC |ACC_FINAL。
- 使用ACC_SUPER可以让类更准确地定位到父类的方法super.method()，现代编译器都会设置并且使用这个标记。
字节码图
16进制的21，对应访问标识表的所有标志值相加等于21，即是ACC_PUBLIC和ACC_SUPER。
补充说明
- 带有ACC_INTERFACE标志的class文件表示的是接口而个是类，反之则表示的是类而个是接口。
- 如果一个class文件被设置了ACC_INTERFACE标志，那么同时也得设置ACC_ABSTRACT标志。同时它不能再设置ACC_FINAL、ACC_SUPER或ACC_ENUM标志。
- 如果没有设置ACC_INTERFACE标志，那么这个class文件可以具有上表中除ACC_ANNOTATION外的其他所有标志。当然，ACC_FINAL和ACC_ABSTRACT这类互斥的标志除外。这两个标志不得同时设置。(注解是@interface)
- ACC_SUPER标志用于确定类或接口里面的invokespecial指令使用的是哪一种执行语义。针对Java虚拟机指令集的编译器都应当设置这个标志。对于JavaSE8及后续版本来说，无论class文件中这个标志的实际值是什么，也不管class文件的版本号是多少，Java虚拟机都认为每个class文件均设置了ACC_SUPER标志。
- ACC_SUPER标志是为了向后兼容由旧Java编译器所编译的代码而设计的。目前的ACC_SUPER标志在由JDK1.0.2之前的编译器所生成的access flags中是没有确定含义的，如果设置了该标志，那么0racle的Java虚拟机实现会将其忽略。
- ACC_SYNTHETIC标志意味着该类或接口是由编译器生成的，而不是由源代码生成的。
- 注解类型必须设置ACC_ANNOTATION标志。如果设置了ACC_ANNOTATION标志，那么也必须设置ACC_ INTERFACE标志。(注解是@interface)
- ACC_ENUM标志表明该类或其父类为枚举类型。
类索引、父类索引、接口索引集合
-
在访问标记后，会指定该类的类别、父类类别以及实现的接口，格式如下：
-
这三项数据来确定这个类的继承关系。
- 类索引用于确定这个类的全限定名
- 父类索引用于确定这个类的父类的全限定名。由于Java语言不允许多重继承，所以父类索引只有一个，除了java.lang.object之外，所有的Java类都有父类，因此除了java.lang.Object外，所有Java类的父类索引都不为e。
- 接口索引集合就用来描述这个类实现了哪些接口，这些被实现的接口将按implements语句（如果这个类本身是一个接口，则应当是extends语句）后的接口顺序从左到右排列在接口索引集合中。
字节码文件说明
-
this_class（类索引）
- 字节无符号整数，指向常量池的索引。它提供了类的全限定名，如com/atguigu/javal/Demo。this_class的值必须是对常量池表中某项的一个有效索引值。常量池在这个索引处的成员必须为CONSTANT_Classinfo类型结构体，该结构体表示这个class文件所定义的类或接口。
-
super_class（父类索引）
- 2字节无符号整数，指向常量池的索引。它提供了当前类的父类的全限定名。如果我们没有继承任何类，其默认继承的是java/lang/Object类。同时，由于Java不支持多继承，所以其父类只有一个。
- superclass指向的父类不能是final。
-
interfaces
- 指向常量池索引集合，它提供了一个符号引用到所有已实现的接口
- 由于一个类可以实现多个接口，因此需要以数组形式保存多个接口的索引，表示接口的每个索引也是一个指向常量池的CONSTANT_Class（当然这里就必须是接口，而不是类）。
-
interfaces_count（接口计数器）
- interfaces_count项的值表示当前类或接口的直接超接口数量。
-
interfaces[]（接口索引集合）
- interfaces[]中每个成员的值必须是对常量池表中某项的有效索引值，它的长度为interfaces_count。每个成员interfaces[i]必须为CONSTANT_Class_info结构，其中0<=i< interfaces_count。在interfaces[]中，各成员所表示的接口顺序和对应的源代码中给定的接口顺序（从左至右）一样，即interfaces[0]对应的是源代码中最左边的接口。
java单继承，多接口
字节码图
字段表集合
fields
- 用于描述接口或类中声明的变量。字段（field）包括类级变量以及实例级变量，但是不包括方法内部、代码块内部声明的局部变量(local variables)。
- 字段叫什么名字、字段被定义为什么数据类型，这些都是无法固定的，只能引用常量池中的常量来描述。
- 它指向常量池索引集合，它描述了每个字段的完整信息。比如字段的标识符、访问修饰符（public、private或protected）、是类变量还是实例变量（static修饰符）、是否是常量（final修饰符）等。
注意事项
- 字段表集合中不会列出从父类或者实现的接口中继承而来的字段，但有可能列出原本Java代码之中不存在的字段。譬如在内部类中为了保持对外部类的访问性，会自动添加指向外部类实例的字段。
- 在Java语言中字段是无法重载的，两个字段的数据类型、修饰符不管是否相同，都必须使用不一样的名称，但是对于字节码来讲，如果两个字段的描述符不一致，那字段重名就是合法的。
字段计数器
字段表
-
fields表中的每个成员都必须是一个fields_info结构的数据项，用于表示当前类或接口中某个字段的完整描述。
-
一个字段的信息包括如下这些信息。这些信息中，各个修饰符都是布尔值，要么有，要么没有。
- 作用域（public、private、protected修饰符）
- 是实例变量还是类变量（static修饰符）
- 可变性（final）
- 并发可见性（volatile修饰符，是否强制从主内存读写）
- 可否序列化（transient修饰符）
- 字段数据类型（基本数据类型、对象、数组）
- 字段名称
-
字段表结构
字段表访问标识
我们知道，一个字段可以被各种关键字去修饰，比如：作用域修饰符（public、private、protected）、static修饰符、final修饰符、volatile修饰符等等。因此，其可像类的访问标志那样，使用一些标志来标记字段。字段的访问标志有如下:
字段名索引
根据字段名索引的值，查询常量池中的指定索引项即可。
描述符索引(和之前的一样)
描述符的作用是用来描述字段的数据类型、方法的参数列表（包括数量、类型以及顺序）和返回值。根据描述符规则，基本数据类型（byte，char，double，float，int，1ong，short，boolean）及代表无返回值的void类型都用一个大写字符来表示，而对象则用字符L加对象的全限定名来表示，如下所示：
字段表访问标识，字段名索引，描述符索引
属性表集合
- 一个字段还可能拥有一些属性，用于存储更多的额外信息。比如初始化值、一些注释信息等。属性个数存放在attribute_count中，属性具体内容存放在attributes数组中。
以常量属性为例，结构为：
ConstantValue_attribute{
u2 attribute_name_index；
u4 attribute_length；
u2 constantvalue_index；
}
说明：对于常量属性而言，attribute_length值恒为2。
方法表聚合
methods
指向常量池索引集合，它完整描述了每个方法的签名。
- 在字节码文件中，每一个method_info项都对应着一个类或者接口中的方法信息。比如方法的访问修饰符（public、private或protected），方法的返回值类型以及方法的参数信息等。
- 如果这个方法不是抽象的或者不是native的，那么字节码中会体现出来。
- 一方面，methods表只描述当前类或接口中声明的方法，不包括从父类或父接口继承的方法。另一方面，methods表有可能会出现由编译器自动添加的方法，最典型的便是编译器产生的方法信息（比如：类（接口）初始化方法()和实例初始化方法()）。
使用注意事项
- 在Java语言中，要重载（Overload）一个方法，除了要与原方法具有相同的简单名称之外，还要求必须拥有一个与原方法不同的特征签名，特征签名就是一个方法中各个参数在常量池中的字段符号引用的集合，也就是因为返回值不会包含在特征签名之中，因此Java语言里无法仅仅依靠返回值的不同来对一个已有方法进行重载。但在Class文件格式中，特征签名的范围更大一些，只要描述符不是完全一致的两个方法就可以共存。也就是说，如果两个方法有相同的名称和特征签名，但返回值不同，那么也是可以合法共存于同一个class文件中。
- 也就是说，尽管Java语法规范并不允许在一个类或者接口中声明多个方法签名相同的方法，但是和Java语法规范相反，字节码文件中却恰恰允许存放多个方法签名相同的方法，唯一的条件就是这些方法之间的返回值不能相同。
返回值不一样的方法(同名同参数)，java不允许。但class文件相反，只要求方法的返回值不能相同
方法计数器器
- methods_count的值表示当前class文件methods表的成员个数。使用两个字节来表示。
- methods 表中每个成员都是一个method_info结构。
方法表
- methods表中的每个成员都必须是一个method_info结构，用于表示当前类或接口中某个方法的完整描述。如果某个method_info结构的access_flags项既没有设置ACC_NATIVE标志也没有设置ACC_ABSTRACT标志，那么该结构中也应包含实现这个方法所用的Java虚拟机指令。
- method_info结构可以表示类和接口中定义的所有方法，包括实例方法、类方法、实例初始化方法和类或接口初始化方法
- 方法表的结构实际跟字段表是一样的，方法表结构如下：
方法表访问标志
跟字段表一样，方法表也有访问标志，而且他们的标志有部分相同，部分则不同，方法表的具体访问标志如下：
方法索引
方法描述符
方法访问标志，方法索引，方法描述符
顺序统一是访问标志，名称索引，描述符引用
属性表集合
- 方法表集合之后的属性表集合，指的是class文件所携带的辅助信息，比如该class文件的源文件的名称。以及任何带有RetentionPolicy.CLASS或者RetentionPolicy.RUNTIME的注解。这类信息通常被用于Java虚拟机的验证和运行，以及Java程序的调试，一般无须深入了解。
- 此外，字段表、方法表都可以有自己的属性表。用于描述某些场景专有的信息。
- 属性表集合的限制没有那么严格，不再要求各个属性表具有严格的顺序，并且只要不与已有的属性名重复，任何人实现的编译器都可以向属性表中写入自己定义的属性信息，但Java虚拟机运行时会忽略掉它不认识的属性。
属性表
attributes[]（属性表）
- 属性表的每个项的值必须是attribute_info结构。属性表的结构比较灵活，各种不同的属性只要满足以下结构即可。
属性的通用格式
即只需说明属性的名称以及占用位数的长度即可，属性表具体的结构可以去自定义。
举列属性类型
属性表实际上可以有很多类型，上面看到的Code属性只是其中一种，Java8里面定义了23种属性。
下面这些是虚拟机中预定义的属性：
举列code属性
Code属性就是存放方法体里面的代码。但是，并非所有方法表都有Code属性。像接口或者抽象方法，他们没有具体的方法体，因此也就不会有Code属性了。
可以看到：Code属性表的前两项跟属性表是一致的，即Code属性表遵循属性表的结构，后面那些则是他自定义的结构。
官网查看属性方法
- https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-4.html
方法的属性表集合
code属性的LineNumberTable属性
code属性的LocalVariableTable属性
类的附加属性SourceFile
Class文件结构的小结
- 随着Java平台的不断发展，在将来，Class文件的内容也一定会做进一步的扩充，但是其基本的格式和结构不会做重大调整。
- 从Java虚拟机的角度看，通过Class文件，可以让更多的计算机语言支持Java虚拟机平台。因此，Class文件结构不仅仅是Java虚拟机的执行入口，更是Java生态圈的基础和核心。
Class文件结构是Java生态圈的基础和核心
使用javap指令解析Class文件
解析字节码的作用
- 通过反编译生成的字节码文件，我们可以深入的了解java代码的工作机制。但是，自己分析类文件结构太麻烦了！除了使用第三方的jclasslib工具之外，oracle官方也提供了工具：javap。
- javap是jdk自带的反解析工具。它的作用就是根据c1ass字节码文件，反解析出当前类对应的code区（字节码指令）
、局部变量表、异常表和代码行偏移量映射表、常量池等信息。 - 通过局部变量表，我们可以查看局部变量的作用域范围、所在槽位等信息，甚至可以看到槽位复用等信息。
关于该小节的代码
public class JavapTest {
private int num;
boolean flag;
protected char gender;
public String info;
public static final int COUNTS = 1;
static {
String url = "www.atguigu.com";
}
{
info = "java";
}
public JavapTest() {
}
private JavapTest(boolean flag) {
this.flag = flag;
}
private void methodPrivate() {
}
int getNum(int i) {
return num + i;
}
protected char showGender() {
return gender;
}
public void showInfo() {
int i = 10;
System.out.println(info + i);
}
}
javac -g操作
- 解析字节码文件得到的信息中，有些信息（如局部变量表、指令和代码行偏移量映射表、常量池中方法的参数名称等等）需要在使用javac编译成class文件时，指定参数才能输出。
- 比如，你直接javac x.java，就不会在生成对应的局部变量表等信息，如果你使用javac-gxx.java就可以生成所有相关信息了。如果你使用的eclipse或IDEA，则默认情况下，eclipse、IDEA在编译时会帮你生成局部变量表、指令和代码行偏移量映射表等信息的。
javap的用法
- javcp <options><classes>
- 其中，classes就是你要反编译的class文件。
- 在命令行中直接输入javap或javap-help可以看到javap的options有如下选项：
- 一般常用的是-v-l-c三个选项:
- javap -l会输出行号和本地变量表信息。
- javap -c会对当前class字节码进行反编译生成汇编代码。
- javap-v classxx除了包含-c内容外，还会输出行号、局部变量表信息、常量池等信息。
使用-v可以输出public和protected绝大多数信息，-p输出private成员
javap解析得到的文件结构的解读
Classfile /D:/apache-maven-3.6.3/maven_repo/jvm/jvm1/target/classes/T1/JavapTest.class // 文件路径
Last modified 2020-9-27; size 1328 bytes // 最后修改时间;文件大小
MD5 checksum c1b96803e2d3ada8808581ab443d949b // MD5散列值
Compiled from "JavapTest.java" // 源文件名称
public class T1.JavapTest
minor version: 0 // 副版本
major version: 52 // 主版本
flags: ACC_PUBLIC, ACC_SUPER // 类的访问标识
Constant pool: // 常量池
#1 = Methodref #16.#46 // java/lang/Object."<init>":()V
#2 = String #47 // java
#3 = Fieldref #15.#48 // T1/JavapTest.info:Ljava/lang/String;
#4 = Fieldref #15.#49 // T1/JavapTest.flag:Z
#5 = Fieldref #15.#50 // T1/JavapTest.num:I
#6 = Fieldref #15.#51 // T1/JavapTest.gender:C
#7 = Fieldref #52.#53 // java/lang/System.out:Ljava/io/PrintStream;
#8 = Class #54 // java/lang/StringBuilder
#9 = Methodref #8.#46 // java/lang/StringBuilder."<init>":()V
#10 = Methodref #8.#55 // java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
#11 = Methodref #8.#56 // java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
#12 = Methodref #8.#57 // java/lang/StringBuilder.toString:()Ljava/lang/String;
#13 = Methodref #58.#59 // java/io/PrintStream.println:(Ljava/lang/String;)V
#14 = String #60 // www.atguigu.com
#15 = Class #61 // T1/JavapTest
#16 = Class #62 // java/lang/Object
#17 = Utf8 num
#18 = Utf8 I
#19 = Utf8 flag
#20 = Utf8 Z
#21 = Utf8 gender
#22 = Utf8 C
#23 = Utf8 info
#24 = Utf8 Ljava/lang/String;
#25 = Utf8 COUNTS
#26 = Utf8 ConstantValue
#27 = Integer 1
#28 = Utf8 <init>
#29 = Utf8 ()V
#30 = Utf8 Code
#31 = Utf8 LineNumberTable
#32 = Utf8 LocalVariableTable
#33 = Utf8 this
#34 = Utf8 LT1/JavapTest;
#35 = Utf8 (Z)V
#36 = Utf8 methodPrivate
#37 = Utf8 getNum
#38 = Utf8 (I)I
#39 = Utf8 i
#40 = Utf8 showGender
#41 = Utf8 ()C
#42 = Utf8 showInfo
#43 = Utf8 <clinit>
#44 = Utf8 SourceFile
#45 = Utf8 JavapTest.java
#46 = NameAndType #28:#29 // "<init>":()V
#47 = Utf8 java
#48 = NameAndType #23:#24 // info:Ljava/lang/String;
#49 = NameAndType #19:#20 // flag:Z
#50 = NameAndType #17:#18 // num:I
#51 = NameAndType #21:#22 // gender:C
#52 = Class #63 // java/lang/System
#53 = NameAndType #64:#65 // out:Ljava/io/PrintStream;
#54 = Utf8 java/lang/StringBuilder
#55 = NameAndType #66:#67 // append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
#56 = NameAndType #66:#68 // append:(I)Ljava/lang/StringBuilder;
#57 = NameAndType #69:#70 // toString:()Ljava/lang/String;
#58 = Class #71 // java/io/PrintStream
#59 = NameAndType #72:#73 // println:(Ljava/lang/String;)V
#60 = Utf8 www.atguigu.com
#61 = Utf8 T1/JavapTest
#62 = Utf8 java/lang/Object
#63 = Utf8 java/lang/System
#64 = Utf8 out
#65 = Utf8 Ljava/io/PrintStream;
#66 = Utf8 append
#67 = Utf8 (Ljava/lang/String;)Ljava/lang/StringBuilder;
#68 = Utf8 (I)Ljava/lang/StringBuilder;
#69 = Utf8 toString
#70 = Utf8 ()Ljava/lang/String;
#71 = Utf8 java/io/PrintStream
#72 = Utf8 println
#73 = Utf8 (Ljava/lang/String;)V
#########################################################字段表集合 begin################################################################################
{
private int num; // 字段名称
descriptor: I // 字段描述符：字段的类型
flags: ACC_PRIVATE // 字段的访问标识
boolean flag;
descriptor: Z
flags:
protected char gender;
descriptor: C
flags: ACC_PROTECTED
public java.lang.String info;
descriptor: Ljava/lang/String;
flags: ACC_PUBLIC
public static final int COUNTS;
descriptor: I
flags: ACC_PUBLIC, ACC_STATIC, ACC_FINAL
ConstantValue: int 1 // 常量字段的属性：ConstantValue
#########################################################字段表集合 end##################################################################################
#########################################################方法表集合 begin##################################################################################
public T1.JavapTest();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=2, locals=1, args_size=1
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: aload_0
5: ldc #2 // String java
7: putfield #3 // Field info:Ljava/lang/String;
10: return
LineNumberTable:
line 19: 0
line 16: 4
line 21: 10
LocalVariableTable:
Start Length Slot Name Signature
0 11 0 this LT1/JavapTest;
private T1.JavapTest(boolean);
descriptor: (Z)V
flags: ACC_PRIVATE
Code:
stack=2, locals=2, args_size=2
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: aload_0
5: ldc #2 // String java
7: putfield #3 // Field info:Ljava/lang/String;
10: aload_0
11: iload_1
12: putfield #4 // Field flag:Z
15: return
LineNumberTable:
line 23: 0
line 16: 4
line 24: 10
line 25: 15
LocalVariableTable:
Start Length Slot Name Signature
0 16 0 this LT1/JavapTest;
0 16 1 flag Z
private void methodPrivate();
descriptor: ()V
flags: ACC_PRIVATE
Code:
stack=0, locals=1, args_size=1
0: return
LineNumberTable:
line 29: 0
LocalVariableTable:
Start Length Slot Name Signature
0 1 0 this LT1/JavapTest;
int getNum(int);
descriptor: (I)I
flags:
Code:
stack=2, locals=2, args_size=2
0: aload_0
1: getfield #5 // Field num:I
4: iload_1
5: iadd
6: ireturn
LineNumberTable:
line 32: 0
LocalVariableTable:
Start Length Slot Name Signature
0 7 0 this LT1/JavapTest;
0 7 1 i I
protected char showGender();
descriptor: ()C
flags: ACC_PROTECTED
Code:
stack=1, locals=1, args_size=1
0: aload_0
1: getfield #6 // Field gender:C
4: ireturn
LineNumberTable:
line 36: 0
LocalVariableTable:
Start Length Slot Name Signature
0 5 0 this LT1/JavapTest;
public void showInfo();
descriptor: ()V // 方法描述符：方法的形参列表、返回值类型
flags: ACC_PUBLIC // 方法的访问标志
Code: // 方法的code属性
stack=3, locals=2, args_size=1 // stack:操作数栈的最大深度，locals：局部变量表的长度，args_size:方法接受参数的个数(默认为1的this参数)
//偏移量 操作码 操作数
0: bipush 10
2: istore_1
3: getstatic #7 // Field java/lang/System.out:Ljava/io/PrintStream;
6: new #8 // class java/lang/StringBuilder
9: dup
10: invokespecial #9 // Method java/lang/StringBuilder."<init>":()V
13: aload_0
14: getfield #3 // Field info:Ljava/lang/String;
17: invokevirtual #10 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
20: iload_1
21: invokevirtual #11 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
24: invokevirtual #12 // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
27: invokevirtual #13 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
30: return
// 行号表:指名字字节码指令的偏移量与java源程序中代码行号一一对应
LineNumberTable:
line 40: 0
line 41: 3
line 42: 30
// 局部变量表
LocalVariableTable:
Start Length Slot Name Signature
0 31 0 this LT1/JavapTest;
3 28 1 i I
static {};
descriptor: ()V
flags: ACC_STATIC
Code:
stack=1, locals=1, args_size=0
0: ldc #14 // String www.atguigu.com
2: astore_0
3: return
LineNumberTable:
line 12: 0
line 13: 3
LocalVariableTable:
Start Length Slot Name Signature
}
#########################################################方法表集合 end##################################################################################
SourceFile: "JavapTest.java" // 类的附加属性
总结
-
通过javap命令可以查看一个java类反汇编得到的Class文件版本号、常量池、访问标识、变量表、指令代码行号表等等信息。不显示类索引、父类索引、接口索引集合、<clinit>()、<init>()等结构I
-
通过对前面例子代码反汇编文件的简单分析，可以发现，一个方法的执行通常会涉及下面几块内存的操作：
- java栈中：局部变量表、操作数栈。
- java堆。通过对象的地址引用去操作。
- 常量池。
- 其他如帧数据区、方法区的剩余部分等情况，测试中没有显示出来，这里说明一下。
-
平常，我们比较关注的是java类中每个方法的反汇编中的指令操作过程，这些指令都是顺序执行的，可以参考官方文档查看每个指令的含义，很简单：docs.oracle.com/javase/specs/jvms/se7/html/jvms-6.html
209
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
