mini2440+jlink v8+mkd4.54 uart串口通信调试心得体会(11.20补完中断部分)

原创 2013年11月17日 23:59:04

开发环境如题。uart串口通信可分为两种方式:轮询(polling)和中断

今天先把uart串口通信方式中的轮询说说,日后补上中断

采用uart0,串口调试助手4.2

这里只讲需要配置的寄存器,其他寄存器采用默认值:

(1)配置数据格式的寄存器ULCON0,8位数据位,无奇偶校验,1停止位

(2)配置波特率的寄存器UBRDIV0:这个需要往寄存器写一个数字UBRDIV,这个数字是由UART CLOCK和你期望的波特率算出来的

UBRDIV=[UART CLOCK/(BAUD RATE*16)]-1

寄存器上电默认选PCLK为UART CLOCK(我这里配置PCLK为50MHz),BAUD RATE为115200Hz,算出UBRDIV=26.12,四舍五入取26

(3)配置GPHCON寄存器,把GPH0-3功能复用为nCTS0,nRTS0,TXD0,RXD0。

程序这边的准备工作做好了,串口调试助手那的数据格式也选为8位数据位,无奇偶校验,1停止位,波特率115200Hz就OK,其他不用设置。下面说下发送和接收。

发送:

不断地检测寄存器UTRSTAT0寄存器的[1]位,只要为1(即表示transmit buffer register为空),就代表我们可以向寄存器UTXH0写我们想发出去的数据了,一旦向UTXH0写入某个8位二进制数据(这里是和寄存器ULCON0里的数据格式对应的,8位正好可以一次通信就传完,不对应的情况我还没试过),瞬间就会发到串口调试助手上了(所以我从memory watch窗口也看不到[1]位的变化,因为从写入数据到到发送完数据(空→满→空)是一瞬间的事)。

接收:

不断地检测寄存器UTRSTAT0寄存器的[0]位,只要为0(即表示receive buffer register收到了一个数据),接着就可以从寄存器URXH0上读从串口调试助手上发过来的数据了。这里有一点要注意,如果你开着mdk的memory watch窗口,并且监视着寄存器UTRSTAT的地址0x50000010,程序本身很有可能会读不到寄存器UTRSTAT的[0]位的变化,因为memory watch在每执行一条指令,或者你对着地址按回车的时候,都会读一遍memory watch窗口里出现的地址的值。当UTRSTAT0的[0]位为1的时候(当receive buffer register接收到了一个数据后,[0]位会自动置1),如果访问了这个寄存器,它的[0]位就会自动清零。

总结:可以发现,用轮询这个方式完成串口收发数据非常简单,其实当相关寄存器配置好后,收发数据只要两条指令,发送是往transmit buffer register写数据,接收是从receive buffer register读数据,而先读寄存器UTRSTAT0的状态再往寄存器读写数据只是为了保证通信的正确性罢了(避免上一个数据,还没发送完毕,你又写新数据进去;避免上个数据,还没从寄存器读出来,又被一个新数据覆盖了)。

这个模式的缺点也显而易见,如果想串口通信,cpu就不能干别的,得一直在查询寄存器UTRSTAT0的值,所以轮询方式只适合简单的程序,如果你的程序复杂到不能让cpu一直读寄存器UTRSTAT0的值,那你就得用中断方式了(中断方式过些日子补完,后面先贴上轮询的代码)。

程序流程:start:配置寄存器 1:发送字节 0:接收字节(调试串口助手那边设的每过1秒发送一个字节)

	AREA uart,CODE,READONLY
	entry
start
	mov r0,#0x50000000 		;uart channel 0 line control register
	add r0,r0,#0x00
	mov r1,#0x3
	str r1,[r0]
	mov r0,#0x50000000 		;uart channel 0 control register
	add r0,r0,#0x4
	mov r1,#0x000
	add r1,r1,#0x05
	str r1,[r0]
	mov r0,#0x50000000 		;uart channel 0 moden register
	add r0,r0,#0xc
	mov r1,#0x0
	str r1,[r0]
	mov r0,#0x50000000 		;uart channel 0 baud rate divisor register
	add r0,r0,#0x28			;115200hz
	mov r1,#26
	str r1,[r0]
	mov r0,#0x56000000 		;GPHCON register
	add r0,r0,#0x70
	mov r1,#0xaa
	str r1,[r0]
