ZYNQ之FPGA学习----FIFO IP核使用实验

最新推荐文章于 2024-08-09 10:33:37 发布
最新推荐文章于 2024-08-09 10:33:37 发布
阅读量1.9k 收藏 28
点赞数
分类专栏： 一起学ZYNQ 笔记 文章标签： fpga开发 ZYNQ Vivado FIFO 经验分享
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_42078934/article/details/127977401
版权
该博客详细介绍了如何在FPGA设计中使用Vivado创建并配置FIFO IP核，实现同步与异步FIFO。通过设置FIFO的宽度和深度，以及监控其状态标志，确保数据的正确写入和读出。同时，利用ILA IP核进行在线逻辑分析，验证FIFO的功能。最后，通过创建TestBench进行功能仿真，验证了FIFO在空满状态下的正确工作。
摘要由CSDN通过智能技术生成

1 FIFO IP核介绍

FIFO 的英文全称是 First In First Out， 即先进先出。与 FPGA 内部的 RAM 和 ROM 的区别是没有外部读写地址线， 采取顺序写入数据， 顺序读出数据的方式，使用起来简单方便，缺点就是不能像 RAM 和 ROM 那样可以由地址线决定读取或写入某个指定的地址

根据 FIFO 工作的时钟域，可以将 FIFO 分为同步 FIFO 和异步 FIFO：

  • 同步 FIFO 是指读时钟和写时钟为同一个时钟，在时钟沿来临时同时发生读写操作
  • 异步 FIFO 是指读写时钟不一致，读写时钟是互相独立的

FIFO常用参数：

  • FIFO 的宽度，FIFO 一次读写操作的数据位 N
  • FIFO 的深度，FIFO 可以存储多少个宽度为 N 位的数据
  • 将空标志(almost_empty)，FIFO 即将被读空
  • 空标志(empty)，FIFO 已空时由 FIFO 的状态电路送出的一个信号，以阻止 FIFO 的读操作继续从 FIFO中读出数据而造成无效数据的读出
  • 将满标志(almost_full)，FIFO 即将被写满
  • 满标志(full)，FIFO 已满时由 FIFO 的状态电路送出的一个号，以阻止 FIFO 的写操作继续向 FIFO 中写数据而造成溢出
  • 读时钟，读 FIFO 时所遵循的时钟，在每个时钟的上升沿触发
  • 写时钟，写 FIFO 时所遵循的时钟，在每个时钟的上升沿触发

2 实验任务

使用 Vivado 生成 FIFO IP 核，并实现以下功能：当 FIFO 为空时，向 FIFO 中写入数据，写入的数据量和 FIFO 深度一致，即 FIFO 被写满；然后从 FIFO 中读出数据，直到 FIFO 被读空为止，系统框图如下：
在这里插入图片描述
图片来自《领航者ZYNQ之FPGA开发指南》

3 实验设计

3.1 创建工程

新建工程，操作如图所示：

在这里插入图片描述

输入工程名和工程路径，如图所示：

在这里插入图片描述

选择创建RTL工程，如图所示：

在这里插入图片描述

直接点击Next：

在这里插入图片描述

继续点击Next：

在这里插入图片描述

添加芯片型号，操作如图所示：

在这里插入图片描述

完成工程创建：

在这里插入图片描述

3.2 设计输入

点击IP Catalog，搜索fifo，如图所示:

在这里插入图片描述

双击打开后，弹出窗口如下，Interface Type 选项用于选择 FIFO 接口的类型，选择默认的 Native；Fifo Implementation 选项用于选择是同步 FIFO 还是异步 FIFO 以及使用哪种资源实现 FIFO，选择 Independent Clocks Block RAM，即使用块 RAM 来实现的异步 FIFO：

在这里插入图片描述

Read Mode 选项用于设置读 FIFO时的读模式，选择默认的Standard FIFO。Data Port Parameters 选型用于设置读写端口的数据总线的宽度以及 FIFO 的深度，写宽度 Write Width 设置为 8 位，写深度 Write Depth 设置为 256。Reset Pin 不使用，取消勾选：

在这里插入图片描述

Status Flags窗口，用于设置用户自定义接口或者用于设定专用的输入口，勾选 即将写满 和 即将读空 这两个信号：

在这里插入图片描述

Data Counts 窗口用于设置 FIFO 内数据计数的输出信号，此信号表示当前在 FIFO 内存在多少个有效数据。为了更加方便地观察读/写过程，设置如图所示：

