一、基本概念
存储过程是一组为了完成特定功能的SQL语句和流控制的语句集,是一种经编译后存储在数据库中的PL/SQL块。通常普通的PL/SQL程序称为无名块,而存储过程是以命名的方式存储于数据库中,用户通过指定存储过程的名字并给出参数(如果该存储过程带有参数)来执行它。
优点:
-- 以命名的数据库对象形式存储在数据库中,而不是保存在本地,用户可以在任何客户机上登录到存储过程,并调用或修改代码;
-- 存储过程可由数据库提供安全保证,需要有存储过程的所有者的授权或这创建者本身才能执行存储过程;
-- 存储过程的信息是写入数据字典的,所以存储过程可以看成一个公用模块,用户编写的PL/SQL程序或其他存储过程都可以调用它。一个重复使用的功能可以被设计成存储过程;
-- 可以传递参数给存储过程,参数的传递有多重方式,存储过程可以有返回值,也可以没有返回值,其返回值必须通过参数带回
二、语法介绍
1. 创建存储过程
创建一个存储过程需要 CREATE PROCEDURE 或 CREATE ANY PROCEDURE 的系统权限,可由系统管理员授予权限。创建一个存储过程的语句如下:
CREATE [OR REPLACE] PROCEDURE 存储过程名[(参数[IN|OUT|IN OUT] 数据类型...)]
{AS|IS}
[说明部分]
BEGIN
可执行部分
[EXCEPTION
错误处理部分]
END [过程名];
其中:
可选关键字or replace表示如果存储过程已存在,则用新的存储过程覆盖,通常用于存储过程的重建。参数部分用于定义多个参数(如果没有参数,就可以省略)。参数有三种形式:IN、OUT、IN OUT,如果没有指明参数的形式,则默认为IN。关键字AS也可以写成IS,后面跟过程的说明部分,可以在此定义过程的局部变量。
编写存储过程可以使用任意文本编辑器或直接在SQL*Plus环境下进行,编写好的存储过程必须要在SQL*Plus环境下进行编译,生成编译代码,源代码和编译代码在编译过程中都会被存入数据库,编译成功的存储过程就可以在Oracle环境下进行调用了。
一个存储过程在不需要的时候可以被删除,删除存储过程的人是过程的创建者或者拥有DROP ANY PROCEDURE系统权限的人。删除语法如下:
DROP PROCEDURE 存储过程名 COMPILE;
执行(或调用)存储过程的人是过程的创建者或是拥有EXECUTE ANY PROCEDURE系统权限的人或是被拥有者授予的EXECUTE权限的人。执行方法如下:
方法1:
EXECUTE 模式名.存储过程名[(参数...)];
方法2:
BEGIN
模式名.存储过程名[(参数...)];
END;
传递的参数必须与定义的参数类型、个数和顺序一致(如果定义了默认值,则调用时可以省略参数)。参数可以是变量、常量或表达式。如果是调用本账户下的存储过程,则模式名可以省略。要调用其他账户编写的存储过程,则模式名必须要添加。
三、具体实现
【举例1】创建一个显示雇员总人数的存储过程。
步骤1:登陆SCOTT账户(或学生个人账户)
【注:scott是一个系统已经新建好的普通用户,用户名scott,密码默认tiger,默认状态是被锁定,DBA用户执行,alter user scott account unlock;可以解锁登陆,用来进行试验和测试】
步骤2:在SQL*Plus输入区中输入以下存储过程:
CREATE OR REPLACE PROCEDURE EMP_COUNT
AS
V_TOTAL NUMBER(10);
BEGIN
SELECT COUNT(*) INTO V_TOTAL FROM EMP;
DBMS_OUTPUT.PUT_LINE('雇员总人数为:' || V_TOTAL);
END;
步骤3:按执行按钮进行编译,如有错误则会报错,编译结果正确将会显示:
过程已创建。
步骤4:调用存储过程,在输入区输入以下语句并执行:
EXECUTE EMP_COUNT;
显示结果为:
雇员总人数为:14
PL/SQL过程已成功完成。
说明:
在该练习中,V_TOTAL变量是存储过程定义的局部变量,用于接受查询到的总人数。注意在SQL*Plus中输入存储过程,按“执行”按钮是进行编译,不是执行存储过程。
如果在存储过程中引用了其他用户的对象,比如表,则必须有其他用户授予的对象访问权限。一个存储过程一旦编译成功,就可以由其他用户或程序来引用。但存储过程或函数的所有者必须授予其他用户执行该过程的权限。
存储过程没有参数,在调用时,直接写过程名即可。
【举例2】在PL/SQL程序中调用存储过程
步骤1:登陆SCOTT账户
步骤2:授权STUDENT账户使用该存储过程,即在SQL*Plus输入区中,输入以下命令:
GRANT EXECUTE ON EMP_COUNT TO STUDENT
授权成功。
登陆STUDENT账户,在SQL*Plus输入区中输入:
SET SERVEROUTPUT ON
BEGIN
SCOTT.EMP_COUNT;
END;
执行以上程序,结果为:
雇员总人数为:14
PL/SQL过程已成功完成。
注意:在程序中调用存储过程,使用了第二种语法。【举例3】编写显示雇员信息的储存过程EMP_LIST,并引用EMP_COUNT存储过程。
步骤1:在SQL*Plus输入区中输入并编译以下存储过程:
CREATE OR REPLACE PROCEDURE EMP_LIST
AS
CURSOR emp_cursor IS
SELECT empno,ename FROM emp;
BEGIN
FOR Emp_record IN emp_cursor LOOP
DBMS_OUTPUT.PUT_LINE(Emp_record.empno||Emp_record.ename);
END LOOP;
EMP_COUNT;
END;
执行结果:
过程已创建。
步骤2:调用存储过程,在输入区中输入以下语句并执行:
EXECUTE EMP_LIST
显示结果:
7369SMITH
7499ALLEN
7521WARD
7566JONES
执行结果:
雇员总人数为:14
PL/SQL 过程已成功完成
说明:以上的EMP_LIST存储过程使用了游标,用来循环显示所有雇员的信息。然后调用已经成功编译的存储过程EMP_COUNT,用来附加显示雇员的总人数。通过EXECUTE命令来执行EMP_LIST存储过程。
参数传递
参数的作用是向存储过程传递数据,或从存储过程获得返回结果。正确使用参数可以大大增加存储过程的灵活性和通用性。
参数有以下三种,
IN 定义一个输入参数变量,用于传递参数给存储过程
OUT 定义一个输出参数变量,用于从存储过程获取数据
IN OUT 定义一个输入、输出参数变量,兼有以上两者的功能
参数的定义形式和作用如下:
参数名 IN 数据类型 DEFAULT 值;
定义一个输入参数变量,用于传递参数给存储过程。在调用存储过程时,主程序的实际参数可以是常量、有值变量或表达式等。DEFAULT 关键字为可选项,用来设定参数的默认值。如果在调用存储过程时不指明参数,则参数变量取默认值。在存储过程中,输入变量接收主程序传递的值,但不能对其进行赋值。
参数名 OUT 数据类型;
定义一个输出参数变量,用于从存储过程获取数据,即变量从存储过程中返回值给主程序。
在调用存储过程时,主程序的实际参数只能是一个变量,而不能是常量或表达式。在存储过程中,参数变量只能被赋值而不能将其用于赋值,在存储过程中必须给输出变量至少赋值一次。
参数名 IN OUT 数据类型 DEFAULT 值;
定义一个输入、输出参数变量,兼有以上两者的功能。在调用存储过程时,主程序的实际参数只能是一个变量,而不能是常量或表达式。DEFAULT 关键字为可选项,用来设定参数的默认值。在存储过程中,变量接收主程序传递的值,同时可以参加赋值运算,也可以对其进行赋值。在存储过程中必须给变量至少赋值一次。
如果省略IN、OUT或IN OUT,则默认模式是IN。
【举例1】编写雇员增加工资的存储过程CHANGE_SALARY,通过IN类型的参数传递要增加工资的雇员编号和增加的工资额。
步骤1:登陆SCOTT账户。
步骤2:在SQL*Plus输入区中输入以下过程并执行:
CREATE OR REPLACE PROCEDURE CHANGE_SALARY(P_EMPNO IN NUMBER DEFAULT 7788,P_RAISE NUMBER DEFAULT 10)
AS
V_ENAME VARCHAR2(10);
V_SAL NUMBER(5);
BEGIN
SELECT ENAME,SAL INTO V_ENAME,V_SAL FROM EMP WHERE EMPNO=P_EMPNO;
UPDATE EMP SET SAL=SAL+P_RAISE WHERE EMPNO=P_EMPNO;
DBMS_OUTPUT.PUT_LINE('雇员'||V_ENAME||'的工资被改为'||TO_CHAR(V_SAL+P_RAISE));
COMMIT;
EXCEPTION
WHEN OTHERS THEN
DBMS_OUTPUT.PUT_LINE('发生错误,修改失败!');
ROLLBACK;
END;
执行结果为:
过程已创建。
步骤3:调用存储过程,在输入区中输入以下语句并执行:
EXECUTE CHANGE_SALARY(7788,80)
显示结果为:
雇员SCOTT的工资被改为3080
说明:从执行结果可以看到,雇员SCOTT的工资已由原来的3000改为3080。参数的值由调用者传递,传递的参数的个数、类型和顺序应该和定义的一致。如果顺序不一致,可以采用以下调用方法。如上例,执行语句可以改为:
EXECUTE CHANGE_SALARY(P_RAISE=>80,P_EMPNO=>7788);
可以看出传递参数的顺序发生了变化,并且明确指出了参数名和要传递的值,=>运算符左侧是参数名,右侧是参数表达式,这种赋值方法的意义较清楚。
【举例2】调用存储过程CHANGE_SALARY,不传递参数,使用默认参数,
在SQL*Plus输入区输入命令:
EXECUTE CHANGE_SALARY
显示结果为:
雇员SCOTT的工资被改为3090
说明:在存储过程的调用中没有传递参数,而是采用了默认值7788和10,即默认雇员号为7788,增加的工资为10。
【举例3】使用OUT类型的参数返回存储过程的结果。步骤1:登录SCOTT账户。
步骤2:在SQL*Plus输入区中输入并编译以下存储过程:
CREATE OR REPLACE PROCEDURE EMP_COUNT(P_TOTAL OUT NUMBER)
AS
BEGIN
SELECT COUNT(*) INTO P_TOTAL FROM EMP;
END;
执行结果为:
1.过程已创建。
步骤3:输入以下程序并执行:
DECLAREV_EMPCOUNT NUMBER;
BEGIN
EMP_COUNT(V_EMPCOUNT);
DBMS_OUTPUT.PUT_LINE('雇员总人数为:'||V_EMPCOUNT);
END;
显示结果为:
雇员总人数为:14
PL/SQL 过程已成功完成。
说明:在存储过程中定义了OUT类型的参数P_TOTAL,在主程序调用该存储过程时,传递了参数V_EMPCOUNT。在存储过程中的SELECT...INTO...语句中对P_TOTAL进行赋值,赋值结果由V_EMPCOUNT变量带回给主程序并显示。
以上程序要覆盖同名的EMP_COUNT存储过程,如果不使用OR REPLACE选项,就会出现以下错误:
ERROR 位于第 1 行:
ORA-00955: 名称已由现有对象使用。
【举例4】使用IN OUT类型的参数,给电话号码增加区码。
步骤1:登录SCOTT账户。
步骤2:在SQL*Plus输入区中输入并编译以下存储过程:
CREATE OR REPLACE PROCEDURE ADD_REGION(P_HPONE_NUM IN OUT VARCHAR2)
AS
BEGIN
P_HPONE_NUM:='0755-'||P_HPONE_NUM;
END;
执行结果为:
过程已创建。
步骤3:输入以下程序并执行:
SET SERVEROUTPUT ONDECLARE
V_PHONE_NUM VARCHAR2(15);
BEGIN
V_PHONE_NUM:='26731092';
ADD_REGION(V_PHONE_NUM);
DBMS_OUTPUT.PUT_LINE('新的电话号码:'||V_PHONE_NUM);
END;
显示结果为:
新的电话号码:0755-26731092
PL/SQL 过程已成功完成。
说明:变量V_HPONE_NUM既用来向存储过程传递旧电话号码,也用来向主程序返回新号码。新的号码在原来基础上增加了区号0755和-。
存储过程和函数的查看
可以通过对数据字典的访问来查询存储过程或函数的有关信息,如果要查询当前用户的存储过程或函数的源代码,可以通过对USER_SOURCE数据字典视图的查询得到。USER_SOURCE的结构如下:
DESCRIBE USER_SOURCE
结果为:
名称 是否为空? 类型
------------------------------------------------------------- ------------- -----------------------
NAME VARCHAR2(30)
TYPE VARCHAR2(12)
LINE NUMBER
TEXT VARCHAR2(4000)
说明:里面按行存放着过程或函数的脚本,NAME是过程或函数名,TYPE 代表类型(PROCEDURE或FUNCTION),LINE是行号,TEXT 为脚本。
【训练1】 查询过程EMP_COUNT的脚本。
在SQL*Plus中输入并执行如下查询:
select TEXT from user_source WHERE NAME='EMP_COUNT';
结果为:
TEXT
--------------------------------------------------------------------------------
PROCEDURE EMP_COUNT(P_TOTAL OUT NUMBER)
AS
BEGIN
SELECT COUNT(*) INTO P_TOTAL FROM EMP;
END;
【训练2】 查询过程GET_EMP_NAME的参数。
在SQL*Plus中输入并执行如下查询:
DESCRIBE GET_EMP_NAME
结果为:
FUNCTION GET_EMP_NAME RETURNS VARCHAR2
参数名称 类型 输入/输出默认值?
----------------------------------------- ----------------------------------- ----------------- -------------
P_EMPNO NUMBER(4) IN DEFAULT
【训练3】 在发生编译错误时,显示错误。
SHOW ERRORS
以下是一段编译错误显示:
LINE/COL ERROR
------------- -----------------------------------------------------------------
4/2 PL/SQL: SQL Statement ignored
4/36 PLS-00201: 必须说明标识符 'EMPP'
说明:查询一个存储过程或函数是否是有效状态(即编译成功),可以使用数据字典USER_OBJECTS的STATUS列。
【训练4】 查询EMP_LIST存储过程是否可用:
STATUS
------------
VALID
说明:VALID表示该存储过程有效(即通过编译),INVALID表示存储过程无效或需要重新编译。当Oracle调用一个无效的存储过程或函数时,首先试图对其进行编译,如果编译成功则将状态置成VALID并执行,否则给出错误信息。
当一个存储过程编译成功,状态变为VALID,会不会在某些情况下变成INVALID。结论是完全可能的。比如一个存储过程中包含对表的查询,如果表被修改或删除,存储过程就会变成无效INVALID。所以要注意存储过程和函数对其他对象的依赖关系。
如果要检查存储过程或函数的依赖性,可以通过查询数据字典USER_DENPENDENCIES来确定,该表结构如下:
DESCRIBE USER_DEPENDENCIES;
结果
名称 是否为空? 类型
-------------------------------------------------------------- ------------- ----------------------------
NAME NOT NULL VARCHAR2(30)
TYPE VARCHAR2(12)
REFERENCED_OWNER VARCHAR2(30)
REFERENCED_NAME VARCHAR2(64)
REFERENCED_TYPE VARCHAR2(12)
REFERENCED_LINK_NAME VARCHAR2(128)
SCHEMAID NUMBER
DEPENDENCY_TYPE VARCHAR2(4)
说明:NAME为实体名,TYPE为实体类型,REFERENCED_OWNER为涉及到的实体拥有者账户,REFERENCED_NAME为涉及到的实体名,REFERENCED_TYPE 为涉及到的实体类型。
【训练5】 查询EMP_LIST存储过程的依赖性。
SELECT REFERENCED_NAME,REFERENCED_TYPE FROM USER_DEPENDENCIES WHERE NAME='EMP_LIST';
结果:
REFERENCED_NAME REFERENCED_TYPE
------------------------------------------------------------------------------------------ ----------------------------
STANDARD PACKAGE
SYS_STUB_FOR_PURITY_ANALYSIS PACKAGE
DBMS_OUTPUT PACKAGE
DBMS_OUTPUT SYNONYM
DBMS_OUTPUT NON-EXISTENT
EMP TABLE
EMP_COUNT PROCEDURE
说明:可以看出存储过程EMP_LIST依赖一些系统包、EMP表和EMP_COUNT存储过程。如果删除了EMP表或EMP_COUNT存储过程,EMP_LIST将变成无效。
还有一种情况需要我们注意:如果一个用户A被授予执行属于用户B的一个存储过程的权限,在用户B的存储过程中,访问到用户C的表,用户B被授予访问用户C的表的权限,但用户A没有被授予访问用户C表的权限,那么用户A调用用户B的存储过程是失败的还是成功的呢?答案是成功的。如果读者有兴趣,不妨进行一下实际测试。
包的应用:
敬请期待......
注:本文仅针对本人使用的Oracle数据库。
参考文章:
http://www.jb51.net/article/50540.htm