1	
	mov r0,#0x50000000 		;read"transmit register empty"
	add r0,r0,#0x10
	ldr r1,[r0]
	and r1,r1,#0x1<<1
	cmp r1,#1<<1
	bne %b1
	mov r0,#0x50000000 		;write a byte to UTXH0
	add r0,r0,#0x20
	mov r1,#90
	strb r1,[r0]

0	
	mov r0,#0x50000000 		;read"receive buffer data ready"
	add r0,r0,#0x10
	ldr r1,[r0]
	and r1,r1,#0x1
	cmp r1,#1
	bne %b0
	
	mov r0,#0x50000000		;read a byte from URXH0
	add r0,r0,#0x24
	ldrb r1,[r0]
	b %b1
	
	
	end

中断方式:

uart0一共能触发三种子中断:INT_RXT0,INT_TXD0,INT_ERR0,他们同属于INT_UART0中断。

本次实验目标:接收从串口调试助手发来的字符,并发回串口调试助手。很简单,就是熟悉中断方式下的UART通信。

相较轮询方式,这里要多配置几个寄存器,主要是一些和中断有关的寄存器。分别是清这三个子中断的mask,清uart0的mask,使能irq中断,其他默认配置。

这里就强调几个要注意的事情,其他细节见代码:

(1)清中断请求,要写1。我因为忘了这件事,就耽误了一些时间,一直在找其他地方的错误。

(2)SUBS PC,LR,#0X4   这里要注意subs一定要加s,这样才能顺利退出IRQ模式回到管理,因为irq默认是关掉irq中断的,不退出的话,没办法响应下次中断。当然你也可以试试,在irq模式里使能irq中断

(3)大概说一下,程序流程:先执行start部分,都是一些寄存器的配置和把异常向量表复制从0x30000000到0x00000000。接着,进入循环l,等待串口调试助手发来字符。receive buffer register收到字符后,就会触发中断,cpu跳转到中断程序执行。把接收到的字符再写入transmit buffer register送出去。然后退出中断,又回到循环l。

	AREA UART,CODE,READONLY
	ENTRY
EXCEPTION_VECTOR
	b START
	NOP
	NOP
	NOP
	NOP
	NOP
	b interrupt_jump
	NOP
interrupt_jump
	MOV r0,#0X30000000			;这里只能给一个绝对地址,至于为什么看
	ADD R0,R0,#0x2c				;我的裸机按键中断那篇博文
	mov pc,r0
INTERRUPT_HANDLE
	MOV R0,#0X50000000			;URXTH0 read"receive buffer register"
	ADD R0,R0,#0x24
	LDR R2,[R0]	
	MOV R0,#0X50000000			;UTRSTAT read"transmit buffer register empty"
	ADD R0,R0,#0x10
1	LDR R1,[R0]
	AND R1,R1,#0X1<<1
	CMP R1,#0X2
	BNE %B1
	MOV R0,#0X50000000			;UTXD0 WRITE "transmit buffer register"
	ADD R0,R0,#0x20
	STR R2,[R0]
	MOV R0,#0X4a000000			;SUBSRCPND clear RXD0 interrupt request
	ADD R0,R0,#0x18
	mov r1,#0x3
	STR R1,[R0]
	MOV R0,#0X4a000000			;SRCPND clear UART0 interrupt request
	ADD R0,R0,#0x0
	mov r1,#0x1<<28
	STR R1,[R0]
	MOV R0,#0X4a000000			;INTPND clear UART0 interrupt request
	ADD R0,R0,#0x10
	mov r1,#0x1<<28
	STR R1,[R0]
	
	SUBS PC,LR,#0X4
START
	MOV R0,#0X30000000			;COPY EXCEPTION_VECTOR TO 0X00000000
	MOV R1,#0X30000000
	MOV R2,#0X00000000
	ADD R1,R1,#48
