1.新建一个文本文档，把下面的代码复制进去，保存退出。
 
@echo off
color 0A
echo.
@echo           ------------------------------------------
@echo            本命令将自动为“本地连接”修改IP地址:
@echo                输入"1"  --  自动获取IP地址
@echo                输入"2"  --  手动获取IP地址
@echo                输入"3"  --  自定义IP地址
@echo           ------------------------------------------
echo.
set sel=
set/p sel=请选择修改方式：
if "%sel%"=="1" goto auto
if "%sel%"=="2" goto dorm
if "%sel%"=="3" goto coustom
echo 请输入您要选择的修改方式并按回车键。
goto end

 

:auto
cls
color 0A
echo 正在更改IP地址，请稍等......
netsh interface ip set address name="本地连接" source=dhcp
echo 正在更改DNS地址，请稍等......
netsh interface ip set dns name="本地连接" source=dhcp
echo 更改IP地址完成！
goto end


:dorm
cls
color 0A
echo 正在手动更改IP地址，请稍等......
netsh interface ip set address name="本地连接" source=static addr=192.168.193.88 mask=255.255.255.0 gateway=192.168.193.99 gwmetric=1
echo 设置IP地址成功！
netsh interface ip set dns 本地连接 static 202.101.172.35
netsh interface ip add dns 本地连接 202.101.172.47
echo 设置DNS服务器成功！
echo.
echo 已更改为手动IP地址。
goto end


:coustom
cls
color 0A
echo 下面将由你配置IP地址，请按提示顺序输入......
set ip_new=
set/p ip_new=请输入IP地址(例:192.168.193.1)：

set mask_new=
set/p mask_new=请输入子网掩码(例:255.255.255.0)：

set gw_new=
set/p gw_new=请输入默认网关(例:192.168.193.1)：

netsh interface ip set address 本地连接 static addr=%ip_new% mask=%mask_new% gateway=%gw_new% gwmetric=1
echo 设置IP地址成功！
echo.
set dns1=
set/p dns1=请输入主DNS地址(例:202.101.172.35)：
netsh interface ip set dns 本地连接 static %dns1%

set dns2=
set/p dns2=请输入备份DNS地址(例:202.101.172.47)：
netsh interface ip add dns 本地连接 %dns2%
echo 设置DNS服务器成功！
echo.
echo IP地址配置完成。


:end
echo. & pause
 
      2. 把文本文档的后缀名.txt改为.bat，变成批处理文件，双击打开就可以运行了。