表达式

表达式是等价于一个结果值的一段代码，可以复合以产生更长的表达式。JavaFX是一种表达式语言，这意味着一切内容，包括循环，条件控制，甚至代码段，都是表达式。在某些情况下（例如while表达式），表达式是Void类型，并不返回任何结果。

Contents

- Block Expressions
- The if Expression
- Range Expressions
- The for Expression
- The while Expression
- The break and continue Expressions
- The throw, try, catch and finally Expressions

Block Expressions
块表达式

块表达式包含一个被大括号括起来的用分号间隔的声明或表达式的列表。块表达式的值是最后一个表达式的值。如果块表达式为包含任何表达式，则为Void类型。注意var和def也是表达式。

下面的块表达式添加一些数值，并存储结果在变量total里：
var nums = [5, 7, 3, 9];
var total = {
var sum = 0;
for (a in nums) { sum += a };
sum;
}
println("Total is {total}.");

运行产生如下输出：
Total is 24.

第一行（var nums = [5, 7, 3, 9];）声明一个整数序列。

第二行声明变量total，接收整数的和。

下面的块表达式在大括号间包含所有内容：
{
var sum = 0;
for (a in nums) { sum += a };
sum;
}

其中第一行声明变量sum，用来接收序列中数字的和。第二行遍历序列并增加每个数字到sum。最后一行设置块表达式的返回值。

The if Expression
if表达式

if表达式通过执行特定的代码段来实现程序流，如果相应的条件成立的话。

例如，下面的脚本根据年龄来定票价。12-65岁的票价10元。老人和儿童票价5元，低于5元的儿童免费。
def age = 8;
var ticketPrice;

if (age < 5 ) {
ticketPrice = 0;
} else if (age < 12 or age > 65) {
ticketPrice = 5;
} else {
ticketPrice = 10;
}
println("Age: {age} Ticket Price: {ticketPrice} dollars.");

年龄设为8时，输出为：
Age: 8 Ticket Price: 5 dollars.

程序流控制如下：
if (age < 5 ) {
ticketPrice = 0;
} else if (age < 12 or age > 65) {
ticketPrice = 5;
} else {
ticketPrice = 10;
}

如果age小于5，票价设成0。

然后程序跳过了接下来的条件验证，并打印出结果。

如果age不小于5，程序执行接下来的条件验证：
if (age < 5 ) {
ticketPrice = 0;
} else if (age < 12 or age > 65) {
ticketPrice = 5;
} else {
ticketPrice = 10;
}

如果age在5到12之间或大于65，票价设为5。

如果age在12和65之间，程序执行最后一段被else关键字标示的代码：
if (age < 5 ) {
ticketPrice = 0;
} else if (age < 12 or age > 65) {
ticketPrice = 5;
} else {
ticketPrice = 10;
}

这一段在以前的条件都不成立的情况下执行。将age在12和65人的票价设为10。

---------------------------------------------------------------------
注意：以上代码可以用一个简明的条件表达式取代：
ticketPrice = if (age < 5) 0 else if (age < 12 or age > 65) 5 else 10;

这时一个很有用的技巧，你还将在以后的教程中看到。
---------------------------------------------------------------------

Range Expressions
范围表达式

在序列那一节已经告诉过你遵循等差数列的数字序列简写形式：
var num = [0..5];

严格地说，[0..5]是一个范围表达式。元素间的数值间隔默认为1，但是你可以使用step关键字来指明一个其他的间隔。例如从1到10之间的奇数序列：
var nums = [1..10 step 2];
println(nums);

输出如下：
[ 1, 3, 5, 7, 9 ]

创建一个下行的范围，使第二个数值小于第一个，需要指明一个负的step值：
var nums = [10..1 step -1];
println(nums);

输出为：
[ 10, 9, 8, 7, 6, 5, 4, 3, 2, 1 ]

如果你不提供一个负的step值，在你创建下行的序列的时候，你将得到一个空序列。
代码如下：
var nums = [10..1 step 1];
println(nums);

下面是编译时的警告：
range.fx:1: warning: empty sequence range literal, probably not what you meant.
var nums = [10..1 step 1];
^
1 warning

你也将得到一个空序列，如果你省略了step值，在上面的例子中。

The for Expression
for表达式

另一个和序列相关的表达式是for表达式。for表达式提供了一种简单的结构在序列项之间循环。
下面是一个例子：
var days = ["Mon","Tue","Wed","Thu","Fri","Sat","Sun"];

for (day in days) {
println(day);
}

