Unity shader学习(三)高光反射

高光反射计算公式（phong模型）Cspecular=(Clight*Mspecular)max(0,v*r)mgloss

mgloss为材质的官泽度，也成反射度，控制高光区域亮点有多大

Mspecular是材质的高光反射颜色，控制材质对于高光反射的轻度和颜色

Clight为光源的颜色和强度

v是观察方向的单位向量

r是反射方向 r=2(法线单位向量n*光源方向向量)法线单位向量-光源方向向量

 

高光反射计算公式（Blinn模型）Cspecular=(Clight*Mspecular)max(0,n*h)mgloss

n为法线向量的单位向量

h是对观察方向和光源方向取平均后归一化得到的：h（注：单位向量）=（v(注：单位向量)+光源方向）/|（v(注：单位向量)+光源方向）|

phong模型 逐顶点:

Shader "Custom/SpecularVertexLevel1" {
	Properties {
		_DifColor("Color",Color)=(1,1,1,1)
		_specular("specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8.0,256))=20
	}
	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _DifColor;
			fixed4 _specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				fixed3 color:COLOR;
			};

			v2f vert(a2v v){
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex);
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));
				fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
				fixed3 diffuse=_LightColor0.rgb*_DifColor.rgb*saturate(dot(worldNormal,worldLightDir));
				fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
				fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-mul(unity_ObjectToWorld,v.vertex).xyz);
				fixed3 specular=_LightColor0.rgb*_specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);
				o.color=ambient+diffuse+specular;
				return o;
			}
			fixed4 frag(v2f f):SV_Target{
				return fixed4(f.color,1.0);
			}

			ENDCG
		}
	}
	FallBack "Specular"
}

phong模型 逐像素: 

Shader "Custom/SpecularVertexLevel2" {
	Properties {
		_DifColor("Color",Color)=(1,1,1,1)
		_specular("specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8.0,256))=20
	}
	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _DifColor;
			fixed4 _specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float3 worldPos:TEXCOORD1;
				float3 worldNormal:TEXCOORD0;

			};

			v2f vert(a2v v){
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex);
				o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
				o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
				return o;
			}
			fixed4 frag(v2f f):SV_Target{
				
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal=normalize(f.worldNormal);
				fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
				fixed3 diffuse=_LightColor0.rgb*_DifColor.rgb*saturate(dot(worldNormal,worldLightDir));
				fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
				fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-f.worldPos.xyz);
				fixed3 specular=_LightColor0.rgb*_specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);
				
				return fixed4(ambient+diffuse+specular,1.0);
			}

			ENDCG
		}
	}
	FallBack "Specular"
}

Blinn模型逐像素:

Shader "Custom/SpecularVertexLevel4" {
	Properties {
		_DifColor("Color",Color)=(1,1,1,1)
		_specular("specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8.0,256))=20
	}
	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}

			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"

			fixed4 _DifColor;
			fixed4 _specular;
			float _Gloss;

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float3 worldPos:TEXCOORD1;
				float3 worldNormal:TEXCOORD0;

			};

			v2f vert(a2v v){
				v2f o;
				 //UnityObjectToClipPos unity自带用来把一个坐标从模型空间转换到剪裁空间
				o.pos=UnityObjectToClipPos(v.vertex);
				o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
				o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
				return o;
			}
			fixed4 frag(v2f f):SV_Target{
				//环境光
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
				fixed3 worldNormal=normalize(f.worldNormal);
				fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(f.worldPos));
				//漫反射光照计算
				fixed3 diffuse=_LightColor0.rgb*_DifColor.rgb*saturate(dot(worldNormal,worldLightDir));
				//反射方向 = 单位化反射光照计算函数        
				fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
				//视角方向 = 单位化（相机方向- 顶点位置）世界坐标系下
				fixed3 viewDir=normalize(UnityWorldSpaceViewDir(f.worldPos));
				//平分线
				fixed3 halfDir=normalize(worldLightDir+viewDir);
				//反射光 = 光照颜色*反射光颜色*视角与反射光方向的点积的光滑洗漱次方
				fixed3 specular=_LightColor0.rgb*_specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);
				
				return fixed4(ambient+diffuse+specular,1.0);
			}

			ENDCG
		}
	}
	FallBack "Specular"
}

仅用于前向渲染的只有在渲染模式为前向渲染时（“LightMode”=“ForwordBase”或者"LightMode"="ForwordAdd"）

这三个函数里的内置变量——WorldSpaceLightPos0等才能被正确赋值。