在SAP中可以使用CSAP函数组中的函数更改BOM,下面是一个结合使用CSAP_MAT_BOM_OPEN, CSAP_BOM_ITEM_MAINTAIN 和 CSAP_MAT_BOM_CLOSE 进行BOM更改的例子,网上有可参考的帮助 http://help.sap.com/saphelp_40b/helpdata/fr/92/58b521417011d189ec0000e81ddfac/content.htm
另外,关于BOM数据批量传输,可以了解一下 SAP Note 545676 - FAQ BOM data transfer .
Update:2009-11-23
Bugfix: 增加CLEAR T_STPO.
********************************************************************************************
* (C) 2008 Shenzhen McQuay Air Conditional
********************************************************************************************
* Program : ZPPR017B
* Title : BOM 批量更改测试
* Description :
* Special logic : http://help.sap.com/saphelp_40b/helpdata/fr/92/58b521417011d189ec0000e81ddfac/content.htm
* Author : likai (gwxkai@gmail.om)
********************************************************************************************
* Amendment Log
* -----------------------
* Name(Cor# ) Date Request No. Description
********************************************************************************************
REPORT ZPPR017B.
"For selection-screen
DATA CSAP_MBOM TYPE CSAP_MBOM.
DATA STPO_API03 TYPE STPO_API03."
DATA T_STPO TYPE STANDARD TABLE OF STPO_API02 WITH HEADER LINE.
DATA T_MATNR TYPE STANDARD TABLE OF MATNR WITH HEADER LINE.
DATA MARC TYPE MARC.
*&---------------------------------------------------------------------*
*& 选择屏幕
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK BLOCK1 WITH FRAME TITLE B1_TITLE . "B1_TITLE = '请指定选择条件'.
"BOM 选择条件
SELECT-OPTIONS S_MATNR FOR CSAP_MBOM-MATNR.
PARAMETERS P_PLANT LIKE CSAP_MBOM-WERKS MEMORY ID WRK.
PARAMETERS P_USAGE LIKE CSAP_MBOM-STLAN DEFAULT '1'.
PARAMETERS P_ALT LIKE CSAP_MBOM-STLAL DEFAULT '1'.
PARAMETERS P_DATUV LIKE CSAP_MBOM-DATUV DEFAULT SY-DATUM.
SELECTION-SCREEN SKIP.
"添加物料
PARAMETERS P_ADD RADIOBUTTON GROUP RAD1 DEFAULT 'X'.
PARAMETERS P_CATEG LIKE STPO_API03-ITEM_CATEG DEFAULT 'L'.
PARAMETERS P_COMP LIKE STPO_API03-COMPONENT.
PARAMETERS P_QTY LIKE STPO_API03-COMP_QTY DEFAULT '1'.
PARAMETERS P_UNIT LIKE STPO_API03-COMP_UNIT DEFAULT 'EA'.
SELECTION-SCREEN SKIP.
"其它功能
PARAMETERS P_OTH RADIOBUTTON GROUP RAD1.
SELECTION-SCREEN END OF BLOCK BLOCK1.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN BEGIN OF BLOCK BLOCK3 WITH FRAME TITLE B2_TITLE . "B2_TITLE = '说明'.
SELECTION-SCREEN COMMENT /2(79) COMM1.
SELECTION-SCREEN COMMENT /2(79) COMM2.
SELECTION-SCREEN END OF BLOCK BLOCK3.
INITIALIZATION. " 初始化选择屏上的变量
B1_TITLE = '请指定选择条件'.
B2_TITLE = '说明'.
COMM1 = '警告:请在有经验的用户指导下使用本报表。'.
COMM2 = '向BOM中添加物料时,如果该物料己存在,将不做任何处理,不会更改数量。'.
*&---------------------------------------------------------------------*
*& 主程序
*&---------------------------------------------------------------------*
START-OF-SELECTION.
PERFORM PLANT_AUTHORITY_CHECK USING P_PLANT.
IF P_ADD = 'X'.
PERFORM ADD_MAT_TO_BOM.
ENDIF.
*&---------------------------------------------------------------------*
*& Form ITAB_GET_DATA
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM ADD_MAT_TO_BOM.
SELECT MATNR INTO TABLE T_MATNR FROM MARC
WHERE MATNR IN S_MATNR
AND WERKS = P_PLANT.
LOOP AT T_MATNR INTO MARC-MATNR.
CLEAR: T_STPO,T_STPO[].
CALL FUNCTION 'CSAP_MAT_BOM_OPEN'
EXPORTING
MATERIAL = MARC-MATNR
PLANT = P_PLANT
BOM_USAGE = P_USAGE
ALTERNATIVE = P_ALT
VALID_FROM = P_DATUV
* CHANGE_NO =
* REVISION_LEVEL =
* FL_NO_CHANGE_DOC = ' '
* IMPORTING
* O_STKO =
* FL_WARNING =
TABLES
T_STPO = T_STPO[]
* T_DEP_DATA =
* T_DEP_DESCR =
* T_DEP_ORDER =
* T_DEP_SOURCE =
* T_DEP_DOC =
EXCEPTIONS
ERROR = 1
OTHERS = 2
.
IF SY-SUBRC <> 0.
WRITE: /'E:','打开',MARC-MATNR, '的BOM失败。'.
EXIT.
ENDIF.
READ TABLE T_STPO WITH KEY COMPONENT = P_COMP.
IF SY-SUBRC = 0.
WRITE: /'W:',MARC-MATNR, '的BOM含有该物料,未做更改。'.
EXIT.
ENDIF.
T_STPO-ITEM_CATEG = P_CATEG.
T_STPO-COMPONENT = P_COMP.
T_STPO-COMP_QTY = P_QTY.
T_STPO-COMP_UNIT = P_UNIT.
CALL FUNCTION 'CSAP_BOM_ITEM_MAINTAIN'
EXPORTING
I_STPO = T_STPO "Headline
* FL_DEP_ALE_CONFORM = ' '
* IMPORTING
* O_STPO =
* FL_WARNING =
* TABLES
* T_DEP_DATA =
* T_DEP_DESCR =
* T_DEP_ORDER =
* T_DEP_SOURCE =
* T_DEP_DOC =
EXCEPTIONS
ERROR = 1
OTHERS = 2
.
IF SY-SUBRC = 0.
WRITE: /'I:',MARC-MATNR, '的BOM己更改,未关闭,未更新。'.
ELSE.
WRITE: /'E:',MARC-MATNR, '的BOM更改失败。'.
ENDIF.
CALL FUNCTION 'CSAP_MAT_BOM_CLOSE'
* EXPORTING
* FL_COMMIT_AND_WAIT = 'X'
* IMPORTING
* FL_WARNING =
EXCEPTIONS
ERROR = 1
OTHERS = 2
.
IF SY-SUBRC = 0.
WRITE: /'S:',MARC-MATNR, '的BOM更改己更新。'.
ENDIF.
ENDLOOP.
ENDFORM. ""ITAB_GET_DATA
*&---------------------------------------------------------------------*
*& Form PLANT_AUTHORITY_CHECK
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->P_PLANT text
*----------------------------------------------------------------------*
FORM PLANT_AUTHORITY_CHECK
USING P_WERKS.
AUTHORITY-CHECK OBJECT 'C_STUE_WRK'
ID 'ACTVT' FIELD '03'
ID 'CSWRK' FIELD P_WERKS.
IF SY-SUBRC <> 0.
MESSAGE E001(00) WITH '你没有工厂 ' P_WERKS ' 的权限.'.
ENDIF.
ENDFORM. "PLANT_AUTHORITY_CHECK