书的复制【答案的记录】

现在要把M本有顺序的书分给K个人复制（抄写），每一个人的抄写速度都一样，一本书不允许给两个（或以上）的人抄写，分给每一个人的书，必须是连续的，比如不能把第一、第三、第四本数给同一个人抄写。现在请你设计一种方案，使得复制时间最短。复制时间为抄写页数最多的人用去的时间。

 

输入

第一行两个整数M、K；（K<=M<=100）

第二行M个整数，第i个整数表示第i本书的页数。

输出

共K行，每行两个正整数，第i行表示第i个人抄写的书的起始编号和终止编号。K行的起始编号应该从小到大排列，如果有多解，则尽可能让前面的人少抄写。

 

样例

BOOK.IN

9 3

1 2 3 4 5 6 7 8 9

 

BOOK.OUT

1 5

6 7

8 9

 

 

这道题在一个月以前才做了 还找到了原因 结果今天又做错了……所以写一篇解题报告。

错误原因1  当有0个人的时候就不输出 注意讨论单独情况！

错误原因2 局部的最优解不一定是全局的最优解 所以局部的方案不一定是全局的最优方案

              例如 1 1 1 1分给两个人抄写 最优值是2 每个人抄写的区间1~2 3~4

              但是最后求解的最优值是3 这时候每个人抄写的区间（按照题目要求）是1~1 2~4

 

program book;
var
  f:array[0..1,0..501] of longint;
  a:array[0..501] of longint;
  n,m:longint;

procedure init;
var i:longint;
begin
  assign(input,'book.in');reset(input);
  assign(output,'book.out');rewrite(output);
  fillchar(a,sizeof(a),0);
  fillchar(f,sizeof(f),255);
  
  readln(m,n);
  if (m=0) and (n=0) then halt;                      
  for i:=1 to m do begin
    read(a[i]);
    a[i]:=a[i-1]+a[i];
  end;
end;

function max(a,b:longint):longint;
begin
  if (a>b) then exit(a) else exit(b);
end;

procedure main;
var i,j,k,tem:longint;
begin
  f[0,0]:=0;
  for i:=1 to n do
    for j:=1 to m do
      for k:=0 to (j-1) do if (f[(i-1) mod 2,k]<>-1) then begin
        tem:=max(a[j]-a[k],f[(i-1) mod 2,k]);
        if (tem<f[i mod 2,j]) or (f[i mod 2,j]=-1) then begin
          f[i mod 2,j]:=tem;
        end;
        if (j=m) then f[(i-1) mod 2,k]:=-1;
      end;
end;

procedure print(r,shu:longint);
var i:longint;
begin
  if (r=1) then writeln('1 ',shu) else begin
    i:=shu;
    while (i>=1) and (a[shu]-a[i-1]<=f[n mod 2,m]) do dec(i);
    inc(i);
    print(r-1,i-1);
    writeln(i,' ',shu);
  end;
end;

procedure terminate;
begin
  print(n,m);
  close(input);close(output);
end;

begin
  init;
  main;
  terminate;
end.

转载于:https://www.cnblogs.com/ushiojamie/archive/2011/10/29/2228630.html