输出如下：
Mon
Tue
Wed
Thu
Fri
Sat
Sun

让我们把这个例子分为若干片段。for表达式从for关键字开始：
for (day in days) {
println(day);
}

days变量是被for表达式执行的输入序列的名字：
for (day in days) {
println(day);
}

day变量接收for表达式循环序列时的当前序列项：
for (day in days) {
println(day);
}

注意for表达式中，day变量不需要在使用前声明。进一步说，day也不能在for循环结束后继续使用和被访问。程序员经常用临时的变量名如一个字母来表示。

在前面的例子中，for表达式未返回值，当然，它也可以返回一个序列。下面的代码显示了用for表达式来从一个序列创建另一个序列的例子：

// Resulting sequence squares the values from the original sequence.
var squares = for (i in [1..10]) i*i;

// Resulting sequence is ["MON", "TUE", "WED", and so on...]
var capitalDays = for (day in days) day.toUpperCase();

注意toUpperCase是String对象的函数。您能在API文档里看到所有有用的函数列表。

The while Expression
while表达式

另一个循环结构是while表达式。不像其他的操作序列的表达式，while表达式一直执行直到给定的条件为false。while在语法上是一个表达式，类型为Void，不返回值。

下面是一个例子：
var count = 0;
while (count < 10) {
println("count == {count}");
count++;
}

输出为：
count == 0
count == 1
count == 2
count == 3
count == 4
count == 5
count == 6
count == 7
count == 8
count == 9

The break and continue Expressions
break和continue表达式

break和continue与循环表达式有关。这两个表达式影响着循环进程：break跳出循环，continue放弃本次循环。

break和continue在语法上算是表达式，类型为Void，不返回值。

例子：
for (i in [0..10]) {
if (i > 5) {
break;
}

if (i mod 2 == 0) {
continue;
}

println(i);
}

输出：
1
3
5

在没有if表达式的情况下，程序简单地输出从0到10的数字。

在只有第一个if表达式的情况下，i的值大于5时，程序跳出循环：
if (i > 5) {
break;
}

程序将打印从0到5的数字。

在增加第二个if表达式的情况下，程序放弃当前循环，继续下次循环；
if (i mod 2 == 0) {
continue;
}

这种情况下，只有当i是偶数时continue才执行。一旦执行，下面的println()将不再被调用，数字将不会输出。

The throw, try, catch and finally Expressions
throw，try，catch，finally表达式

在程序实际运行时，很多事件会打破代码的正常执行流程。例如，当程序读取文件的时候，文件不存在，程序将不被执行。我们称这种情况为“异常”。

---------------------------------------------------------------------
注意：异常也是对象。它们的类型通常以它们代表的情况来命名（例如，FileNotFoundException代表文件未找到的情况）。无论如何，向上面的例子中定义特定的异常超出了这一节的范围。我们将使用一个通用的Exception（从Java语言中借来的）来展示throw，try，catch和finally表达式。
---------------------------------------------------------------------

下面的脚本定义（及触发）了一个抛出异常的函数：
import java.lang.Exception;

foo();

println("The script is now executing as expected... ");

function foo() {
var somethingWeird = false;

if(somethingWeird){
throw new Exception("Something weird just happened!");
} else {
println("We made it through the function.");
}
}

执行脚本，打印出以下消息：
We made it through the function.
The script is now executing as expected...

将变量的值置为true，异常将被抛出。运行时脚本将崩溃并输出以下信息：
Exception in thread "main" java.lang.Exception: Something weird just happened!
at exceptions.foo(exceptions.fx:10)
at exceptions.javafx$run$(exceptions.fx:3)

为了防止程序崩溃，我们用try/catch表达式将foo()函数括起来。顾名思义，表达式试图执行一些代码，当有问题出现的时候捕获异常：
try {
foo();
} catch (e: Exception) {
println("{e.getMessage()} (but we caught it)");
}

现在，取代程序崩溃的是，程序输出：
Something weird just happened! (but we caught it)
The script is now executing as expected...

一个finally块（严格地说不是表达式）也可以用上，它总是在try表达式执行完之后的某个时刻执行，不管是由有异常抛出。finally块经常用来做一些清理工作，而不管try代码是成功执行还是抛出异常。
try {
foo();
} catch (e: Exception) {
println("{e.getMessage()} (but we caught it)");
} finally {
println("We are now in the finally expression...");
}

输出如下：
Something weird just happened! (but we caught it)
We are now in the finally expression...
The script is now executing as expected...