全面理解Gradle - 定义Task

版权声明:本文为博主原创文章,未经博主允许不得转载。 https://blog.csdn.net/singwhatiwanna/article/details/78898113

系列文章回顾
Gradle从入门到实战 - Groovy基础
全面理解Gradle - 执行时序

之前我们讲述了Groovy的语法,还讲述了Gradle的执行时序,本篇文章讲述下Task的定义。

Task可以理解为Gradle的执行单元,实在是太重要了。根据前面的分析,Gradle通过一个个task来完成具体的构建任务,下面我们来看下Task的定义。

最简单直接,通过如下方式来定义:

task myTask {
    println "config myTask"
}

我们执行下

renyugang$ gradle myTask

config myTask

再执行下

renyugang$ gradle clean

config myTask

可以看出,通过上述方式定义的task,括号内部的代码会在配置阶段执行,也就是说,只要我执行任何一个task,那段代码都会执行,因为每个task执行之前都需要进行一遍完整的配置。

但是很多时候我们并不需要写配置代码,我们想要括号内的代码仅仅在执行我们的task的时候才执行,这个时候可以通过doFirst或者doLast来完成。

  • doFirst:task执行时,最开始的操作
  • doLast:task执行时,最后的操作
// 定义并配置myTask
task myTask {
    println "config myTask"
}

myTask.doLast {
    println "after execute myTask"
}

myTask.doFirst {
    println "before execute myTask"
}

执行结果如下

config myTask
:app:myTask
before execute myTask
after execute myTask

除此之外,doLast还有一个等价的操作leftShift,leftShift还可以缩写为<<,因此下面的三种实现效果等价:

myTask.doLast {
    println "after execute myTask"
}

myTask.leftShift {
    println "after execute myTask"
}

myTask << {
    println "after execute myTask"
}

在上面的demo中,myTask真正执行的时候啥都没干,它只是在执行的最开始和最后做了一些事情。

其实,通过@TaskAction操作符也可以指定一个Task执行时要做的事情,它区别于doFirst和doLast,不过@TaskAction平时用的较少,这里简单示范下:

class RygTask extends DefaultTask {

    String message = 'This is RygTask'

    // @TaskAction 表示该Task要执行的动作,即在调用该Task时,hello()方法将被执行
    @TaskAction
    def hello(){
        println "Hello world. $message"
    }
}

// hello使用了默认的message值
task hello(type:RygTask)

// 重新设置了message的值
task hello1(type:RygTask){
    message ="I am an android developer"
}

执行gradle hello hello1

:app:hello
Hello world. This is RygTask

:app:hello1
Hello world. I am an android developer

除了上面的Task定义方式以外,Gradle本身还提供了一些已有的Task供我们使用,比如Copy、Delete、Sync等。因此我们定义Task的时候是可以继承已有的Task,比如我们可以继承自系统的Copy Task来完成文件的拷贝操作。

task myTask(type: Copy) { configure closure }

除了这种方式以外,我们还可以通过API来动态创建Task,API也有很多,这里介绍几个最常用的(Gradle水很深,API特别灵活,大家记住最常用的就好)。

// 下面三种定义也一模一样

task myTask << {
    println "after execute myTask"
}

project.task('myTask').doLast {
    println "after execute myTask"
}

project.tasks.create('myTask').doLast {
    println "after execute myTask"
}

定义Task的时候是可以指定很多参数的,如下所示:

参数 含义 默认值
name task的名字 不能为空,必须指定
type task的“父类” DefaultTask
overwrite 是否替换已经存在的task false
dependsOn task依赖的task的集合 []
group task属于哪个组 null
description task的描述 null

在上面的例子中都没涉及参数,下面举个带参数的栗子。

task myTask1 << {
    println "execute myTask1"
}

task myTask2 << {
    println "execute myTask2"
}

// 定义一个名字为rygTask的task,属于renyugang分组,并且依赖myTask1和myTask2两个task。
project.task('rygTask', group: "renyugang", description: "我自己的Task", dependsOn: ["myTask1", "myTask2"] ).doLast {
    println "execute rygTask"
}

通过Gradle tasks来查看:

Publishing tasks
----------------
bintrayUpload - Publishes artifacts to bintray.com.

Renyugang tasks
---------------
rygTask - 我自己的Task

Upload tasks
------------
uploadArchives - Uploads all artifacts belonging to configuration ':AndroidStub:archives'

尝试执行gradle rygTask,结果如下:

:app:myTask1
execute myTask1

:app:myTask2
execute myTask2

:app:rygTask
execute rygTask

结果不用我解释了,相信大家都能看懂。

补充说明

  • Gradle命令是支持连在一起拼写的,比如gradle hello hello1,那么gradle将会先执行hello,然后再执行hello1。
  • Gradle命令是可以缩写的,前提是这个缩写能够唯一地限定一个task。比如rygTask,那么执行的时候就可以缩写为gradle rTask

最后,定义task的API很多,我介绍了最常用的部分,剩下的细节还是需要大家查看Gradle文档,其实学习Gradle就是一个查文档的过程。如下几个文档,大家读读。

Project API
TaskContainer API
Task API

阅读更多

没有更多推荐了,返回首页