ant生成jmeter测试报告没有数据【已解决】

最新推荐文章于 2023-02-01 18:40:24 发布
最新推荐文章于 2023-02-01 18:40:24 发布
阅读量664 收藏
点赞数 1
文章标签： 测试 javascript ViewUI
原文链接：http://www.cnblogs.com/Jack-cx/p/9395115.html
版权

1.如下图，在配置build时，到网上找配置文件，配置样式表文件名经常是jmeter-results-detail-report_21.xsl，

 

3.但是在其他版本可能被不是这个文件名，在jmeter根目录下模糊搜索 jmeter-res，就会出来，然后再把jmeter-results-detail-report.xsl替换到上面ant的配置文件中

 

3.再次使用ant尝试生成测试报告如果测试报告生成了，但是只是个空文件。那么需要把jmeter-results-detail-report.xsl里内容都替换掉（替换整个文件内容）再尝试生成 

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<!--
   Licensed to the Apache Software Foundation (ASF) under one or more
   contributor license agreements.  See the NOTICE file distributed with
   this work for additional information regarding copyright ownership.
   The ASF licenses this file to You under the Apache License, Version 2.0
   (the "License"); you may not use this file except in compliance with
   the License.  You may obtain a copy of the License at
 
       http://www.apache.org/licenses/LICENSE-2.0
 
   Unless required by applicable law or agreed to in writing, software
   distributed under the License is distributed on an "AS IS" BASIS,
   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
   See the License for the specific language governing permissions and
   limitations under the License.
-->

<!-- 
    Stylesheet for processing 2.1 output format test result files 
    To uses this directly in a browser, add the following to the JTL file as line 2:
    <?xml-stylesheet type="text/xsl" href="../extras/jmeter-results-detail-report_21.xsl"?>
    and you can then view the JTL in a browser
-->

<xsl:output method="html" indent="yes" encoding="UTF-8" doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN" />

<!-- Defined parameters (overrideable) -->
<xsl:param    name="showData" select="'n'"/>
<xsl:param    name="titleReport" select="'Load Test Results'"/>
<xsl:param    name="dateReport" select="'date not defined'"/>

<xsl:template match="testResults">
    <html>
        <head>
            <title><xsl:value-of select="$titleReport" /></title>
            <style type="text/css">
                body {
                    font:normal 68% verdana,arial,helvetica;
                    color:#000000;
                }
                table tr td, table tr th {
                    font-size: 68%;
                }
                table.details tr th{
                    color: #ffffff;
                    font-weight: bold;
                    text-align:center;
                    background:#2674a6;
                    white-space: nowrap;
                }
                table.details tr td{
                    background:#eeeee0;
                    white-space: nowrap;
                }
                h1 {
                    margin: 0px 0px 5px; font: 165% verdana,arial,helvetica
                }
                h2 {
                    margin-top: 1em; margin-bottom: 0.5em; font: bold 125% verdana,arial,helvetica
                }
                h3 {
                    margin-bottom: 0.5em; font: bold 115% verdana,arial,helvetica
                }
                .Failure {
                    font-weight:bold; color:red;
                }
                
    
                img
                {
                  border-width: 0px;
                }
                
                .expand_link
                {
                   position=absolute;
                   right: 0px;
                   width: 27px;
                   top: 1px;
                   height: 27px;
                }
                
                .page_details
                {
                   display: none;
                }
                                
                                .page_details_expanded
                                {
                                    display: block;
                                    display/* hide this definition from  IE5/6 */: table-row;
                                }


            </style>
            <script language="JavaScript"><![CDATA[
                           function expand(details_id)
               {
                  
                  document.getElementById(details_id).className = "page_details_expanded";
               }
               
               function collapse(details_id)
               {
                  
                  document.getElementById(details_id).className = "page_details";
               }
               
               function change(details_id)
               {
                  if(document.getElementById(details_id+"_image").src.match("expand"))
                  {
                     document.getElementById(details_id+"_image").src = "collapse.png";
                     expand(details_id);
                  }
                  else
                  {
                     document.getElementById(details_id+"_image").src = "expand.png";
                     collapse(details_id);
                  } 
                           }
            ]]></script>
        </head>
        <body>
        
            <xsl:call-template name="pageHeader" />
            
            <xsl:call-template name="summary" />
            <hr size="1" width="95%" align="center" />
            
            <xsl:call-template name="pagelist" />
            <hr size="1" width="95%" align="center" />
            
            <xsl:call-template name="detail" />

        </body>
    </html>
</xsl:template>