在这里插入图片描述

设置完成：

在这里插入图片描述

弹出如下窗口，直接点击Generate：

在这里插入图片描述

点击OK：

在这里插入图片描述

继续添加ILA(集成逻辑分析器) IP核，即在线逻辑分析仪的功能，操作如图所示：

在这里插入图片描述

进行如下设置，Number of Probes 用于设置所需的探针数量；Sample Data Depth 用于设置采样深度：

在这里插入图片描述

如下进行设置每个探针的参数：

在这里插入图片描述

设置完成，点击OK：

在这里插入图片描述

创建工程顶层文件，操作如图所示：

在这里插入图片描述

创建文件ip_fifo，作为顶层模块：

在这里插入图片描述

创建完成：

在这里插入图片描述

双击打开，输入代码如下：

module ip_fifo( 
    input    sys_clk ,  // 时钟信号 
    input    sys_rst_n  // 复位信号 
); 

//wire define 
wire         fifo_wr_en         ;  // FIFO 写使能信号 
wire         fifo_rd_en         ;  // FIFO 读使能信号 
wire  [7:0]  fifo_din           ;  // 写入到 FIFO 的数据 
wire  [7:0]  fifo_dout          ;  // 从 FIFO 读出的数据 
wire         almost_full        ;  // FIFO 将满信号 
wire         almost_empty       ;  // FIFO 将空信号 
wire         fifo_full          ;  // FIFO 满信号
wire         fifo_empty         ;  // FIFO 空信号 
wire  [7:0]  fifo_wr_data_count ;  // FIFO 写时钟域的数据计数 
wire  [7:0]  fifo_rd_data_count ;  // FIFO 读时钟域的数据计数 
//例化 FIFO IP 核 
fifo_generator_0  fifo_generator_0 ( 
    .wr_clk        ( sys_clk             ),  // input wire wr_clk 
    .rd_clk        ( sys_clk             ),  // input wire rd_clk 

    .wr_en         ( fifo_wr_en          ),  // input wire wr_en 
    .rd_en         ( fifo_rd_en          ),  // input wire rd_en 

    .din           ( fifo_din            ),  // input wire [7 : 0] din 
    .dout          ( fifo_dout           ),  // output wire [7 : 0] dout 
    
    .almost_full   (almost_full          ),  // output wire almost_full 
    .almost_empty  (almost_empty         ),  // output wire almost_empty 
    .full          ( fifo_full           ),  // output wire full 
    .empty         ( fifo_empty          ),  // output wire empty 
 
    .wr_data_count ( fifo_wr_data_count  ),  // output wire [7 : 0] wr_data_count     
    .rd_data_count ( fifo_rd_data_count )   // output wire [7 : 0] rd_data_count 
);
//例化写 FIFO 模块 
fifo_wr  u_fifo_wr( 
    .clk            ( sys_clk     ),   // 写时钟 
    .rst_n          ( sys_rst_n   ),   // 复位信号 

    .fifo_wr_en     ( fifo_wr_en )  , // fifo 写请求 
    .fifo_wr_data   ( fifo_din    ) , // 写入 FIFO 的数据 
    .almost_empty   ( almost_empty  ), // fifo 将空信号 
    .almost_full    ( almost_full  )  // fifo 将满信号 
); 

//例化读 FIFO 模块 
fifo_rd  u_fifo_rd( 
    .clk          ( sys_clk     ),      // 读时钟 
    .rst_n        ( sys_rst_n   ),      // 复位信号 

    .fifo_rd_en   ( fifo_rd_en  ),      // fifo 读请求 
    .fifo_dout    ( fifo_dout   ),      // 从 FIFO 输出的数据 
    .almost_empty ( almost_empty  ),    // fifo 将空信号 
    .almost_full  ( almost_full  )     // fifo 将满信号 
); 
//例化 ILA IP 核 
ila_0  ila_0 ( 
    .clk    ( sys_clk             ), // input wire clk 
 
    .probe0 ( fifo_wr_en          ), // input wire [0:0]  probe0   
    .probe1 ( fifo_rd_en          ), // input wire [0:0]  probe1  
    .probe2 ( fifo_din            ), // input wire [7:0]  probe2  
    .probe3 ( fifo_dout           ), // input wire [7:0]  probe3  
    .probe4 ( fifo_empty          ), // input wire [0:0]  probe4  
    .probe5 ( almost_empty        ), // input wire [0:0]  probe5  
    .probe6 ( fifo_full           ), // input wire [0:0]  probe6 
    .probe7 ( almost_full         ), // input wire [0:0]  probe7  
    .probe8 ( fifo_wr_data_count  ), // input wire [7:0]  probe8  
    .probe9( fifo_rd_data_count  )  // input wire [7:0]  probe9 
); 
 
