Unity Shader入门精要 | 基础纹理

最新推荐文章于 2022-04-01 17:06:03 发布

油炸汽水

最新推荐文章于 2022-04-01 17:06:03 发布

阅读量106

点赞数

分类专栏： UnityShader

本文链接：https://blog.csdn.net/qq_42772001/article/details/107721274

版权

UnityShader 专栏收录该内容

7 篇文章 2 订阅

订阅专栏

单张纹理

在原本的光照模型shader基础上，添加纹理的信息。

首先在Properties语义中添加纹理属性_Maintex：

Properties
    {
        _Color ("Color Tint", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }

接着在SubShader的Pass中，声明匹配的变量：

fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Specular;
float _Gloss;

纹理类型属性还需要声明一个float4变量，命名为纹理名_ST（ST是旋转和平移的缩写），_MainTex_ST.xy存储缩放值， _MainTex_ST.zw存储偏移值，这些可以在材质面板调节。

顶点着色器的输入输出结构体：

struct a2v {
	float4 vertex : POSITION;
	float3 normal : NORMAL;
	float4 texcoord : TEXCOORD0; 
};

struct v2f {
	float4 pos : SV_POSITION;
	float3 worldNormal : TEXCOORD0;
	float3 worldPos : TEXCOORD1;
	float2 uv : TEXCOORD2; 
};

第一组纹理坐标会存到a2v的texcoord中，输出为uv坐标传到片元着色器。

v2f vert(a2v v) {
    v2f o;
    o.pos = UnityObjectToClipPos(v.vertex);
    o.worldNormal = UnityObjectToWorldNormal(v.normal);
    o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
    o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //or build-in function: o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
    return o;
}

在片元着色器中，用tex2d函数对要纹理和相应坐标进行采样，把它和颜色属性_Color的乘积作为材质反射率albedo，albedo用于计算环境光和漫反射。

fixed4 frag(v2f i) : SV_TARGET{
	fixed3 worldNormal = normalize(i.worldNormal);
	fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
	
	fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
	fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
	fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
	fixed3 halfDir = normalize(worldLightDir + viewDir);
	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
	
	return fixed4(ambient + diffuse + specular, 1.0);
}

效果：

在这里插入图片描述

凹凸映射

凹凸映射的原理是修改表面法线，来影响光照从而造成凹凸的效果。

高度纹理

高度图存储表面的高度，需要进一步计算法线。

法线纹理

法线纹理即直接存储法线信息，有两种储存方式，一种是使用模型空间，一种是使用切线空间。它们有各自的优缺点。

模型空间：更加直观，而且在边角部分会更加平滑（因为是同一个坐标系下）
切线空间：自由度高，可进行uv动画，可重用，可压缩

在实际应用中，一般选用切线空间来存储。

切线空间

属性中添加Bump Map和Bump Scale：

Properties
{
	_Color ("Color Tint", Color) = (1, 1, 1, 1)
	_MainTex ("Main Tex", 2D) = "white" {}
	_Specular ("Specular", Color) = (1, 1, 1, 1)
	_Gloss ("Gloss", Range(8.0, 256)) = 20
	_BumpMap ("Normal Map", 2D) = "bump" {}
	_BumpScale ("Bump Scale", Float) = 1.0
}

其中默认值bump是Unity内置的法线纹理，Bump Scale为0时意味着法线纹理不产生影响。

声明变量在第一部分的基础上添加：

sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;

顶点着色器的输入结构体如下，其中tangent是float4，因为还需要一维来存储副切线的方向。

struct a2v {
	float4 vertex : POSITION;
	float3 normal : NORMAL;
	float4 tangent : TANGENT;
	float4 texcoord : TEXCOORD0; 
};

需要在顶点着色器中计算好切线空间下的光照和视角方向，因此v2f中需要存储它们。

struct v2f {
	float4 pos : SV_POSITION;
	float2 uv : TEXCOORD0; 
	float3 lightDir : TEXCOORD1;
	float3 viewDir : TEXCOORD2;
};

顶点着色器的实现：

v2f vert(a2v v) {
    v2f o;
    o.pos = UnityObjectToClipPos(v.vertex);

    o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
    o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

    // Compute the binormal
    TANGENT_SPACE_ROTATION;

    // Transform lightDir & viewDir to tangent space
    o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
    o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
    
    return o;
}

TANGENT_SPACE_ROTATION是内置函数，它将模型空间下切线、副切线、法线方向按行排列得到模型空间到切线空间的变换矩阵rotation，利用rotaion把模型空间下的光照和视角方向变换到切线空间。

此时片元着色器只需要采样得到切线空间下的法线，在切线空间下进行光照计算：

fixed4 frag(v2f i) : SV_TARGET{
	fixed3 tangentLightDir = normalize(i.lightDir);
	fixed3 tangentViewDir = normalize(i.viewDir);
	
	// Get the texel in normal map
	fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
	fixed3 tangentNormal = UnpackNormal(packedNormal);
	tangentNormal.xy *= _BumpScale;
	tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
	
	fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
	
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
	
	fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
	
	fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss);
	
	return fixed4(ambient + diffuse + specular, 1.0);
}