2	LDMIA R0!,{R3-R6}			
	STMIA R2!,{R3-R6}
	CMP R0,R1
	BNE %B2
	MOV R0,#0X56000000			;GPHCON
	ADD R0,R0,#0x70
	MOV R1,#0XAA
	STR R1,[R0]
	MOV R0,#0x50000000			;ULCON0
	MOV R1,#0x3
	STR R1,[R0]
	MOV R0,#0x50000000			;UCON0
	ADD R0,R0,#0x4				
	MOV R1,#0x05
	ADD R1,R1,#0x0
	STR R1,[R0]
	MOV R0,#0x50000000			;UBRDIV0 115200HZ
	ADD R0,R0,#0x28				
	MOV R1,#26
	ADD R1,R1,#0x0
	STR R1,[R0]	
	MOV R0,#0X4A000000			;INTMASK clear uart0 mask
	ADD R0,R0,#0x8
	MOV R1,#0xFFFFFFFF
	EOR R1,R1,#0x1<<28
	STR R1,[R0]	
	MOV R0,#0X4A000000			;INTSUBMASK clear RXD0 TXD0 ERR0 mask
	ADD R0,R0,#0x1c
	MOV R1,#0x000EF000
	ADD R1,R1,#0X00000FF0
	ADD R1,R1,#0X0000000E
	STR R1,[R0]
	MRS R0,cpsr				;enable irq mode
	eor r0,#0x1<<7
	MSR cpsr_c,r0
	
l
	b l
	end
	



keil MDK升级到V4.54后使用J-link问题

今天将Keil MDK升级到了V4.54,使用J-link下载程序,发现MDK自带的Jlink驱动已经更新到V4.5版本,然后MDK提示有J-Link新固件,这之前也遇到过这类提示,然后我选择了升级j...
  • zhzht19861011
  • zhzht19861011
  • 2012-07-12 20:57:33
  • 20401

JLINK固件烧写_SAMBA(修正)

原文地址:http://wenku.baidu.com/link?url=RTQ1bHCdTsDW60AsT2l0RmKuDsB1EOy4rhJhQDoJ8UQTONOXEwy3sfWQ1dFrCnC...
  • wletv
  • wletv
  • 2015-01-22 19:08:17
  • 2629

dsPIC33F串口通讯中断接收发送数据-UART

/* **************************************************************** ** 功能描述: 串行通讯程序,DSP中断收到8个数据后,将收...
  • Augusdi
  • Augusdi
  • 2013-08-13 14:44:33
  • 5061

串口uart调试小小结

写作原因:近来蛋闲?非也  !  昨天一同事合作的项目代码出现的bug-----他的上位机每200ms给我发送命令向我这边下位机读取一些数据,在此过程会按下按键做一些另外操作并给他返回数据;(通信是通...
  • yx_l128125
  • yx_l128125
  • 2013-08-23 17:01:36
  • 3265

Msp430 g2553 UART与电脑串口通信例程

  • 2013年10月25日 11:32
  • 5KB
  • 下载

【蓝桥杯单片机组】(6)uart

(1)波特率的概念:1bps = 1 bit/s (2)板载资源有两个串口,仅UART1可以通过USB连接电脑 (3)四种方式波特率计算公式:(fosc:晶振频率 ) 方式1:baud = fosc ...
  • qq_21989461
  • qq_21989461
  • 2017-02-09 23:48:37
  • 742

UART(异步串口通信)裸板编程

一、先弄懂几个概念: 1、通信协议(通信规程): 是指通信双方约定的一些规则。 比如UART,在使用异步通信传送一个字符的信息时,对资料格式有如下规定:有空闲位、起始位、数据位、奇偶校验位、停止位...
  • good123_2014
  • good123_2014
  • 2015-11-26 20:48:17
  • 821

串口通信的三种方式(查询、中断、DMA) 之dma

由于UART串行口的广泛应用,在传统的8位和16位的处理器以及32位处理器中,一般都带有UART串行口。传统的基于UART的数据通讯中,采用的方式一般有两种,查询式和中断式。查询方式下CPU的负担较重...
  • luvzhan
  • luvzhan
  • 2013-03-25 17:30:01
  • 2151

创龙TMS320C6748开发板———UART寄存器介绍及程序

1、UART寄存器 (1)、FIFO控制寄存器(FCR) RXFIFTL:接收FIFO中断触发(当FIFO中的数据量刚到达所要求(trigger level)的时候会产生中断); D...
  • xiaoluoshan
  • xiaoluoshan
  • 2017-01-13 21:30:10
  • 958
收藏助手
不良信息举报
您举报文章:mini2440+jlink v8+mkd4.54 uart串口通信调试心得体会(11.20补完中断部分)
举报原因:
原因补充:

(最多只允许输入30个字)