endmodule

如图所示：

在这里插入图片描述

继续创建fifo_wr文件，即写FIFO模块，如图所示：

在这里插入图片描述

双击打开，输入代码如下：

module fifo_wr( 
    input                  clk    ,          // 时钟信号 
    input                  rst_n  ,          // 复位信号 
     
    input                  almost_empty,     // FIFO 将空信号 
    input                  almost_full ,     // FIFO 将满信号 
    output     reg          fifo_wr_en ,      // FIFO 写使能 
    output     reg  [7:0]   fifo_wr_data      // 写入 FIFO 的数据 
); 

//reg define 
reg  [1:0]  state            ;  //动作状态
reg         almost_empty_d0  ;  //almost_empty 延迟一拍 
reg         almost_empty_syn ;  //almost_empty 延迟两拍 
reg  [3:0]  dly_cnt          ;  //延迟计数器

//因为 almost_empty 信号是属于 FIFO 读时钟域的 
//所以要将其同步到写时钟域中 
always @(  posedge clk )  begin 
    if( !rst_n )  begin 
        almost_empty_d0   <= 1'b0 ; 
        almost_empty_syn  <= 1'b0 ; 
    end 
    else  begin 
        almost_empty_d0   <= almost_empty ; 
        almost_empty_syn  <= almost_empty_d0 ; 
    end 
end 

