【原题】【数据结构】【noip 2010T3】关押罪犯

问题

描述 Description

  S 城现有两座监狱，一共关押着N 名罪犯，编号分别为1~N。他们之间的关系自然也极不和谐。很多罪犯之间甚至积怨已久，如果客观条件具备则随时可能爆发冲突。我们用“怨气值”（一个正整数值）来表示某两名罪犯之间的仇恨程度，怨气值越大，则这两名罪犯之间的积怨越多。如果两名怨气值为c 的罪犯被关押在同一监狱，他们俩之间会发生摩擦，并造成影响力为c 的冲突事件。
每年年末，警察局会将本年内监狱中的所有冲突事件按影响力从大到小排成一个列表，然后上报到S 城Z 市长那里。公务繁忙的Z 市长只会去看列表中的第一个事件的影响力，如果影响很坏，他就会考虑撤换警察局长。
在详细考察了N 名罪犯间的矛盾关系后，警察局长觉得压力巨大。他准备将罪犯们在两座监狱内重新分配，以求产生的冲突事件影响力都较小，从而保住自己的乌纱帽。假设只要处于同一监狱内的某两个罪犯间有仇恨，那么他们一定会在每年的某个时候发生摩擦。那么，应如何分配罪犯，才能使Z 市长看到的那个冲突事件的影响力最小？这个最小值是多少？

输入格式 Input Format

输入文件的每行中两个数之间用一个空格隔开。
第一行为两个正整数N 和M，分别表示罪犯的数目以及存在仇恨的罪犯对数。
接下来的M 行每行为三个正整数aj，bj，cj，表示aj 号和bj 号罪犯之间存在仇恨，其怨气值为cj。数据保证1<=aj<bj<N,0<cj<=1,000,000,000 且每对罪犯组合只出现一次。

输出格式 Output Format

输出共1 行，为Z 市长看到的那个冲突事件的影响力。如果本年内监狱中未发生任何冲突事件，请输出0。

4 6
1 4 2534
2 3 3512
1 2 28351
1 3 6618
2 4 1805
3 4 12884

3512

分析

一共两个监狱，我们先采用一种贪心的思想，将两罪犯之间的冲突值从大到小排序，显然，对于大的冲突值的罪犯，我们一定要分开，才能使答案尽可能的小，直到当前罪犯不能再分开为止（即两人已经在一个监狱）。如果两人要分开，我们开数组记录一个人不能和谁在一所监狱，我们可以得到这样的逻辑关系，如果a不能和b在一起，a又不能和c一起，那么b一定和c在一起！

为了维护逻辑关系，判断矛盾，我们想到了并查集。

所以，贪心+并查集=ac

code

program liukee;
var
  f:array[1..20000] of longint;
  x,y,z:array[1..100000] of longint;
  r:array[1..20000] of longint;
  ans1,ans2,i:longint;
  n,m:longint;
procedure init;
var
  i:longint;
begin
  readln(n,m);
  for i:=1 to m do
    readln(x[i],y[i],z[i]);
  for i:=1 to n do
    f[i]:=i;
end;

procedure sort(l,r:longint);
var
  i,j,mid,temp:longint;
begin
  i:=l;
  j:=r;
  mid:=z[(i+j)>>1];
  repeat
    while z[i]>mid do inc(i);
    while z[j]<mid do dec(j);
    if i<=j then
    begin
       temp:=z[i];z[i]:=z[j];z[j]:=temp;
       temp:=x[i];x[i]:=x[j];x[j]:=temp;
       temp:=y[i];y[i]:=y[j];y[j]:=temp;
       inc(i);
       dec(j);
    end;
  until i>j;
  if l<j then sort(l,j);
  if i<r then sort(i,r);
end;

function find(x:longint):longint;
begin
  if f[x]=x then exit(x);
  f[x]:=find(f[x]);
  exit(f[x]);
end;

procedure union(x,y:longint);
var
  xx,yy:longint;
begin
  xx:=find(x);
  yy:=find(y);
  if xx<>yy then
    f[xx]:=yy;
end;

procedure doit;
var
  i,temp1,temp2:longint;
begin
  for i:=1 to m do
  begin
    if find(x[i])=find(y[i])then
	begin
	  writeln(z[i]);
	  exit;
	end;
	if (r[x[i]]=0)and(r[y[i]]=0)then
	begin
	  r[x[i]]:=y[i];
	  r[y[i]]:=x[i];
	  continue;
	end;
	if r[x[i]]=0 then  r[x[i]]:=y[i];
	if r[y[i]]=0 then  r[y[i]]:=x[i];
	union(r[x[i]],y[i]);
	union(r[y[i]],x[i]);
  end;
  writeln(0);
end;

begin
  init;
  sort(1,m);
  doit;
end.

反思

贪心的思想，逻辑关系思维，用经典数据结构实现！

转载于:https://www.cnblogs.com/liukeke/archive/2011/03/10/1979354.html