<xsl:template name="pageHeader">
    <h1><xsl:value-of select="$titleReport" /></h1>
    <table width="100%">
        <tr>
            <td align="left">Date report: <xsl:value-of select="$dateReport" /></td>
            <td align="right">Designed for use with <a href="http://jmeter.apache.org/">JMeter</a> and <a href="http://ant.apache.org">Ant</a>.</td>
        </tr>
    </table>
    <hr size="1" />
</xsl:template>

<xsl:template name="summary">
    <h2>Summary</h2>
    <table align="center" class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
        <tr valign="top">
            <th># Samples</th>
            <th>Failures</th>
            <th>Success Rate</th>
            <th>Average Time</th>
            <th>Min Time</th>
            <th>Max Time</th>
        </tr>
        <tr valign="top">
            <xsl:variable name="allCount" select="count(/testResults/*)" />
            <xsl:variable name="allFailureCount" select="count(/testResults/*[attribute::s='false'])" />
            <xsl:variable name="allSuccessCount" select="count(/testResults/*[attribute::s='true'])" />
            <xsl:variable name="allSuccessPercent" select="$allSuccessCount div $allCount" />
            <xsl:variable name="allTotalTime" select="sum(/testResults/*/@t)" />
            <xsl:variable name="allAverageTime" select="$allTotalTime div $allCount" />
            <xsl:variable name="allMinTime">
                <xsl:call-template name="min">
                    <xsl:with-param name="nodes" select="/testResults/*/@t" />
                </xsl:call-template>
            </xsl:variable>
            <xsl:variable name="allMaxTime">
                <xsl:call-template name="max">
                    <xsl:with-param name="nodes" select="/testResults/*/@t" />
                </xsl:call-template>
            </xsl:variable>
            <xsl:attribute name="class">
                <xsl:choose>
                    <xsl:when test="$allFailureCount &gt; 0">Failure</xsl:when>
                </xsl:choose>
            </xsl:attribute>
            <td align="center">
                <xsl:value-of select="$allCount" />
            </td>
            <td align="center">
                <xsl:value-of select="$allFailureCount" />
            </td>
            <td align="center">
                <xsl:call-template name="display-percent">
                    <xsl:with-param name="value" select="$allSuccessPercent" />
                </xsl:call-template>
            </td>
            <td align="center">
                <xsl:call-template name="display-time">
                    <xsl:with-param name="value" select="$allAverageTime" />
                </xsl:call-template>
            </td>
            <td align="center">
                <xsl:call-template name="display-time">
                    <xsl:with-param name="value" select="$allMinTime" />
                </xsl:call-template>
            </td>
            <td align="center">
                <xsl:call-template name="display-time">
                    <xsl:with-param name="value" select="$allMaxTime" />
                </xsl:call-template>
            </td>
        </tr>
    </table>
</xsl:template>

