【转载】SAP-ABAP-如何查找系统中已经存在的增强（包括1代2代3代BTE表字段增强等）和标准的增强点...-CSDN博客

本文详细解释了如何使用SE38执行程序查找SAPABAP中的二代和三代增强（如BADI、BTE）、CIIncludes以及客户出口增强，包括通过SMOD和SXSD的查找过程。同时提及了如何通过BAPI查找自定义程序列表。

摘要由CSDN通过智能技术生成

原文

SE38执行程序SNIF，输入如下参数，运行。等待运行结果

结果如下，下面我们逐项说明：

append：表增强字段，alv中append name代表表增强结构，used in table代表增强的表，剩余两项分别代表增强结构所在的包及增强结构的描述，双击可以看到增强结构中的具体字段，也可在se11中寻找表字段为.APPEND的字段，代表增强字段
三代增强（BADI）:ALV中第一个字段为标准BADI名称可在SE18中查看实施方法；第三个字段代表系统中已经存在的增强实施名称可在SE19中查看

3.BTE增强，也叫替代增强，ALV展现出系统中存在的所有的BTE增强清单，在第二个字段筛选Z*就可以找到系统已经实施的BTE增强

4.CI Includes ：表字段增强的一种

5.二代增强，客户出口：第三个字段为客户出口名称，可在SMOD中查看，出现的功能模块即为ALV上的第一个字段，双击功能模组可查看增强字段

6.我也不知道是个啥，猜测应该是一代增强(欢迎各路大神评论指出)

7.BAPI:运行程式选择BAPI，由于提示说用时较长，此处单独摘出来，看着样子像是哪些自开发程序调用了bapi的清单，但是也不全，具体我也不太懂，欢迎各路大神评论指点。

该程式除了以上7点找系统中已经存在的增强外，也可以找系统中没有被实施的增强点，勾选了下图这个选项就会将系统中没有实施的增强点也列出来。

SAP-ABAP-快速查找二代三代增强程序

运行截图

选择屏幕

*&---------------------------------------------------------------------*
*& Report ZCOM_CEARCH_BADI
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZCOM_CEARCH_BADI.
 
TABLES : TSTC,
         TADIR,
         MODSAPT,
         MODACT,
         TRDIR,
         TFDIR,
         ENLFDIR,
         SXS_ATTRT ,
         TSTCT.
DATA : JTAB LIKE TADIR OCCURS 0 WITH HEADER LINE.
DATA : FIELD1(30).
DATA : V_DEVCLASS LIKE TADIR-DEVCLASS.
PARAMETERS : P_TCODE LIKE TSTC-TCODE,
             P_PGMNA LIKE TSTC-PGMNA.
DATA WA_TADIR TYPE TADIR.
 
START-OF-SELECTION.
  IF NOT P_TCODE IS INITIAL.
    SELECT SINGLE * FROM TSTC WHERE TCODE EQ P_TCODE.
  ELSEIF NOT P_PGMNA IS INITIAL.
    TSTC-PGMNA = P_PGMNA.
  ENDIF.
  IF SY-SUBRC EQ 0.
    SELECT SINGLE * FROM TADIR
    WHERE PGMID = 'R3TR'
    AND OBJECT = 'PROG'
    AND OBJ_NAME = TSTC-PGMNA.
    MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
    IF SY-SUBRC NE 0.
      SELECT SINGLE * FROM TRDIR
      WHERE NAME = TSTC-PGMNA.
      IF TRDIR-SUBC EQ 'F'.
        SELECT SINGLE * FROM TFDIR
        WHERE PNAME = TSTC-PGMNA.
        SELECT SINGLE * FROM ENLFDIR
        WHERE FUNCNAME = TFDIR-FUNCNAME.
        SELECT SINGLE * FROM TADIR
        WHERE PGMID = 'R3TR'
        AND OBJECT = 'FUGR'
        AND OBJ_NAME EQ ENLFDIR-AREA.
        MOVE : TADIR-DEVCLASS TO V_DEVCLASS.
      ENDIF.
    ENDIF.
    SELECT * FROM TADIR INTO TABLE JTAB
    WHERE PGMID = 'R3TR'
    AND OBJECT IN ('SMOD', 'SXSD')
    AND DEVCLASS = V_DEVCLASS.
    SELECT SINGLE * FROM TSTCT
    WHERE SPRSL EQ SY-LANGU
    AND TCODE EQ P_TCODE.
    FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
    WRITE:/(19) 'Transaction Code - ',
    20(20) P_TCODE,
    45(50) TSTCT-TTEXT.
    SKIP.
    IF NOT JTAB[] IS INITIAL.
      WRITE:/(105) SY-ULINE.
      FORMAT COLOR COL_HEADING INTENSIFIED ON.
