shader入门精要读书笔记41 消融效果(使用噪声)

一、前言

消融效果常见于角色死亡、地图烧毁等等。

消融效果就是指在不同的区域开始，并且看似随机扩张，最后整个物体都消失不见。

二、实现代码(具体见注释)：

Shader "Unity Shaders Book/Chapter 15/Dissolve" {
	Properties {
		_BurnAmount ("Burn Amount", Range(0.0, 1.0)) = 0.0			//控制消融变化进程，0为原样，1为彻底消融
		_LineWidth("Burn Line Width", Range(0.0, 0.2)) = 0.1		//燃烧的线宽，值越大，火焰边缘蔓延范围越广
		_MainTex ("Base (RGB)", 2D) = "white" {}			//主纹理、漫发射纹理
		_BumpMap ("Normal Map", 2D) = "bump" {}			//法线纹理，进行凹凸映射，使用切线空间计算
		_BurnFirstColor("Burn First Color", Color) = (1, 0, 0, 1)		//火焰边缘的两种颜色值
		_BurnSecondColor("Burn Second Color", Color) = (1, 0, 0, 1)
		_BurnMap("Burn Map", 2D) = "white"{}		//噪声纹理
	}
	SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}//不透明的几何体
		
		Pass {
			Tags { "LightMode"="ForwardBase" }

			Cull Off
			
			CGPROGRAM  
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			#pragma multi_compile_fwdbase			//前向渲染同来正确值的，不同Shader代码等等
			
			#pragma vertex vert
			#pragma fragment frag
			
			fixed _BurnAmount;
			fixed _LineWidth;
			sampler2D _MainTex;
			sampler2D _BumpMap;
			fixed4 _BurnFirstColor;
			fixed4 _BurnSecondColor;
			sampler2D _BurnMap;
			
			float4 _MainTex_ST;			//三个纹理的偏移，缩放属性
			float4 _BumpMap_ST;
			float4 _BurnMap_ST;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uvMainTex : TEXCOORD0;
				float2 uvBumpMap : TEXCOORD1;
				float2 uvBurnMap : TEXCOORD2;
				float3 lightDir : TEXCOORD3;
				float3 worldPos : TEXCOORD4;
				SHADOW_COORDS(5)
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);			//裁剪坐标
				
				o.uvMainTex = TRANSFORM_TEX(v.texcoord, _MainTex);		//计算偏移缩放得到纹理坐标
				o.uvBumpMap = TRANSFORM_TEX(v.texcoord, _BumpMap);
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
				
				TANGENT_SPACE_ROTATION;			//计算模型空间转换到切线空间的变换矩阵rotation(3×3)，具体实现代码在150页。
  				o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;		//计算模型空间视角方向 再转换到 切线空间
  				
  				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;		//世界空间顶点用于 计算阴影等
  				
  				TRANSFER_SHADOW(o);		//计算阴影纹理采样坐标，计算阴影那个三剑客
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;			//采样噪声纹理
				
				clip(burn.r - _BurnAmount);		//剔除burn.r - _BurnAmount小于0的像素，
				//也就是说采样结果有0.5，有1，那么_BurnAmount为0.5时，采样结果为0.5的像素就会被裁剪掉，为1时采样结果为1的像素也被裁剪掉
				//这样就对应随着时间进程 不同位置像素的消失过程。
				
				float3 tangentLightDir = normalize(i.lightDir);		//切线空间
				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));		//取样法线纹理，再从像素映射回回法线方向
				
				fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;			//材质反射率
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;			//获得环境光
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));		//采样法线纹理，在切线空间内计算的

				fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);		
				//smoothstep(0.0, _LineWidth, burn.r - _BurnAmount)意义是 当(burn.r - _BurnAmount)大于_LineWidth时，返回1，小于0时返回0，否则进行插值
				//也就是可以用smoothstep(0.0, _LineWidth, burn.r - _BurnAmount)来模拟这个像素在距离消融前有多远。
				//可以举例子，比如现在像素采样burn.r为0.6，_BurnAmount为0.5，那么也就是还差0.1 这个像素就要消融了
				//然后再用0.1，插值0-_LineWidth，得到一个值代表像素燃烧颜色变化进程模拟 燃烧过程的效果
				//1-0.1(假如0.1为插值结果)=0.9，这样t就是更大，为更接近烧焦效果的那一边。所以下一句t越大，越是烧焦的_BurnSecondColor。

				fixed3 burnColor = lerp(_BurnFirstColor, _BurnSecondColor, t);		//根据不同燃烧进程进行颜色计算，每个像素随着进程由第一个颜色变成第二个颜色
				burnColor = pow(burnColor, 5);				//使用pow函数进行处理可以更接近烧焦效果颜色
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);			//计算阴影衰减等
				fixed3 finalColor = lerp(ambient + diffuse * atten, burnColor, t * step(0.0001, _BurnAmount));		//再使用t混合正常的光照颜色
				
				return fixed4(finalColor, 1);		//返回
			}
			
			ENDCG
		}
		
		// Pass to render object as a shadow caster
		Pass {				
			Tags { "LightMode" = "ShadowCaster" }					//投射阴影的Pass
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_shadowcaster			//指明需要的编译指令
			
			#include "UnityCG.cginc"
			
			fixed _BurnAmount;
			sampler2D _BurnMap;
			float4 _BurnMap_ST;
			
			struct v2f {
				V2F_SHADOW_CASTER;			//定义阴影投射需要定义的变量，
				float2 uvBurnMap : TEXCOORD1;			//噪声纹理的纹理坐标
			};
			
			v2f vert(appdata_base v) {
				v2f o;
				
				TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)		//填充V2F_SHADOW_CASTER定义的那些变量，这两个和最后那个要记下，计算自定义阴影投射相关变量
				
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);			//计算噪声纹理的纹理坐标
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;			//采样噪声纹理
				
				clip(burn.r - _BurnAmount);			//剔除
				
				SHADOW_CASTER_FRAGMENT(i)			//第三个阴影纹理计算宏，把结果输出到深度图和阴影映射纹理中
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

三、注意

需要记住那自定义阴影计算的3个宏，固定输入规定需要名称为v的输入结构体、v.vertex、v.normal，一般我们使用appdata_base代替。

如果我们要计算顶点动画阴影相关，我们可以在第二个宏之前的顶点着色器中改变v.vertex。
。。
。。

使用辅助脚本模拟时间循环变化：

burnAmount = Mathf.Repeat(Time.time * burnSpeed, 1.0f);
//类似于%，但是%会有负数，这个只有0-第二个参数之间的值，这个也就是随着时间返回0-1之间循环的数
material.SetFloat("_BurnAmount", burnAmount);

完事。