drop type t_dj_concat;
drop function dj_concat;
create or replace type dejia.t_dj_concat authid current_user as object
(
curr_str clob,
static function odciaggregateinitialize(sctx in out t_dj_concat)
return number,
member function odciaggregateiterate(self in out t_dj_concat,
p1 in varchar2) return number,
member function odciaggregateterminate(self in t_dj_concat,
returnvalue out clob,
flags in number)
return number,
member function odciaggregatemerge(self in out t_dj_concat,
sctx2 in t_dj_concat) return number
);
/
create or replace type body dejia.t_dj_concat
is
static function odciaggregateinitialize(sctx in out t_dj_concat)
return number
is
begin
sctx := t_dj_concat(null) ;
return odciconst.success;
end;
member function odciaggregateiterate(self in out t_dj_concat,
p1 in varchar2)
return number
is
begin
if(curr_str is not null) then
curr_str := curr_str || ',' || p1;
else
curr_str := p1;
end if;
return odciconst.success;
end;
member function odciaggregateterminate(self in t_dj_concat,
returnvalue out clob,
flags in number)
return number
is
begin
returnvalue := curr_str ;
return odciconst.success;
end;
member function odciaggregatemerge(self in out t_dj_concat,
sctx2 in t_dj_concat)
return number
is
begin
if(sctx2.curr_str is not null) then
self.curr_str := self.curr_str || ',' || sctx2.curr_str ;
end if;
return odciconst.success;
end;
end;
/
create or replace function dejia.dj_concat(p1 varchar2)
return clob aggregate using t_dj_concat ;
/