Count Color_poj2777_线段树+位运算

Description

Chosen Problem Solving and Program design as an optional course, you are required to solve all kinds of problems. Here, we get a new problem. 

There is a very long board with length L centimeter, L is a positive integer, so we can evenly divide the board into L segments, and they are labeled by 1, 2, ... L from left to right, each is 1 centimeter long. Now we have to color the board - one segment with only one color. We can do following two operations on the board: 

1. "C A B C" Color the board from segment A to segment B with color C. 
2. "P A B" Output the number of different colors painted between segment A and segment B (including). 

In our daily life, we have very few words to describe a color (red, green, blue, yellow…), so you may assume that the total number of different colors T is very small. To make it simple, we express the names of colors as color 1, color 2, ... color T. At the beginning, the board was painted in color 1. Now the rest of problem is left to your. 

Input

First line of input contains L (1 <= L <= 100000), T (1 <= T <= 30) and O (1 <= O <= 100000). Here O denotes the number of operations. Following O lines, each contains "C A B C" or "P A B" (here A, B, C are integers, and A may be larger than B) as an operation defined previously.

Output

Ouput results of the output operation in order, each line contains a number.

Sample Input

2 2 4

C 1 1 2

P 1 2

C 2 2 2

P 1 2

Sample Output

2

1

题目大意：

在一段1…L的区间上进行O次涂色和查询两种操作

涂色：将A..B区间染上C颜色

查询：统计A…B区间有多少段不同颜色。

颜色种类不超过C种

思路：

线段树模拟染色过程，每个区间用visit域表示是否有颜色覆盖，用二进制数c表示当前域的覆盖颜色状态，最后统计颜色种数。看错数据范围所以wa，蛋疼许久。

源代码/pas:

 

type
tree=record
  l,r,c:longint;
  visit:boolean;
end;
var
  n,m,p,k:longint;
  t:array[0..400001]of tree;
procedure build(f,x,y:longint);
var
  mid:longint;
begin
  t[f].l:=x;
  t[f].r:=y;
  t[f].c:=t[f].c or 1;
  if x=y then exit;
  mid:=(x+y)div 2;
  build(f*2,x,mid);
  build(f*2+1,mid+1,y);
end;
procedure insert(f,x,y,color:longint);
var
  mid:longint;
begin
  if (x=t[f].l)and(y=t[f].r) then
  begin
    t[f].c:=1 shl (color-1);
    t[f].visit:=true;
    exit;
  end;
  if t[f].visit then
  begin
    t[f].visit:=false;
    t[f*2].visit:=true;
    t[f*2].c:=t[f].c;
    t[f*2+1].visit:=true;
    t[f*2+1].c:=t[f].c;
  end;
  mid:=(t[f].l+t[f].r)div 2;
  if y<=mid then insert(f*2,x,y,color)
  else
  if x>mid then insert(f*2+1,x,y,color)
  else
  begin
    insert(f*2,x,mid,color);
    insert(f*2+1,mid+1,y,color);
  end;
  t[f].c:=t[f*2].c or t[f*2+1].c;
end;
procedure count(f,x,y:longint);
var
  mid:longint;
begin
  if (t[f].visit)or(x=t[f].l)and(y=t[f].r) then
  begin
    k:=k or t[f].c;
    exit;
  end;
  mid:=(t[f].l+t[f].r)div 2;
  if y<=mid then count(f*2,x,y)
  else
  if x>mid then count(f*2+1,x,y)
  else
  begin
    count(f*2,x,mid);
    count(f*2+1,mid+1,y);
  end;
end;
procedure main;
var
  i,j,x,y,z,ans:longint;
  ch:char;
begin
  readln(n,p,m);
  build(1,1,n);
  for i:=1 to m do
  begin
    read(ch,x,y);
    if x>y then
    begin
      x:=x xor y;
      y:=x xor y;
      x:=x xor y;
    end;
    if ch='C' then
    begin
      readln(z);
      insert(1,x,y,z);
    end
    else
    begin
      readln;
      k:=0;
      ans:=0;
      count(1,x,y);
      for j:=1 to p do
      if k and(1 shl(j-1))>0 then
      inc(ans);
      writeln(ans);
    end;
  end;
end;
begin
  main;
end.

转载于:https://www.cnblogs.com/olahiuj/p/5781317.html