bat脚本删除指定天数以前的文件，日期格式为（xxxx20190101.xxx）

xxxxx代表为任意字符

文件名称为：xxxxx20190101.xxxxx

脚本内容为：

@echo off

rem 使用相对路径
set SrcDir="%cd%\dict"
rem echo %prog_path%
rem 使用绝对路径
rem set SrcDir=C:\Users\X250\Desktop\xx\demo\dict
rem 指定天数
set DaysAgo=30

>"%temp%/DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%/DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%/DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%/DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%%DstDate:~4,2%%DstDate:~6,2%
rem echo "%DstDate%"
setlocal enabledelayedexpansion
for /r "%SrcDir%" %%a in (*.*) do (
    set "FileDate=%%~na"
    set "FileDate=!FileDate:~7,8!"
    if "!FileDate!" leq "%DstDate%" (
        if exist "%%a" (
            echo del /f /q "%%a"
        )
    )
)
endlocal
pause

上述代码中：

SrcDir为要删除的目录

DaysAgo为删除多少天以前的内容

这句话要按需修改：set DstDate=%DstDate:~0,4%%DstDate:~4,2%%DstDate:~6,2%

例如：文件名内容包含有20190101，则上述set DstDate=%DstDate:~0,4%%DstDate:~4,2%%DstDate:~6,2%

           文件名内容包含有2019-01-01，则上述set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%

           这段代码的作用是将当前系统的日期减去DaysAgo后进行拆装组合。

           2019-02-14减去30=2019-01-15，拆装后为20190115

接下来修改下面的话，这句话意思是截取文件名中的日期，我这里的日期是从第七位开始的，截取了8位。

set "FileDate=!FileDate:~7,8!"

截取的日期会和上面的日期进行对比，满足条件则删除。