QT粒子特效2

import QtQuick 2.6
import QtQuick.Particles 2.0

/*
 * 作者: yubo
 * 功能: 粒子背景发射器
 * 描述: 三维粒子发射角度，中线点坐标需要按需求设置，粒子数量，速度，变化量，颜色可控制
 * 日期: 2018-07-12
 */
ParticleSystem {
    id: sys
    // 粒子发射速率
    property real particleEmitRate: 20
    // 粒子生命周期
    property real particleLifeSpan: 2000
    // 粒子发射加速度
    property real emitterMagnitude: 0.15 + 0.15 * Car.speed / 220
    // 发射器状态
    property bool emitterStatus: true
    // 发射器粒子颜色
    property string particleColor: "#cde0ff"

    // 发射器粒子图片
    property string particleImage: ""
    // 发射器形状背景图片
    property string maskBackground: ""

    ImageParticle {
        id: part
        visible: emitterStatus
        system: sys
        groups: "A"
        color: particleColor
        width: 200
        height: 30
        source: particleImage
        rotation: 180
        rotationVariation: 180
        rotationVelocity: 15
        rotationVelocityVariation: 15
        entryEffect: ImageParticle.Scale
        autoRotation: true
        Behavior on color { ColorAnimation { duration: 1000 } }
    }

    Emitter {
        id: emitter
        system: sys
        width: background.width
        height: background.height
        emitRate: particleEmitRate
        lifeSpan: particleLifeSpan
        lifeSpanVariation: 1000
        size: 8 + 1
        sizeVariation: 5
        endSize: 1 + 1
        shape: MaskShape { source: maskBackground }
        group: "A"
        velocity: TargetDirection {
            targetX: 350
            targetY: 136
            proportionalMagnitude: true
            magnitude: emitterMagnitude
        }
    }

    Image {
        id: background
        source: maskBackground
    }
}