* Sorting the internal Table
      SORT JTAB BY OBJECT.
      DATA : WF_TXT(60)     TYPE C,
             WF_SMOD        TYPE I,
             WF_BADI        TYPE I,
             WF_OBJECT2(30) TYPE C.
      CLEAR : WF_SMOD, WF_BADI , WF_OBJECT2.
* Get the total SMOD.
      LOOP AT JTAB INTO WA_TADIR.
        AT FIRST.
          FORMAT COLOR COL_HEADING INTENSIFIED ON.
          WRITE:/1 SY-VLINE,
          2 'Enhancement/ Business Add-in',
          41 SY-VLINE ,
          42 'Description',
          105 SY-VLINE.
          WRITE:/(105) SY-ULINE.
        ENDAT.
        CLEAR WF_TXT.
        AT NEW OBJECT.
          IF WA_TADIR-OBJECT = 'SMOD'.
            WF_OBJECT2 = 'Enhancement' .
          ELSEIF WA_TADIR-OBJECT = 'SXSD'.
            WF_OBJECT2 = ' Business Add-in'.
          ENDIF.
          FORMAT COLOR COL_GROUP INTENSIFIED ON.
          WRITE:/1 SY-VLINE,
          2 WF_OBJECT2,
          105 SY-VLINE.
        ENDAT.
        CASE WA_TADIR-OBJECT.
          WHEN 'SMOD'.
            WF_SMOD = WF_SMOD + 1.
            SELECT SINGLE MODTEXT INTO WF_TXT
            FROM MODSAPT
            WHERE SPRSL = SY-LANGU
            AND NAME = WA_TADIR-OBJ_NAME.
            FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
          WHEN 'SXSD'.
* For BADis
            WF_BADI = WF_BADI + 1 .
            SELECT SINGLE TEXT INTO WF_TXT
            FROM SXS_ATTRT
            WHERE SPRSL = SY-LANGU
            AND EXIT_NAME = WA_TADIR-OBJ_NAME.
            FORMAT COLOR COL_NORMAL INTENSIFIED ON.
        ENDCASE.
        WRITE:/1 SY-VLINE,
        2 WA_TADIR-OBJ_NAME HOTSPOT ON,
        41 SY-VLINE ,
        42 WF_TXT,
        105 SY-VLINE.
        AT END OF OBJECT.
          WRITE : /(105) SY-ULINE.
        ENDAT.
      ENDLOOP.
      WRITE:/(105) SY-ULINE.
      SKIP.
      FORMAT COLOR COL_TOTAL INTENSIFIED ON.
      WRITE:/ 'No.of Exits:' , WF_SMOD.
      WRITE:/ 'No.of BADis:' , WF_BADI.
    ELSE.
      FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
      WRITE:/(105) 'No userexits or BADis exist'.
    ENDIF.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(105) 'Transaction does not exist'.
  ENDIF.
 
AT LINE-SELECTION.
  DATA : WF_OBJECT TYPE TADIR-OBJECT.
  CLEAR WF_OBJECT.
  GET CURSOR FIELD FIELD1.
  CHECK FIELD1(8) EQ 'WA_TADIR'.
  READ TABLE JTAB WITH KEY OBJ_NAME = SY-LISEL+1(20).
  MOVE JTAB-OBJECT TO WF_OBJECT.
  CASE WF_OBJECT.
    WHEN 'SMOD'.
      SET PARAMETER ID 'MON' FIELD SY-LISEL+1(10).
      CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.
    WHEN 'SXSD'.
      SET PARAMETER ID 'EXN' FIELD SY-LISEL+1(20).
      CALL TRANSACTION 'SE18' AND SKIP FIRST SCREEN.
  ENDCASE.

有时候在上网查资料的时候，发现比较好的文章，就会分享给大家，版权归原作者所有。

原文链接：

https://blog.csdn.net/huanglin529/article/details/117476695?utm_medium=distribute.pc_relevant.none-task-blog-2~default~baidujs_baidulandingword~default-4-117476695-blog-122881729.235^v38^pc_relevant_default_base&spm=1001.2101.3001.4242.3&utm_relevant_index=7