RQNOJ225_书本整理

题目描述
Frank是一个非常喜爱整洁的人。他有一大堆书和一个书架，想要把书放在书架上。书架可以放下所有的书，所以Frank首先将书按高度顺序排列在书架上。但是Frank发现，由于很多书的宽度不同，所以书看起来还是非常不整齐。于是他决定从中拿掉k本书，使得书架可以看起来整齐一点。
书架的不整齐度是这样定义的：每两本书宽度的差的绝对值的和。例如有4本书：
1x2
5x3
2x4
3x1
那么Frank将其排列整齐后是：
1x2
2x4
3x1
5x3
不整齐度就是2+3+2=7
已知每本书的高度都不一样，请你求出去掉k本书后的最小的不整齐度。

输入格式
第一行两个数字n和k，代表书有几本，从中去掉几本。(1<=n<=100, 1<=k<n)
下面的n行，每行两个数字表示一本书的高度和宽度，均小于200。

输出格式
一行一个整数，表示书架的最小不整齐度。

样例输入
4 1
1 2
2 4
3 1
5 3
 
样例输出
3

//----------------------------------------------------------------------------------------

分析:我们反过来思考,问题其实等价于从N本书中取N-K本.

用f[i,j]表示从前i本书中取j本且第i本必取的最小不整齐度.

f[i,j]=min{f[k,j-1]+abs(b[k]-b[i])}  (j-1<=k<=i-1)

code:

const maxn=101;
      oo=100000000;
var   f:array[0..maxn,0..maxn] of longint;
      a,b:array[0..maxn] of longint;
      ans,m,n,k,i,j:Longint;

      procedure swap(var a,b:longint);
      var   t:longint;
      begin
            t:=a; a:=b; b:=t;
      end;

      function min(a,b:longint):longint;
      begin
            if a>b then exit(b); exit(a);
      end;

begin
      readln(n,k);
      for i:=1 to n do read(a[i],b[i]);
      for i:=1 to n-1 do
         for j:=i+1 to n do
         if a[i]>a[j] then
         begin
               swap(a[i],a[j]);
               swap(b[i],b[j]);
         end;
      for i:=1 to n do
         for j:=2 to min(n-k,i) do
         begin
               f[i,j]:=oo;
               for m:=j-1 to i-1 do
                  f[i,j]:=min(f[i,j],f[m,j-1]+abs(b[m]-b[i]));
         end;

      ans:=oo;
      for i:=n-k to n do
         ans:=min(ans,f[i,n-k]);

      writeln(ans);
end.

转载于:https://www.cnblogs.com/exponent/archive/2011/08/08/2130676.html