<xsl:template name="pagelist">
    <h2>Pages</h2>
    <table align="center" class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
        <tr valign="top">
            <th>URL</th>
            <th># Samples</th>
            <th>Failures</th>
            <th>Success Rate</th>
            <th>Average Time</th>
            <th>Min Time</th>
            <th>Max Time</th>
            <th></th>
        </tr>
        <xsl:for-each select="/testResults/*[not(@lb = preceding::*/@lb)]">
            <xsl:variable name="label" select="@lb" />
            <xsl:variable name="count" select="count(../*[@lb = current()/@lb])" />
            <xsl:variable name="failureCount" select="count(../*[@lb = current()/@lb][attribute::s='false'])" />
            <xsl:variable name="successCount" select="count(../*[@lb = current()/@lb][attribute::s='true'])" />
            <xsl:variable name="successPercent" select="$successCount div $count" />
            <xsl:variable name="totalTime" select="sum(../*[@lb = current()/@lb]/@t)" />
            <xsl:variable name="averageTime" select="$totalTime div $count" />
            <xsl:variable name="minTime">
                <xsl:call-template name="min">
                    <xsl:with-param name="nodes" select="../*[@lb = current()/@lb]/@t" />
                </xsl:call-template>
            </xsl:variable>
            <xsl:variable name="maxTime">
                <xsl:call-template name="max">
                    <xsl:with-param name="nodes" select="../*[@lb = current()/@lb]/@t" />
                </xsl:call-template>
            </xsl:variable>
            <tr valign="top">
                <xsl:attribute name="class">
                    <xsl:choose>
                        <xsl:when test="$failureCount &gt; 0">Failure</xsl:when>
                    </xsl:choose>
                </xsl:attribute>
                <td>
                <xsl:if test="$failureCount > 0">
                  <a><xsl:attribute name="href">#<xsl:value-of select="$label" /></xsl:attribute>
                  <xsl:value-of select="$label" />
                  </a>
                </xsl:if>
                <xsl:if test="0 >= $failureCount">
                  <xsl:value-of select="$label" />
                </xsl:if>
                </td>
                <td align="center">
                    <xsl:value-of select="$count" />
                </td>
                <td align="center">
                    <xsl:value-of select="$failureCount" />
                </td>
                <td align="right">
                    <xsl:call-template name="display-percent">
                        <xsl:with-param name="value" select="$successPercent" />
                    </xsl:call-template>
                </td>
                <td align="right">
                    <xsl:call-template name="display-time">
                        <xsl:with-param name="value" select="$averageTime" />
                    </xsl:call-template>
                </td>
                <td align="right">
                    <xsl:call-template name="display-time">
                        <xsl:with-param name="value" select="$minTime" />
                    </xsl:call-template>
                </td>
                <td align="right">
                    <xsl:call-template name="display-time">
                        <xsl:with-param name="value" select="$maxTime" />
                    </xsl:call-template>
                </td>
                <td align="center">
                   <a href="">
                      <xsl:attribute name="href"><xsl:text/>javascript:change('page_details_<xsl:value-of select="position()" />')</xsl:attribute>
                      <img src="expand.png" alt="expand/collapse"><xsl:attribute name="id"><xsl:text/>page_details_<xsl:value-of select="position()" />_image</xsl:attribute></img>                      
                   </a>
                </td>
            </tr>
            
                        <tr class="page_details">
                           <xsl:attribute name="id"><xsl:text/>page_details_<xsl:value-of select="position()" /></xsl:attribute>
                           <td colspan="8" bgcolor="#FF0000">
                              <div align="center">
                     <b>Details for Page "<xsl:value-of select="$label" />"</b>
                     <table bordercolor="#000000" bgcolor="#2674A6" border="0"  cellpadding="1" cellspacing="1" width="95%">
                     <tr>
                        <th>Thread</th>
                        <th>Iteration</th>
                        <th>Time (milliseconds)</th>
                        <th>Bytes</th>
                        <th>Success</th>
                     </tr>
                                      
                     <xsl:for-each select="../*[@lb = $label and @tn != $label]">                                             
                        <tr>
                           <td><xsl:value-of select="@tn" /></td>
                           <td align="center"><xsl:value-of select="position()" /></td>
                           <td align="right"><xsl:value-of select="@t" /></td>
                           <!--  TODO allow for missing bytes field -->
                           <td align="right"><xsl:value-of select="@by" /></td>
                           <td align="center"><xsl:value-of select="@s" /></td>
                        </tr>
                     </xsl:for-each>
                     
                     </table>
                  </div>
                           </td>
                        </tr>
            
        </xsl:for-each>
    </table>
</xsl:template>

<xsl:template name="detail">
    <xsl:variable name="allFailureCount" select="count(/testResults/*[attribute::s='false'])" />

    <xsl:if test="$allFailureCount > 0">
        <h2>Failure Detail</h2>

        <xsl:for-each select="/testResults/*[not(@lb = preceding::*/@lb)]">

            <xsl:variable name="failureCount" select="count(../*[@lb = current()/@lb][attribute::s='false'])" />

            <xsl:if test="$failureCount > 0">
                <h3><xsl:value-of select="@lb" /><a><xsl:attribute name="name"><xsl:value-of select="@lb" /></xsl:attribute></a></h3>

                <table align="center" class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
                <tr valign="top">
                    <th>Response</th>
                    <th>Failure Message</th>
                    <xsl:if test="$showData = 'y'">
                       <th>Response Data</th>
                    </xsl:if>
                </tr>
            
                <xsl:for-each select="/testResults/*[@lb = current()/@lb][attribute::s='false']">
                    <tr>
                        <td><xsl:value-of select="@rc | @rs" /> - <xsl:value-of select="@rm" /></td>
                        <td><xsl:value-of select="assertionResult/failureMessage" /></td>
                        <xsl:if test="$showData = 'y'">
                            <td><xsl:value-of select="./binary" /></td>
                        </xsl:if>
                    </tr>
                </xsl:for-each>
                
                </table>
            </xsl:if>

        </xsl:for-each>
    </xsl:if>
</xsl:template>

