Shader "Unlit/SpecularVertexLevelMat"
{
Properties
{
_Diffuse("Difuse", Color) = (1, 1, 1, 1) //漫反射颜色属性
_Specular("Specular", Color) = (1, 1, 1, 1) //高光反射颜色
_Gloss("Gloss", Range(8.0, 256)) = 20 //控制高光区域大小
}
SubShader{
Pass{
//LightMode 定义Pass在Unity光照流水线中的角色
Tags{"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f{
float4 pos : SV_POSITION;
fixed3 color : COLOR;
};
v2f vert(a2v v){
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
// 反射方向 = l - 2(n · l)n ,函数reflect(i, n) i代表入射方向, n代表法线方向
fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
//viewDir指物体表面顶点指向相机位置的方向
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
//高光反射 = 入射光颜色强度 * 材质高光反射系数 * Max(0, 视角方向 · 反射方向)^ 光泽度
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
o.color = ambient + diffuse + specular;
return o;
}
fixed4 frag(v2f i) : SV_Target{
return fixed4(i.color, 1.0);
}
ENDCG
}
}
Fallback "Specular"
}
【Unity Shader】逐顶点高光反射
于 2024-07-30 16:16:20 首次发布