自定义函数做标识列的例子,不自动重排编号,而是自动补号

--自已做标识列的例子,不自动重排编号,而是自动补号:

--创建得到最大id的函数
IF NOT OBJECT_ID('[f_getid]') IS NULL
    DROP function f_getid
GO
create function f_getid()
returns int
as
begin
declare @id int
if not exists(select 1 from tb where id=1)
    set @id=1
else
begin
    select @id=max(id) from tb
    if @id is null
        set @id=1
    else
    begin
        declare @id1 int
        select @id1=min(id) from tb a where id<>@id and not exists(select 1 from tb where id=a.id+1)
        if @id1 is not null set @id=@id1
        set @id=@id+1
    end
end
lb_re:
return @id
end
go

--创建表
IF NOT OBJECT_ID('[tb]') IS NULL
    DROP TABLE tb
GO
create table tb(id int primary key default dbo.f_getid(),name varchar(10))
go

--插入记录测试
insert into tb(name) values('张三')
insert into tb(name) values('张四')
insert into tb(name) values('张五')
insert into tb(name) values('张六')
insert into tb(name) values('张七')
insert into tb(name) values('张八')
insert into tb(name) values('张九')
insert into tb(name) values('张十')

--显示插入的结果
select * from tb
/*
id          name
----------- ----------
1           张三
2           张四
3           张五
4           张六
5           张七
6           张八
7           张九
8           张十

(8 行受影响)

*/
--删除部分记录
delete from tb where name in('张三','张七','张八','张十')

--显示删除后的结果
select * from tb
/*
id          name
----------- ----------
2           张四
3           张五
4           张六
7           张九

(4 行受影响)

*/
--再次插入记录
insert into tb(name) values('李一')
insert into tb(name) values('李二')

--显示插入的结果
select * from tb order by id
/*
id          name
----------- ----------
1           李一
2           张四
3           张五
4           张六
5           李二
7           张九

(6 行受影响)
*/

--删除环境
drop table tb
drop function f_getid

 

本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/htl258/archive/2009/07/22/4369943.aspx