<xsl:template name="min">
    <xsl:param name="nodes" select="/.." />
    <xsl:choose>
        <xsl:when test="not($nodes)">NaN</xsl:when>
        <xsl:otherwise>
            <xsl:for-each select="$nodes">
                <xsl:sort data-type="number" />
                <xsl:if test="position() = 1">
                    <xsl:value-of select="number(.)" />
                </xsl:if>
            </xsl:for-each>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="max">
    <xsl:param name="nodes" select="/.." />
    <xsl:choose>
        <xsl:when test="not($nodes)">NaN</xsl:when>
        <xsl:otherwise>
            <xsl:for-each select="$nodes">
                <xsl:sort data-type="number" order="descending" />
                <xsl:if test="position() = 1">
                    <xsl:value-of select="number(.)" />
                </xsl:if>
            </xsl:for-each>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="display-percent">
    <xsl:param name="value" />
    <xsl:value-of select="format-number($value,'0.00%')" />
</xsl:template>

<xsl:template name="display-time">
    <xsl:param name="value" />
    <xsl:value-of select="format-number($value,'0 ms')" />
</xsl:template>
    
</xsl:stylesheet>

 

转载于:https://www.cnblogs.com/Jack-cx/p/9395115.html

weixin_30470857
关注
解决jmeter-results-report_21.xsl 的一个小不足(一)
行走产品经理之道
12-03 4091
用过jmeter-results-report_21.xsl来转换测试结果为html的朋友们，不知道你们有没有发现，如果你的testplan中的threads 数大于1的时候，转换出来的结果会不正确，就是在的第一个request 结果会重复出现两行，本来应该是一个request一行的，但是第一个request会出现两行。给大家看一个例子：这个是我的testPlan, 只有两个request, 一个search 一个是readselectlist, 而线程数是3，用Jmeter 原有的 jmeter-resu
JMeter非GUI模式自动生成测试报告
DearMorning的博客
05-03 4069
JMeter非GUI模式生成测试报告report.jtl，以及在该模式下生成html格式的测试报告
用Ant 自动生成Jmeter测试报告
Orange_ysen的博客
01-24 3597
1、建立一个ResultLong文件夹和一个Script文件夹，在ResultLong文件夹下创建一个html文件夹以及jtl文件夹，Script文件夹主要放测试脚本，其他文件夹分别放ant生成的html文件以及jtl文件。 ...
jmeter ant的html结果为空,Jmeter接口测试（六_2）Ant生成结果报告时遇到的问题
weixin_39922749的博客
06-04 656
ANT批量执行jmeter脚本，功能实现上都没有什么问题，但是最后生成的报告有一点小问题，虽然不影响使用，但还是可以改进的地方，具体问题如下：Paste_Image.png1、Date report这里的时间没有正确显示出来2、Summary里的字段Min Time和Max Time显示的是NaN，没有显示正确的时间。本文主要解决上述两个问题。二、Jmeter+Ant报告生成原理：在解决问题之前，...
jmeter ant的html结果为空,Ant Jmeter Jenkins生成html测试报告
weixin_39610353的博客
06-04 485
Ant配置1、 将jmeter安装目录或者源码目录下\apache-jmeter-3.1\extras的ant-jmeter-1.1.1.jar复制到ant安装目录下apache-ant-1.10.3\lib2、在Ant安装目录下新建build.xml文件，参考如下文件内容修改：force="true"in="${jmeter.result.jtlName}"out="${jmeter.resul...
jmeter Summary Report 汇总报告的查看
人生苦短，何妨一试
07-03 807
jmeter Summary Report 汇总报告的查看
ant +jmeter 生成测试报告.docx
01-20
总结来说，通过 Ant 和 JMeter 的集成，我们可以实现自动化测试并生成专业的测试报告，这有助于我们更好地理解和分析测试数据，从而优化系统性能。务必按照上述步骤操作，并根据实际项目需求调整配置，以确保测试...
jmeter+ant生成测试报告
yangfan_sh的博客
05-19 623
jmeter+ant生成测试报告 1.下载并安装，jdk、jmeter、ant，安装成功。 打开命令行，java -v;jmeter -v;ant -v;测试是否安装成功 2.找到jmeter安装路径下extras的ant-jmeter-1.1.1.jar包，复制到ant的lib目录下，这样ant运行的时候，才能触发到jmeter 3.新建build.xml文件，指定测试报告产出内容的相关配置（内容如下5），将build文件和将要运行的测试jmx脚本放到同一个目录下 4.在命令行进入到此目录下，输入an
基于Jmeter生成测试报告过程图解
08-18
根据提供的文件内容，以下是生成Jmeter测试报告的主要步骤和知识点： 1. Jmeter测试报告生成的基础知识 - Jmeter能够以非GUI模式运行，即在命令行中执行测试。这种方式可以用于自动化测试和持续集成的场景。 - ...
ant+jmeter报告模板源代码.rar_Jmeter Jenkins_ant xsl模板_jemter源码分析_jmeter
09-14
在JMeter测试中，Ant可以用于自动化执行JMeter脚本，例如，通过配置Ant的build.xml文件，我们可以设定一系列的任务，如启动JMeter、执行测试、收集结果文件等。 Jenkins则是一个持续集成工具，能够自动化各种任务，...
JMeter+Jenkins+Ant环境生成测试报告
weixin_46143392的博客
10-12 342
一、配置ant 1：打开Test文件夹 2：找到Test中的ant文件夹下的如下路径 3：配置环境变量 在环境变量中系统变量新增ANT_HOME: 为 ant解压位置 PATH为%ANT_HOME%\bin CLASSPATH为 %ANT_HOME%\lib; 4：验证ant是否安装成功，如下显示的为成功 5：配置库文件 将jmeter extras目录下的ant-jmeter-1.1.1.jar文件拷...
解决jmeter测试报告不显示后面的断言错误失败信息
lyhDream的专栏
02-07 4831
一、问题描述 使用jmeter进行自动测试了两个接口，该接口测试有4个断言，其中有3个断言是失败的，并且有相应的断言错误信息： 请求失败11111111111111 请求失败222222222222 请求失败333333333333  通过jmeter命令行ant生成的测试报告如下： 【jmeter通过ant自动生成测试报告参见：https://www.cnblogs.com/liy...
如何解决jmeter响应结果树中，返回数据显示不完整的问题？
热门推荐
Rookie_Dragon的博客
01-31 1万+
在使用jmeter的过程中，返回了大量数据，在统计数据量的时候发现与数据库差距较大，遂检查返回结果。 拉倒最后发现，MMP没有加载完！！！！ 这里给出解决办法： 1：在jmeter安装文件下找到文件：../bin/jmeter.properties  2：修改参数：#view.results.tree.max_size 。 3：修改完成后记得重启jmeter！
jmter生成的报告没有显示请求和响应明细数据
aizongzhuang2281的博客
05-04 969
第一次把环境全部搭建好后运行得出的html报告如下：没有显示Request和Response数据，这样不利于定位问题 估计是jmeter为了减轻客户机负担，就没又默认把这些信息保存，如果想要保存，也可以，需要做出如下配置： 修改bin目录下的user.properties文件，追加配置： jmeter.save.saveservice.output_format=xmljmet...
jemeter 压测并生成报告
Mr_Wanter
12-14 3828
jmeter：是Apche公司使用Java平台开发的一款测试工具。
jmeter ant的html结果为空,window 下 jmeter+ant 自动生成html报告
weixin_30823465的博客
06-04 327
一、安装ant1、ant 下载地址：https://ant.apache.org/bindownload.cgi2、下载完成解压到指定目录下3、配置ant 环境变量新建系统变量 -ANT_HOMECLASSPATH 住家ant的lib包--%ANT_HOME%\libpath 增加 ant的bin目录--%ANT_HOME%\bin4、检查ant是否安装成功ant -version重要配置：1)将...
【独家工具】JMeterPerfReporter3.0正式版本，让你的JMeter更好用
最新发布
主要分享测试的学习资源，帮助快速了解测试行业，帮助想转行、进阶、小白成长为高级测试工程师。
02-01 679
Lemon-JMeterPerfReporter工具，是我们性能测试课程教研组根据JMeter性能测试报告的不足，定制开发的一个性能报告生成工具。有需要的同学，可以通过小编官方gitee账户下载，或咨询我免费获取哦！做过性能测试的人员都知道，性能测试中，有一个非常重要的工作，就是分析测试结果。而做分析，必须要有数据支撑。JMeter工具自身具备把性能测试过程中，事务相关的数据保存下来，生成HTML报告的能力。但是，这个能力很基础。相比一些其他性能工具而言，这是一个明显的短板。
JMeter数据驱动与Jenkins集成：简化测试与报告生成
4. 创建或修改Jenkins构建脚本（build.xml），定义如何在每次构建时自动执行JMeter测试，并生成测试报告。 5. 在Jenkins中配置JMeter报告输出格式为XML，以便于集成到持续集成流程中，以便实时监控测试结果。 最后...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值