erlang学习:书上案例22.6练习题

在下面这些练习里，我们将用job_centre模块制作一个服务器，它用gen_server实现一种
任务管理服务。任务中心（job center）持有一个必须完成的任务队列，这些任务会被编号，任何
人都能向队列添加任务。工人可以从队列请求任务，并告诉任务中心已经执行了某项任务。任务
是由fun表示的，要执行任务F，工人必须执行F()函数。
(1) 实现任务中心的基本功能，它的接口如下。
job_centre:start_link() -> true
启动任务中心服务器。
job_centre:add_job(F) -> JobNumber
添加任务F到任务队列，然后返回一个整数任务编号。
job_centre:work_wanted() -> {JobNumber,F} | no
请求任务。如果工人想要一个任务，就调用job_centre:work_wanted()。如果队列里
有任务，就会返回一个{JobNumber, F}元组。工人执行F()来完成任务。如果队列里没有任务，则会返回no。请确保同一项任务每次只分配给一个工人，并确保系统是公平的，
意思是任务按照请求的顺序进行分配。
job_centre:job_done(JobNumber)
发出任务完成的信号。如果工人完成了某一项任务，就必须调用job_centre:job_done
(JobNumber)。

对练习题做了一个初步实现，其中用到了队列相关的api，对这方面还不是很了解，明天先学习以下队列的使用在进行书上后面练习题的练习

-module(gen_server_test).

-export([start_link/0, add_job/1, work_wanted/0, job_done/1]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
  terminate/2, code_change/3]).
-export([test_job_centre/0]).
-define(SERVER, ?MODULE).

-record(state, {jobs = queue:new(), next_job_number = 1}).

start_link() ->
  gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).
add_job(Fun) ->
  gen_server:call(?SERVER, {add_job, Fun}).
work_wanted() ->
  gen_server:call(?SERVER, work_wanted).
job_done(JobNumber) ->
  gen_server:call(?SERVER, {job_done, JobNumber}).
%%---------------------------------------------------------------------------
init([]) ->
  {ok, #state{}}.

handle_call({add_job, Fun}, _From, State) ->
  NewJobs = queue:in({State#state.next_job_number, Fun}, State#state.jobs),
  {reply, State#state.next_job_number, State#state{jobs = NewJobs, next_job_number = State#state.next_job_number + 1}};
handle_call(work_wanted, _From, State) ->
  IsEmpty = queue:is_empty(State#state.jobs),
  case IsEmpty of
    true ->
      {reply, no, State};
    false ->
      {{value, {JobNumber, Fun}}, NewJobs} = queue:out(State#state.jobs),
      {reply, {JobNumber, Fun}, State#state{jobs = NewJobs}}
  end;
handle_call({job_done, _}, _From, State) ->
  {reply, ok, State};
handle_call(Request, _From, State) ->
  {reply, {error, {unknown_request, Request}}, State}.

handle_cast(_Msg, State) ->
  {noreply, State}.

handle_info(_Info, State) ->
  {noreply, State}.

terminate(_Reason, _State) ->
  ok.

code_change(_OldVsn, State, _Extra) ->
  {ok, State}.

test_job_centre() ->
  Job1 = fun() -> io:format("Doing job 1~n") end,
  Job2 = fun() -> io:format("Doing job 2~n") end,
  JobNumber1 = add_job(Job1),
  io:format("Job number 1 is ~p~n", [JobNumber1]),
  JobNumber2 = add_job(Job2),
  io:format("Job number 2 is ~p~n", [JobNumber2]),
  {JobNumber1, Job1} = work_wanted(),
  io:format("Doing job ~p~n", [{JobNumber1,Job1}]),
  {JobNumber2, Job2} = work_wanted(),
  io:format("Doing job ~p~n", [{JobNumber2,Job2}]),
  job_done(JobNumber1),
  job_done(JobNumber2),
  no = work_wanted(),
  ok.

今天只进行了简单的框架搭建与使用一些相关的队列api完成练习题的第一个要求，对其中队列的使用还不是很了解。只进行了代码的修改调试能够得到正确的输出结果