//向 FIFO 中写入数据 
always  @( posedge clk )  begin 
    if (!rst_n)  begin 
        fifo_wr_en    <= 1'b0; 
        fifo_wr_data  <= 8'd0; 
        state         <= 2'd0; 
        dly_cnt       <= 4'd0; 
    end 
    else  begin 
        case(state) 
            2'd0:  begin  
                if(almost_empty_syn)  begin  //如果检测到 FIFO 将被读空（下一拍就会空） 
                    state  <= 2'd1;          //就进入延时状态 
                end  
                else 
                    state  <= state; 
                end  
            2'd1:  begin 
                if(dly_cnt  == 4'd10)  begin  //延时 10 拍 
                                             //原因是 FIFO IP 核内部状态信号的更新存在延时 
                                            //延迟 10 拍以等待状态信号更新完毕
                    dly_cnt     <= 4'd0;      
                    state       <= 2'd2;        //开始写操作 
                    fifo_wr_en  <= 1'b1;        //打开写使能 
                end 
                else 
                    dly_cnt  <= dly_cnt + 4'd1; 
                end              
            2'd2:  begin 
                if(almost_full)  begin      //等待 FIFO 将被写满（下一拍就会满） 
                    fifo_wr_en    <= 1'b0;  //关闭写使能 
                    fifo_wr_data  <= 8'd0; 
                    state         <= 2'd0;  //回到第一个状态 
                end 
                else  begin                 //如果 FIFO 没有被写满 
                    fifo_wr_en    <= 1'b1;  //则持续打开写使能 
                    fifo_wr_data  <= fifo_wr_data + 1'd1;  //且写数据值持续累加 
                end 
            end  
        default : state  <= 2'd0; 
        endcase 
    end 
end 

endmodule

如图所示：

在这里插入图片描述

继续创建fifo_rd文件，即读FIFO模块，如图所示：

在这里插入图片描述

双击打开，输入代码如下：

module fifo_rd( 
    input               clk          ,   // 时钟信号 
    input               rst_n        ,   // 复位信号 

    input        [7:0]  fifo_dout    ,   // 从 FIFO 读出的数据 
    input               almost_full  ,   // FIFO 将满信号 
    input               almost_empty ,   // FIFO 将空信号 
    output   reg         fifo_rd_en       // FIFO 读使能 
); 
 
//reg define 
reg  [1:0]  state           ;  //状态 
reg         almost_full_d0  ;  //almost_full 延迟一拍 
reg         almost_full_syn ;  //almost_full 延迟两拍 
reg  [3:0]  dly_cnt         ;  //延迟计数器 

//因为 fifo_full 信号是属于 FIFO 写时钟域的 
//所以要将其同步到读时钟域中 
always @(  posedge clk )  begin 
    if( !rst_n )  begin 
        almost_full_d0   <= 1'b0 ; 
        almost_full_syn  <= 1'b0 ; 
    end 
    else  begin 
        almost_full_d0   <= almost_full ; 
        almost_full_syn  <= almost_full_d0 ; 
    end 
end 
 
//读出 FIFO 的数据 
always  @( posedge clk )  begin 
    if (!rst_n)  begin 
        fifo_rd_en  <= 1'b0; 
        state       <= 2'd0; 
        dly_cnt     <= 4'd0; 
    end 
    else  begin 
        case(state) 
            2'd0:  begin                      
                if(almost_full_syn)        //如果检测到 FIFO 被写满 
                    state  <= 2'd1;         //就进入延时状态 
                else 
                    state  <= state; 
                end  
            2'd1:  begin 
                if(dly_cnt  == 4'd10)  begin //延时 10 拍 
                                           //原因是 FIFO IP 核内部状态信号的更新存在延时 
                                           //延迟 10 拍以等待状态信号更新完毕 
                    dly_cnt  <= 4'd0;
                    state    <= 2'd2;          //开始读操作 
                end 
                else 
                    dly_cnt  <= dly_cnt + 4'd1; 
                end 
            2'd2:  begin 
                if(almost_empty)  begin     //等待 FIFO 将被读空（下一拍就会空） 
                    fifo_rd_en  <= 1'b0;    //关闭读使能 
                    state       <= 2'd0;    //回到第一个状态 
                end 
                else                       //如果 FIFO 没有被读空 
                    fifo_rd_en  <= 1'b1;    //则持续打开读使能 
                end  
            default : state  <= 2'd0; 
            endcase 
        end 
end 
 
endmodule

如图所示：

在这里插入图片描述

3.3 分析与综合

对设计进行分析，操作如图所示：

在这里插入图片描述

分析后的设计，Vivado自动生成顶层原理图，如图所示：

在这里插入图片描述

对设计进行综合，操作如图所示：

在这里插入图片描述

综合完成后，弹出窗口如下，直接关闭：

在这里插入图片描述

3.4 约束输入

创建约束文件，操作如图所示：

在这里插入图片描述

创建约束文件，输入文件名：

在这里插入图片描述

双击打开，输入约束代码：

create_clock -period 20.000 -name clk [get_ports sys_clk] 
set_property -dict {PACKAGE_PIN U18 IOSTANDARD LVCMOS33} [get_ports sys_clk] 
set_property -dict {PACKAGE_PIN J15 IOSTANDARD LVCMOS33} [get_ports sys_rst_n]

如图所示：

在这里插入图片描述

3.5 设计实现

点击 Flow Navigator 窗口中的 Run Implementation，如图所示：

在这里插入图片描述

点击OK：

在这里插入图片描述

完成后，关闭即可：

在这里插入图片描述

3.6 功能仿真

创建TestBench，操作如图所示：

在这里插入图片描述

创建激励文件，输入文件名：

在这里插入图片描述

创建完成：

在这里插入图片描述

双击打开，输入TestBench(激励)代码：

`timescale 1ns / 1ps 
module tb_ip_fifo(  ); 
// Inputs 
    reg sys_clk; 
    reg sys_rst_n; 
   
// Instantiate the Unit Under Test (UUT) 
ip_fifo  u_ip_fifo  ( 
    .sys_clk         (sys_clk ),  
    .sys_rst_n       (sys_rst_n) 
); 
   
//Genarate the clk 
parameter PERIOD = 20; 
always  begin 
    sys_clk = 1'b0; 
    #(PERIOD/2) sys_clk = 1'b1; 
    #(PERIOD/2 ); 
end  
initial  begin 
    // Initialize Inputs 
    sys_rst_n = 0; 
    // Wait 100 ns for global reset to finish 
    #100  ; 
    sys_rst_n = 1; 
    // Add stimulus here  
end 
endmodule

如图所示：

在这里插入图片描述

开始进行仿真，操作如下：

在这里插入图片描述

选择HDL仿真对象：

在这里插入图片描述

点击Restart，波形窗口中的当前仿真时刻点回归到0ns：

在这里插入图片描述

写满数据后，fifo_full信号拉高：

在这里插入图片描述

读完数据后，fifo_empty信号拉高：

在这里插入图片描述

3.7 下载验证

由于疫情，一直无法去实验室，故ZYNQ开发板不在身边，该步骤内容待更新

致谢领航者ZYNQ开发板，开启FPGA学习之路！

希望本文对大家有帮助，上文若有不妥之处，欢迎指正

分享决定高度，学习拉开差距

鲁棒最小二乘支持向量机
关注
专栏目录
（16）ZYNQ FPGA AXI4-stream DATA FIFO IP核（学无止境）
m0_46498597的博客
09-17 3743
1 应用领域 AXI4-stream DATA FIFO主要是PS与PL交互数据时使用。 2 AXI4-stream DATA FIFO IP核 FIFO如图1所示。 图1 3 AXI4-stream DATA FIFO IP核配置 Component Name：器件名字。 FIFO depth：FIFO深度。 Enable packet mode：使能包模式 Asynchronous Clocks：异步时钟 Synchronization Stages across Cross Clock.
【ZYNQ】从入门到秃头11 DAC FIFO实验（AXI-stream FIFO IP核配置）
“逛丢一只鞋”的博客
03-27 6534
文章目录实验任务例化模块CLKAXI-Stream-Data FIFODDS 实验任务 DAC FIFO实验 基于“DDS IP 数字波形合成DAC ” “ ADDA测试” 实验方案 用MMCM 把 合成出100MHz的时钟，让DDS工作在100MHz时钟 让DAC和DAC的接口电路工作在50MHz，此时DAC的采样率为50MHz 在DDS和DAC接口电路之间，放置一个带独立时钟的AXI-Stream-Data FIFO，FIFO两端的时钟分别为DDS的工作时钟100MHz和DAC的工作时钟50MHz 生成
FPGA的FIFO的IP核
08-28
在FIFO很常用的一中寄存器，里面有怎么运用quartus里面的fifo IP核
FPGA知识基础之--FIFO ip核的使用以及实例化clocking wizard ip产生一个异步FIFO，附RTL和仿真代码
最新发布
2301_76707170的博客
08-09 1261
FIFO是一种先进先出的数据缓存队列，主要特点是数据顺序写入，再按照同样的顺序输出数据，即先进去的数据先被取出来。
FIFO IP核
weixin_30367945的博客
09-02 594
转载： 说白了，IP核就是别人做好了的硬件模块，提供完整的用户接口和说明文档，更复杂的还有示例工程，你只要能用好这个IP核，设计已经完成一半了。说起来容易，从冗长的英文文档和网上各个非标准教程中汲取所需，并灵活运用还是需要下一番功夫的。 　　我认为其中最重要的几点如下： 　　1) 提供给IP核正确的时钟和复位条件； 　　2)明确各个重要用户接口功能； 　　3)掌握所需指令的操作时序；...
FPGA FIFO——IP核
qq_52215423的博客
07-20 1413
FPGA FIFO——IP核
FPGA:FIFO IP核
bossot的博客
03-08 269
2022/0308 FIFO IP核 采用异步FIFO对数据进行传递时，可以是读的速度大于写的速度，但是不能是写的速度大于读的速度，因为如果会出现缓存器溢出。 数据的位宽表示数据有多少位，数据深度表示有多少个数据。 ...
【正点原子FPGA连载】第十五章 IP核之FIFO实验 -摘自【正点原子】领航者ZYNQ之FPGA开发指南_V2.0
weixin_55796564的博客
01-04 2856
1）实验平台：正点原子领航者ZYNQ开发板 2）平台购买地址：https://item.taobao.com/item.htm?&id=606160108761 3）全套实验源码+手册+视频下载地址：http://www.openedv.com/thread-301505-1-1.html 4）对正点原子FPGA感兴趣的同学可以加群讨论：994244016 5）关注正点原子公众号，获取最新资料更新 第十五章 IP核之FIFO实验 FIFO的英文全称是First In First Out，即先进先出
FPGA MPSoC-XCZU4EV实现IP核FIFO驱动（Vivado Design Suite和Verilog HDL实现）
04-25
在本文中，我们将深入探讨如何使用Xilinx的FPGA MPSoC XCZU4EV来实现IP核FIFO驱动，并且结合Vivado Design Suite和Verilog HDL进行设计与实现。这一技术对于嵌入式系统开发者来说是至关重要的，因为它涉及到高性能、...
fpga axi-can ip核数据手册
06-07
LogiCORE IP AXI-CAN IP 核采用 AXI4-Lite 接口，支持 Virtex-7、Kintex-7、Artix-7、Zynq-7000、Virtex-6 和 Spartan-6/XA 等 FPGA 设备家族。 四、寄存器描述 LogiCORE IP AXI-CAN IP 核的寄存器可以分为以下几...
ZYNQ&FPGA FIFO IP核实验
m0_58413328的博客
11-06 903
FIFO简介 FIFO的英文全称是First In First Out，即先进先出。 FPGA使用的FIFO一般指的是对数据的存储具有先进先出特性的一个缓存器，常被用于数据的缓存，或者高速异步数据的交互也即所谓的跨时钟域信号传递。 它与FPGA内部的RAM和ROM的区别是没有外部读写地址线，采取顺序写入数据，顺序读出数据的方式，使用起来简单方便，由此带来的缺点就是不能像RAM和ROM那样可以由地址线决定读取或写入某个指定的地址。 同步FIFO：指读时钟和写时钟为同一个时钟，在时钟沿来临时同时发生
ise中FIFOIP核使用
12-17
该文档描述了ise调用FIFOIP核的使用方法，有图文教程。
ZYNQ进阶之路13--自定义AXI-FULL IP实现PS和PL双向高速通讯， 的示例工程，希望对的广大博友有所帮助.zip
03-15
在本篇中，我们将深入探讨ZYNQ进阶之路中的一个重要环节：自定义AXI-FULL IP实现PS（Processing System）与PL（Programmable Logic）之间的双向高速通讯。AXI（Advanced eXtensible Interface）是ARM公司推出的一种...
FPGA原理与结构（12）——FIFO IP核原理学习
热门推荐
apple_53311083的博客
08-24 1万+
本文对于xilinx的FIFOGenerator IP核进行了一个简单的介绍，解释了IP核中各个类型信号的具体功能。介绍了FIFO的读写操作，其中读操作又可以分成2种模式，推荐使用标准模式，最后介绍了FIFO的非对称读写位宽
（四）零基础学懂FIFO——最详细的FIFO IP核应用教程
ChinaRyan666（蔡杰涛）的博客
09-20 4097
爆肝2w字！只为了彻底学懂FIFO！让您零基础都会用FIFO！
正点原子FPGA学习笔记3.2——FIFO IP核的使用，基于达芬奇开发板 A7
qq_40677883的博客
01-03 450
学习笔记3.2——FIFO IP核的使用（超详细）
FPGA--IP核之FIFO
weixin_60354142的博客
03-09 4234
FIFO 的英文全称是 First In First Out，即先进先出。FPGA 使用的 FIFO 一般指的是对数据的存储具有先进先出特性的一种缓存器，常被用于数据的缓存，或者高速异步数据的交互（即跨时钟域信号传递）。FIFO 与 FPGA 内部的 RAM 和 ROM 的区别是 FIFO 没有外部读写地址线，采取顺序写入数据，顺序读出数据的方式，使用起来简单方便，由此带来的缺点就是不能像 RAM 和 ROM 那样可以由地址线决定读取或写入某个指定的地址。 根据FIFO工作的时钟域，可以将 FIFO 分为
fifo介绍及fifo IP核使用(工程文件获取请参考文末)
piper291023的博客
09-24 7494
一.fifo简介 1.fifo first in first out的缩写，先进先出数据缓存器。 与普通存储器的区别：对外接口没有地址线。 由此所带来的优点是：不用处理地址信号，时序较简单。 缺点是：不能像普通存储器那样自由读写某个地址的数据，只能顺序地写入，顺序地读出数据。 例如：往fifo中存入100个数据，想要读出第50个，只能先读出前面那49个。 2.用途 （1）跨时钟域数据传输； 例如：以50M的时钟写入，再将其以100M的时钟读出。如此，便完成了由低频域系统向高频域系统的传输
FPGA基础学习(2) -- FIFO IP核(Quartus)
weixin_30437481的博客
06-22 2018
ALTERA在LPM（library of parameterized mudules）库中提供了参数可配置的单时钟FIFO（SCFIFO）和双时钟FIFO（DCFIFO）。FIFO主要应用在需要数据缓冲且数据符合先进先出规律的同步或异步场合。LPM中的FIFO包含以下几种： 1.SCFIFO：单时钟FIFO； 2.DCFIFO：双时钟FIFO，数据输入和输出的宽度相同； 3.DCFIFO_MIX...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

鲁棒最小二乘支持向量机

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值